home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Shareware Overload
/
ShartewareOverload.cdr
/
games
/
eamon0.zip
/
NEWGUY.BAS
< prev
next >
Wrap
BASIC Source File
|
1986-06-23
|
7KB
|
171 lines
1 RANDOMIZE VAL(RIGHT$(TIME$,2))
100 REM CHARACTER GENERATOR FOR EAMON UNIVERSE
110 REM ORIGIONAL VERSION FOR APPLE II BY DONALD BROWN
120 REM MICROSOFT VERSION BY JON WALKER FOR MS-DOS & CP/M
130 REM
140 REM ENJOY!
150 REM
160 REM
170 REM CNAME$: CHARACTER NAME HD: HARDINESS AG: AGILITY CH: CHARISMA
180 REM
190 REM SA(1)-SA(4):SPELL ABILITIES
200 REM WA(1)-WA(5):WEAPON ABILITIES
210 REM
220 REM AE: AMROUR EXPERT. SEX$: M OR F GOLD: ON PERSON BANK: GOLD IN BANK
230 REM AC: ARMOUR CLASS
240 REM
250 REM WEAPON INFO:
260 REM WNAME$: WEAPON NAME
270 REM WTYPE: TYPE WODDS:ODDS OF HIT WDICE:# OF DICE WSIDE:# OF SIDES
280 REM
290 REM
300 DEF FNR(X)=INT(X*RND(1)+1)
310 DEF FNA(X)=FNR(X)+FNR(X)+FNR(X)
320 OPEN"I",#1,"ADVENTUR.ER"
330 INPUT#1,CNAME$
340 INPUT#1,REC:CLOSE#1
360 PRINT:PRINT"The Irishman says, 'First I must know whether ye be male"
370 PRINT" or female. Which are ye ' (Hit 'M' for male, 'F' for female) ";
380 A$=INKEY$:IF A$="" THEN 380
390 IF A$="m" THEN A$="M" ELSE IF A$="f" THEN A$="F"
395 IF A$<>"M" AND A$<>"F" THEN 380
400 SEX$=A$:PRINT SEX$:PRINT
410 PRINT:PRINT"The Irishman walks away and in walks a tall man of possibly"
420 PRINT"elvish descent. He studies you for a moment and says, 'Here is a"
430 PRINT"booklet of instruction for you to read, and your prime attributes"
440 PRINT"are --" :PRINT
450 HD=FNA(8):AG=FNA(8):CH=FNA(8)
460 PRINT" HARDINESS--";HD:PRINT" AGILITY --";AG:PRINT" CHARISMA --";CH;"'"
470 PRINT:PRINT"(Hit 'R' to read instructions, 'T' to give them back) ";
480 A$=INKEY$:IF A$="" THEN 480
490 IF A$="t" OR A$="T" THEN 1230
500 IF A$<>"r" AND A$<>"R" THEN 480
510 CLS
520 PRINT"You read the instructions and they say--IFORMATION ABOUT THE WORLD OF EAMON"
530 PRINT:PRINT"You will have to buy a weapon. Your chance to hit with it will"
540 PRINT"be the weapon complexity, plus your ability in that class, plus "
550 PRINT"twice your agility."
560 PRINT"The five classes of weapons (and your current abilities with each)"
570 PRINT"are--":PRINT" club/mace 20%":PRINT" spear 10%"
580 PRINT" axe 5%":PRINT" sword 0%":PRINT" bow -10%"
590 PRINT
600 PRINT"Every time you score a hit in battle, your ability in the weapon"
610 PRINT"class may go up by 2%, if a random number from 1-100 is less than"
620 PRINT"your chance to miss!":PRINT
630 PRINT:PRINT
640 PRINT"(Hit any key to continue) ";
650 IF INKEY$="" THEN 650
660 CLS
670 PRINT"There are four armor types, and you may also carry a shield if you"
680 PRINT"do not use a two handed weapon. These protections will absorb "
690 PRINT"hits placed upon you (ALMOST ALWAYS) But they lower your chance to"
700 PRINT"hit. The protections are--":PRINT:PRINT"ARMOUR";TAB(15);"hits protect odds adjust"
710 PRINT" none";TAB(18);0;TAB(35);"-0%"
720 PRINT" leather";TAB(18);1;TAB(35);"-10%"
730 PRINT" chain";TAB(18);2;TAB(35);"-20%"
740 PRINT" plate";TAB(18);5;TAB(35);"-60%"
750 PRINT" shield";TAB(18);1;TAB(35);"-5%
760 PRINT:PRINT:PRINT"You will develop an armour expertise, which will go up"
770 PRINT"when you hit a blow wearing armour and your expertise is less than"
780 PRINT"the armour you are wearing."
790 PRINT"No matter how high your armour expertise is, however, the net"
800 PRINT"effect will never increase you chance to hit.":PRINT
810 PRINT:PRINT:PRINT"(Hit any key to continue) ";
820 IF INKEY$="" THEN 820
830 CLS
840 PRINT"You can carry weights up to ten times your hardiness or "
850 PRINT HD*10;" gronds. (A measure of weight, one grond=10 dos)":PRINT
860 PRINT"Additionally, your hardiness tells how many points of damage you"
870 PRINT"can survive. Therefore, you can be hit with ";HD;" 1-point blows"
880 PRINT"before you die.":PRINT
890 PRINT"However, you will not be told how many blows you have taken. You"
900 PRINT"will be merely told things such as 'WOW, That one hurt!' or 'You"
910 PRINT"don't feel very well'.":PRINT
920 PRINT:PRINT:PRINT"(Hit any key to continue) ";
930 IF INKEY$="" THEN 930
940 CLS
950 PRINT"Your charisma (";CH;") affects how citizens of Eamon react to you."
960 PRINT"You affect a monster's friendliness rating by your charisma less"
970 PRINT"ten, differnce times two";"(";(CH-10)*2;"%)":PRINT
980 PRINT"You start off with 200 gold pieces, which you will want to spend "
990 PRINT"on supplies for your first adventure. You will get a lower price"
1000 PRINT"if your charisma is high.":PRINT
1010 PRINT"After you begin to acumulate wealth, you may want to put some of"
1020 PRINT"your money into the bank, where it cannot be stolen. However, it"
1030 PRINT"is a good idea to carry some gold with you for use in bargaining"
1040 PRINT"and ransom situations.":PRINT:PRINT:PRINT"(Hit any key to continue)";
1050 IF INKEY$="" THEN 1050
1060 CLS
1070 PRINT"You may also hire a wizard to teach you some magic spells. There"
1080 PRINT"are four spells you may buy."
1090 PRINT"BLAST-- Hurt your enemies from a distance."
1100 PRINT"HEAL -- Remove damage from your body."
1110 PRINT"SPEED-- Double your dexterity for a time."
1120 PRINT"POWER-- Effect is unpredictable.":PRINT
1130 PRINT:PRINT"Other types of magic may work in various adventures, and "
1140 PRINT"may have special properties. However, thse will not nescessarly"
1150 PRINT"work in other adventures than where they were found. Thus it is"
1160 PRINT"best (and you have no choice but to) sell all items found in"
1170 PRINT"adventures, except for weapons and armour.":PRINT
1180 PRINT:PRINT:PRINT"(HIT ANY KEY TO CONTINUE) ";
1190 IF INKEY$="" THEN 1190
1200 REM
1210 REM end of instructions
1220 REM
1230 CLS:PRINT"The man behind the desk takes back the instructions and says,"
1240 PRINT"'It is now time for you to start your life.' He makes an odd sign"
1250 PRINT"with his hand and says, 'Live long and prosper.'":PRINT
1260 PRINT"You now wander into the Main Hall."
1270 REM
1280 REM
1290 REM save the new character to then chacter file
1300 REM
1310 WA(1)=5:WA(2)=-10:WA(3)=20:WA(4)=10
1320 GOLD=200
1330 FOR I=1 TO 4:WNAME$(I)="NONE":WDICE(I)=0:WODDS(I)=0:WSIDE(I)=0:WTYPE(I)=0:NEXT I
1340 GOSUB 1750
1350 REM
1360 REM put him in character file
1370 REM
1380 OPEN"R",#2,"CHARACTE.RS",255
1390 FIELD 2,255 AS C$
1400 GET#2,1
1410 NC=VAL(C$)
1420 REM
1430 FOR R=1 TO NC
1440 GET#2,R+1
1450 IF LEFT$(C$,1)="," THEN 1480
1460 NEXT R
1470 R=NC+1
1480 LSET C$=A$
1490 PUT#2,R+1
1500 REM
1510 REM put # of characters into file
1520 REM
1530 LSET C$=STR$(R)
1540 PUT#2,1
1550 CLOSE#2
1560 REM
1570 REM put him in adventurer file for main hall
1580 REM
1590 OPEN"O",#1,"ADVENTUR.ER"
1610 PRINT#1,CNAME$
1620 PRINT#1,R
1630 CLOSE#1
1640 RUN"MAINHALL"
1650 STOP
1710 CNAME$=LEFT$(REC$,I-1)
1720 RETURN
1730 REM
1740 REM pack the array with commas
1750 REM
1760 A$=CNAME$+","+STR$(HD)+","+STR$(AG)+","+STR$(CH)+","
1770 FOR I=1 TO 4:A$=A$+STR$(SA(I))+",":NEXT I
1780 FOR I=1 TO 5:A$=A$+STR$(WA(I))+",":NEXT I
1790 A$=A$+STR$(AE)+","+SEX$+","+STR$(GOLD)+","+STR$(BANK)+","+STR$(AC)
1800 FOR I=1 TO 4:A$=A$+","+WNAME$(I)+","
1810 A$=A$+STR$(WTYPE(I))+","+STR$(WODDS(I))+","
1820 A$=A$+STR$(WDICE(I))+","+STR$(WSIDE(I))
1830 NEXT I
1840 RETURN