home *** CD-ROM | disk | FTP | other *** search
/ Shareware Overload / ShartewareOverload.cdr / games / eamon0.zip / EAMON.BAS < prev    next >
BASIC Source File  |  1986-06-23  |  5KB  |  108 lines
  1. 10 REM the Wonderful World of Eamon
  2. 20 REM
  3. 30 REM a computerized fantasy role-playing system origionaly made for
  4. 40 REM the apple computer system by Donald Brown,407 Peery Parkway
  5. 50 REM Golden, CO 80401
  6. 60 REM
  7. 70 REM Programmed for MBASIC by Jon Walker,Video Shop,139 S. Central
  8. 80 REM Marshfield, WI 54449
  9. 90 REM
  10. 100 REM ///Boot up program for Eamon system.
  11. 110 REM ///Gets name of player and send to main hall or new players
  12. 120 REM
  13. 130 CLS
  14. 135 FOR I=1 TO 24:PRINT:NEXT I
  15. 140 PRINT,"**************************************"
  16. 150 PRINT,"*                                    *"
  17. 160 PRINT,"*    THE WONDERFUL WORLD OF EAMON    *"
  18. 165 PRINT,"*            VERSION 1.1             *"
  19. 170 PRINT,"*                                    *"
  20. 180 PRINT,"*     Origional work by Donald       *"
  21. 190 PRINT,"*                       Brown        *"
  22. 200 PRINT,"*                                    *"
  23. 210 PRINT,"*     Converted  by Jon              *"
  24. 220 PRINT,"*                   Walker           *"
  25. 230 PRINT,"*                                    *"
  26. 240 PRINT,"**************************************"
  27. 250 PRINT
  28. 251 A$=INKEY$:IF A$=CHR$(27) THEN 280
  29. 255 GOSUB 3000
  30. 261 PRINT,"**************************************"
  31. 262 PRINT,"*                                    *"
  32. 263 PRINT,"*    NON COMERCIAL DISTRIBUTION IS   *"
  33. 264 PRINT,"*              WELCOME               *"
  34. 265 PRINT,"*                                    *"
  35. 266 PRINT,"**************************************"
  36. 267 PRINT
  37. 268 GOSUB 3000
  38. 270 REM
  39. 280 CLS
  40. 290 X=RND(10)
  41. 300 OPEN"R",#1,"CHARACTE.RS",255
  42. 310 FIELD 1,255 AS B$
  43. 320 GET#1,1
  44. 330 NC=VAL(B$)
  45. 340 PRINT"     You are in the outer chamber of the hall of the guild of"
  46. 350 PRINT"free adventurers.  Many men and women are guzzling beer and"
  47. 360 PRINT"there is loud singing and laughter.  On the north side of the"
  48. 370 PRINT"chamber is a cubbyhole with a desk.  Over the desk is a sign"
  49. 380 PRINT"which says 'REGISTER HERE OR ELSE!'."
  50. 390 PRINT:PRINT:PRINT"Do you go over to the desk or join the men drinking the beer?"
  51. 400 PRINT"(hit 'D' for desk or 'M' for men)   ";
  52. 410 A$=INKEY$:IF A$="" THEN 410
  53. 420 IF A$="d" OR A$="D" THEN 500
  54. 430 IF A$<>"m" AND A$<>"M" THEN 410
  55. 440 PRINT A$:FOR I=1 TO 22:PRINT:NEXT I
  56. 450 PRINT"     As you go over to the men, you feel a sword being thrust"
  57. 460 PRINT"through your back and you hear someone say, 'You really must"
  58. 470 PRINT"learn to follow directions!'":END
  59. 480 REM
  60. 490 REM
  61. 500 PRINT A$:FOR I=1 TO 12:PRINT:NEXT I
  62. 510 PRINT"     You are greeted there by a burly Irishman who looks at you with a"
  63. 520 PRINT"scowl and asks you, 'What's your name?'"
  64. 530 PRINT:PRINT"You give him your name (type it now)    ";
  65. 540 INPUT TNAME$
  66. 550 PRINT:IF TNAME$<>"" THEN 600
  67. 560 PRINT"     He pulls out a sword and begins to sharpen it  saying,"
  68. 570 PRINT"'Beware the blud stains on the floor.  They belong to a poor"
  69. 580 PRINT"lad who came in last week and wonna give me his name.'"
  70. 590 PRINT:PRINT:GOTO 530
  71. 600 IF LEN(TNAME$)<=30 THEN 630
  72. 610 PRINT"    He scowls at you and says, 'Yer name's too long fer me book."
  73. 620 PRINT"I canna use more than thirty letters.'":PRINT:PRINT:GOTO 530
  74. 630 A1$="":FOR I=1 TO LEN(TNAME$)
  75. 631 A1$=A1$+ CHR$( ASC(MID$(TNAME$,I,1)) - ABS(MID$(TNAME$,I,1)>="a" AND MID$(TNAME$,I,1)<="z")*32)
  76. 632 NEXT I:T1$=TNAME$:TNAME$=A1$
  77. 635 PRINT"    He starts to look through his book, muttering to himself about"
  78. 670 PRINT"'Strange Saxon names'";
  79. 675 IF T1$<>TNAME$ THEN PRINT", and something about people who don't use caps lock." ELSE PRINT "."
  80. 700 PRINT
  81. 710 FOR R=1 TO NC:GET#1,R+1
  82. 720 IF LEFT$(B$,1)="," THEN 770
  83. 730    FOR I=1 TO LEN(B$)
  84. 740       IF MID$(B$,I,1)="," THEN 760
  85. 750    NEXT I:PRINT"SYSTEM ERROR, BAD FILE DATA":STOP
  86. 760    IF TNAME$= LEFT$(B$,I-1) THEN 880
  87. 770 NEXT R:PRINT"    He looks at you and says, 'Yer names na here.  Have ye given it to me"
  88. 790 PRINT"aright?'      How do you answer (Hit 'Y' or 'N' ) ";
  89. 800 A$=INKEY$:IF A$="" THEN 800
  90. 810 IF A$<>"n" AND A$<>"N" THEN 830
  91. 820 PRINT A$:PRINT:PRINT"     He says, 'Well try again!'":PRINT:GOTO 530
  92. 830 IF A$<>"y" AND A$<>"Y" THEN 800
  93. 840 PRINT A$:PRINT:PRINT"    He hits his forehead and says 'Ah, ye must be new here!"
  94. 850 PRINT"Well, wait just a minute and I'll bring someone out to take care of ye.'":PRINT
  95. 870 GOSUB 920 :RUN"NEWGUY"
  96. 880 PRINT:PRINT:PRINT"    He looks up and says, 'Ah, here ye be!  Well, go and have fun in the Hall!'":PRINT
  97. 900 GOSUB 920:RUN"MAINHALL"
  98. 910 STOP
  99. 920 OPEN "O",#2,"ADVENTUR.ER"
  100. 930 PRINT#2,TNAME$+","+STR$(R)
  101. 940 CLOSE #2
  102. 950 RETURN
  103. 3000 FOR I=1 TO 6:PRINT:NEXT I
  104. 3265 FOR I=1 TO 500:A$=INKEY$:IF A$=CHR$(27) THEN 3270
  105. 3266 NEXT I
  106. 3270 FOR I=1 TO 12:PRINT:NEXT I
  107. 3280 RETURN
  108.