home *** CD-ROM | disk | FTP | other *** search
/ Shareware Overload / ShartewareOverload.cdr / games / cycle.zip / CYCLE.BAS next >
BASIC Source File  |  1983-04-25  |  4KB  |  118 lines
  1. 10 KEY OFF:CLS
  2. 20  DIM I2(14),I$(84)
  3. 30  REM  INITIALIZATION OF RANDOM FUNCTION
  4. 40  LOCATE 1,1 
  5. 50 I$ = "R.ARM L.ARM R.LEG L.LEG BACK  NECK  SKULL RIBS  KNEE  BUTT  FACE  PELVISPRIDE BIKE  "
  6. 60 T = .1
  7. 70  REM  T IS RATE OF JUMP CALCULATION
  8. 80 T2 = 0
  9. 90 T3 = 0
  10. 100  LOCATE 1,1 : PRINT 
  11. 110  PRINT "WE'RE AT THE SCENE OF THE BIG MOTORCYCLE JUMP!"
  12. 120  PRINT : PRINT "JUMP YOUR BIKE FROM ONE RAMP OVER": PRINT "ANY NUMBER OF BUSES AND LAND ON THE"
  13. 130  PRINT "OTHER RAMP, MISS AND BOTH BONES & BIKE WILL BREAK"
  14. 140  PRINT : INPUT "HOW MANY BUSSES WILL YOU TRY TO JUMP? ";N
  15. 150  IF N > 40 THEN 1140
  16. 160 J = N * 15
  17. 170  PRINT N;" BUSSES?  THAT'S ";J;" FEET!"
  18. 180  PRINT 
  19. 190  INPUT "WHAT RAMP ANGLE WILL YOU USE? ";A2
  20. 200  PRINT 
  21. 210  IF A2 < 89 AND A2 > 0 THEN 240
  22. 220  PRINT A2;" DEGREES?  THAT'S IMPOSSISBLE. COME ON NOW, "
  23. 230  GOTO 190
  24. 240 A = A2 * .01745
  25. 250  INPUT "HOW FAST WILL YOU LEAVE THE RAMP? ";S
  26. 260  PRINT "      GOOD LUCK!"
  27. 270  IF S > 0 THEN 310
  28. 280  PRINT "A PRACTICE JUMP!"
  29. 290  PRINT "OK,  THIS TIME."
  30. 300  GOTO 250
  31. 310 H = 6
  32. 320 D = 0
  33. 330 G = 6
  34. 340 R2 = 0
  35. 350 S2 = 0
  36. 360 S = S * 1.5
  37. 370  PRINT
  38. 380  PRINT "THERE HE GOES!!!!!!"
  39. 390  REM  JUMP CALCULATION LOOP
  40. 400 LOCATE 20,1:PRINT "/"+STRING$(N,254)+"\";
  41. 410 S = S - S2
  42. 420 F = S * T
  43. 430 D2 = F *  COS (A)
  44. 440 R = F *  SIN (A)
  45. 450 R2 = R2 + (32 * T)
  46. 460 R3 = R2 * T
  47. 470 H = H + R - R3
  48. 480 D = D + D2
  49. 490 LOCATE 19,1:PRINT SPACE$(79);
  50. 500 HZ=INT(D/15):IF HZ>78 THEN HZ=78 ELSE IF HZ<1 THEN HZ=1
  51. 510 LOCATE 19,HZ:PRINT "o+o";
  52. 520  REM  S2 IS DRAG FACTOR
  53. 530 S2 = (S / 120) * 32 * T
  54. 540  IF D >  = J THEN G = G - R
  55. 550  REM  CALCULATE HEIGHT ABOVE GROUND (ALLOW FOR OFFRAMP)
  56. 560  IF G <  = 0 THEN G = 0
  57. 570  IF H > G THEN 410
  58. 580  PRINT 
  59. 590  IF D < J THEN 680
  60. 600  PRINT:PRINT "HE JUMPED ";D;" FEET"
  61. 610  PRINT "THE DISTANCE WAS ";J;" FEET
  62. 620  IF D > J + 20 THEN 730
  63. 630 L = ((D - J) / 30) +  RND (1)
  64. 640  IF L > .8 THEN 740
  65. 650  PRINT:PRINT "HE MADE IT!!  GREAT JUMP, KILLER! "
  66. 660 T2 = T2 + 1
  67. 670  GOTO 1060
  68. 680  PRINT:PRINT "HE'S SHORT OF THE RAMP ......."
  69. 690  PRINT "HE ONLY JUMPED ";D;" FEET
  70. 700  REM  CALCULATION OF INJURIES
  71. 710 L2 =  INT ((((J - D) / 5) * 2) + ( RND (1) * 5) + .5)
  72. 720  GOTO 770
  73. 730  PRINT:PRINT "HE JUMPED TOO FAR!"
  74. 740  PRINT "HE MISSED THE RAMP."
  75. 750  IF D > J + 50 THEN 1170
  76. 760 L2 =  INT (((D + 20 - J) / 20) + ( RND (1) * 5))
  77. 770  PRINT "I THINK HE'S HURT ........."
  78. 780  FOR XX = 1 TO 2500: NEXT XX
  79. 790  FOR K = 1 TO 14
  80. 800 I2(K) = K
  81. 810  NEXT K
  82. 820 K2 = 14
  83. 830  IF L2 > 14 THEN L2 = 14
  84. 840  IF L2 <  = 0 THEN L2 = 1
  85. 850  REM  LISTING OF INJURIES
  86. 860  REM  RANDOM PERMUTATION OF LENGTH OF L2
  87. 870  FOR K = 1 TO L2
  88. 880 V =  INT ( RND (0) * 1000)
  89. 890 V = (V - ( INT (V / K2) * K2)) + 1
  90. 900 H2 = I2(V)
  91. 910 I2(V) = I2(K2)
  92. 920 I2(K2) = H2
  93. 930 K2 = K2 - 1
  94. 940  NEXT K
  95. 950  PRINT
  96. 960  PRINT "WELL ... KILLER, THE DOCTOR SAYS YOU BROKE YOUR ";
  97. 970  REM  GET SPECIFIC INJURIES LIST
  98. 980  FOR K = (15 - L2) TO 14
  99. 990 P = (6 * I2(K)) - 5
  100. 1000 A$ =  MID$ (I$,P,6)
  101. 1010  PRINT ", "+A$;
  102. 1020 CNT.INJ=CNT.INJ+1:IF CNT.INJ>3 THEN K=14
  103. 1030  NEXT K
  104. 1040 CNT.INJ=0
  105. 1050  PRINT : PRINT "HOPE YOU GET WELL SOON."
  106. 1060 T3 = T3 + 1
  107. 1070  PRINT 
  108. 1080  PRINT "WANT TO JUMP AGAIN(Y/N)? ": INPUT A$
  109. 1090  IF A$ = "Y" OR A$="y" THEN 1130
  110. 1100  PRINT "YOU MADE IT ";T2;" OUT OF ";T3;" TIMES."
  111. 1110  PRINT "BETTER LUCK NEXT TIME"
  112. 1120  END 
  113. 1130  LOCATE 1,1 :CLS: PRINT : GOTO 140
  114. 1140  PRINT 
  115. 1150  PRINT "THAT IMPOSSIBLE!"
  116. 1160  GOTO 140
  117. 1170 PRINT " ADIOS ":END
  118. 30  LOCATE 1,1 :CLS: PRINT : GOTO