home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Shareware Overload
/
ShartewareOverload.cdr
/
games
/
bullseye.zip
/
BULLSEYE.BAS
Wrap
BASIC Source File
|
1987-06-24
|
2KB
|
41 lines
240 PRINT TAB(32);"BULLSEYE"
250 PRINT TAB(15);"CREATIVE COMPUTING MORRISTOWN, NEW JERSEY"
260 PRINT:PRINT:PRINT
270 PRINT "IN THIS GAME, UP TO 20 PLAYERS THROW DARTS AT A TARGET"
280 PRINT "WITH 10, 20, 30, AND 40 POINT ZONES. THE OBJECTIVE IS"
290 PRINT "TO GET 200 POINTS.": PRINT
300 PRINT "THROW",TAB(20);"DESCRIPTION";TAB(45);"PROBABLE SCORE"
310 PRINT "1";TAB(20);"FAST OVERARM";TAB(45);"BULLSEYE OR COMPLETE MISS"
320 PRINT "2";TAB(20);"CONTROLLED OVERARM";TAB(45);"10, 20 OR 30 POINTS"
330 PRINT"3";TAB(20)"UNDERARM";TAB(45);"ANYTHING":PRINT
340 DIM A$(20),S(20),W(10): M=0 :R=0:FOR I=1 TO 20: S(I)=0:NEXT I
350 INPUT "HOW MANY PLAYERS";N:PRINT
360 FOR I=1 TO N
370 PRINT "NAME OF PLAYER #";I;:INPUT A$(I)
380 NEXT I
390 R=R+1:PRINT :PRINT "ROUND";R
400 FOR I=1 TO N
410 PRINT :PRINT A$(I)"'S THROW";: INPUT T
420 IF T<0 OR T>3 THEN PRINT "INPUT 1,2 OR 3!": GOTO 410
430 ON T GOTO 440, 450, 460
440 P1=.65:P2=.55: P3=.5: P4=.5: GOTO 470
450 P1=.9899999: P2=.77: P3=.43: P4=.01: GOTO 470
460 P1=.95: P2=.75: P3=.45: P4=.05
470 U=RND(1)
480 IF U>=P1 THEN PRINT "BULLESYE!! 40 POINTS!":B=40:GOTO 540
490 IF T=1 THEN 530
500 IF U>=P2 THEN PRINT "30-POINT ZONE!":B=30: GOTO 540
510 IF U>=P3 THEN PRINT "20-POINT ZONE":B=20: GOTO 540
520 IF U>=P4 THEN PRINT "WHEW! 10 POINTS.":B=10: GOTO 540
530 PRINT "MISSED THE TARGET! TOO BAD.": B=0
540 S(I)=S(I)+B: PRINT "TOTAL SCORE =";S(I): NEXT I
550 FOR I =1 TO N
560 IF S(I)>=200 THEN M=M+1: W(M)=I
570 NEXT I
580 IF M=0 THEN 390
590 PRINT :PRINT "WE HAVE A WINNER!!!":PRINT
600 FOR I=1 TO M:PRINT A$(W(I));"SCORED";S(W(I));"POINTS.":NEXT I
610 PRINT :PRINT "THANKS OR THE GAME.":END
NER!!!":PRINT
600 FOR I=1 TO M:PRINT A$(W(I));"SCORED";S(W(I));"POINTS.":NEXT I
610 PRINT :PRINT "THANKS OR