home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Shareware Overload
/
ShartewareOverload.cdr
/
games
/
alpha.zip
/
SYSAR3W.BAS
< prev
next >
Wrap
BASIC Source File
|
1986-11-09
|
5KB
|
111 lines
10 DEF FNPHLP1(W,WC,D) = -ATN(W/WC)
20 DEF FNPHHP1(W,WC,D) = ATN(WC/W)
30 DEF FNPHLP2(W,WC,D) = -ATN( D*W /(WC*(1.000001-(W/WC)^2 ) ) ) + PI*(W>WC)
40 DEF FNPHHP2(W,WC,D) = ATN( D*WC/(W *(1.000001-(WC/W)^2 ) ) ) - PI*(W<WC)
50 DEF FNAMLP1(W,WC,D) = 1 / SQR(1!+(W/WC)^2)
60 DEF FNAMHP1(W,WC,D) = 1 / SQR(1!+(WC/W)^2)
70 DEF FNAMLP2(W,WC,D) = 1 / SQR(1+(W/WC)^4+(D*D-2!)*(W/WC)^2)
80 DEF FNAMHP2(W,WC,D) = 1 / SQR(1+(WC/W)^4+(D*D-2.000001)*(WC/W)^2)
90 DEF FNDBV(AMP) = 20!*LOG(AMP)/LOG(10!)
100 DEF FNPHD(RAD) = 180!*RAD/PI
110 DEF FNSUMA(AA,AB,PA,PB) = SQR((AA*SIN(PA)+AB*SIN(PB))^2 + (AA*COS(PA)+AB*COS(PB))^2 )
120 DEF FNSUMPW(AA,AB,PA,PB) = SQR((AA*AA*SIN(PA)+AB*AB*SIN(PB))^2 + (AA*AA*COS(PA)+AB*AB*COS(PB))^2 )
130 DEF FNSUMPN(AA,AB,PA,PB) = AA*SIN(PA)+AB*SIN(PB)
140 DEF FNSUMPD(AA,AB,PA,PB) = AA*COS(PA)+AB*COS(PB)
150 DEF FNDIRF(AA,AB,PA,PB) = ABS((SIN((PA-PB))*(((AA >= AB)*AB/AA)+((AB > AA)*AA/AB) )))
160 PI = ATN(SQR(3!))*3
170 DIM FREQT(10)
180 FREQT(1)=20:FREQT(2)=25:FREQT(3)=32:FREQT(4)=40:FREQT(5)=50:FREQT(6)=64:
190 FREQT(7)=80:FREQT(8)=100:FREQT(9)=128:FREQT(10)=160
200 REM Crossover characteristics
210 FCL = 65.1 :QCL = 1.307
215 FCL2 = 65.1 :QCL2 = .543
220 FCH = 65! :QCH = .600
221 print "Enter QCL1 or hit enter for ";QCL
222 input ANS
223 if ans > 0 then QCL = ans
231 print "Enter QCL2 or hit enter for ";QCL2
232 input ANS
233 if ans > 0 then QCL2 = ans
241 print "Enter QCH1 or hit enter for ";QCh
242 input ANS
243 if ans > 0 then QCh = ans
250 REM driver characteristics
255 FLB = 25! :QLB = 1.307
260 FLL = 25! :QLL = .543
270 FLH = 1000.01 :QLH = .15
280 FHL = 45! :QHL = 1.1
290 FHH = 1200!:QHH = 1.1
300 REM Upper driver is dist inches in front of lower driver
310 DIST = 0!
320 REM End of variables
323 WLB = FLB*2*PI
327 DLB = 1!/QLB
330 WCH = FCH*2*PI
340 WCL2 = FCL2*2*PI
345 DCL2 = 1!/QCL2
350 WCL = FCL*2*PI
355 DCL = 1!/QCL
360 DCH = 1!/QCH
370 WLL = FLL*2*PI
380 WLH = FLH*2*PI
390 DLL = 1!/QLL
400 DLH = 1!/QLH
410 WHL = FHL*2!*PI
420 WHH = FHH*2!*PI
430 DHL = 1!/QHL
440 DHH = 1!/QHH
450 GOSUB 790
460 FOR ID = 2 TO 4
470 FOR IO = 1 TO 10
480 IF ID = 5 AND IO > 1 THEN GOTO 770
490 F = FREQT(IO)*10^(ID-2)
500 IF F=1000! THEN GOSUB 790
510 W = F*2!*PI
520 REM basic equations for response
530 LPPHAS = FNPHLP2(W,WCL,DCL) + FNPHLP2(W,WCL2,DCL2) + FNPHLP2(W,WLH,DLH) + FNPHHP2(W,WLL,DLL) + FNPHHP2(W,WLB,DLB)
540 LPGAIN = FNAMLP2(W,WCL,DCL) * FNAMLP2(W,WCL2,DCL2) * FNAMLP2(W,WLH,DLH) * FNAMHP2(W,WLL,DLL) * FNAMHP2(W,WLB,DLB)
550 HPPHAS = FNPHHP2(W,WCH,DCH) + FNPHHP2(W,WHL,DHL) + FNPHLP2(W,WHH,DHH) + DIST * W /(12!*1100)
560 HPGAIN = FNAMHP2(W,WCH,DCH) * FNAMHP2(W,WHL,DHL) * FNAMLP2(W,WHH,DHH)
570 REM
580 DIRC = FNDIRF(HPGAIN,LPGAIN,HPPHAS,LPPHAS)
590 AMPR = FNSUMA(HPGAIN,LPGAIN,HPPHAS,LPPHAS)
591 AMPR = AMPR * FNAMHP2(W,WEL,DEL)^4
600 POWR = FNSUMPW(HPGAIN,LPGAIN,HPPHAS,LPPHAS)
602 POWR = POWR * FNAMHP2(W,WEL,DEL)^4
610 PHASN = FNSUMPN(HPGAIN,LPGAIN,HPPHAS,LPPHAS)
620 PHASD = FNSUMPD(HPGAIN,LPGAIN,HPPHAS,LPPHAS)
630 PHAS = ATN(PHASN/PHASD)
632 rem PHAS = PHAS * FNPHHP2(W,WEL,DEL)*2!
640 IF (PHASN<0! AND PHASD<0!)THEN PHAS = PHAS-PI
650 IF (PHASN>0! AND PHASD<0!)THEN PHAS = PI+PHAS
660 LPAMP = FNDBV(LPGAIN)
670 HPAMP = FNDBV(HPGAIN)
680 AMPRD = FNDBV(AMPR)
690 POWRD = FNDBV(POWR)*.5
700 HPPHAS = FNPHD(HPPHAS)
710 PHASD = FNPHD(PHAS)
720 LPPHAS = FNPHD(LPPHAS)
730 PRINT USING"###### ####.## ####.## ####.## ####.## #.## ###.## ###.## ###.## ####.##";F;LPPHAS;LPAMP;HPPHAS;HPAMP;DIRC;HPPHAS-LPPHAS,AMPRD,POWRD,PHASD
740 NEXT IO
750 NEXT ID
760 PRINT" "
770 rem LIST 200-250
780 STOP
790 PRINT " "
800 PRINT "Lower Crossover (1) at:";FCL;" Q:";QCL
805 PRINT "Lower Crossover (2) at:";FCL2;" Q:";QCL2
810 PRINT "Upper Crossover at:";FCH;" Q:";QCH
820 PRINT " Lower driver (1) lower Fc:";FLL;" Q:";QLL
825 PRINT " Lower driver (2) lower Fc:";FLB;" Q:";QLB
830 PRINT " Lower driver upper Fc:";FLH;" Q:";QLH
840 PRINT " Upper driver lower Fc:";FHL;" Q:";QHL
850 PRINT " Upper driver upper Fc:";FHH;" Q:";QHH
860 PRINT "Upper driver is:";DIST;" Inches in front of lower driver"
870 PRINT " "
880 PRINT " Lower driver Upper driver
890 PRINT " ---------------- --------------
900 PRINT " Freq phase amp,dB phase amp,dB Dirf Ph Diff Vsum Psum Phsum"
910 PRINT "------ ------- -------- ------- ------- ---- ------- ------ ----- -----"
920 RETURN