Shareware Overload/ShartewareOverload.cdr/database/workdb.zip/REPORT.INV

Text File | 1983-01-04 | 4KB | 110 lines

* report.inv 08/18/83
* report menu of inventory program
STORE t TO more
DO WHILE more
    STORE CHR(PEEK (063)) TO dr
    ERASE
    STORE 'Y' TO printer
    STORE 'N' TO wrfile
    STORE '        ' TO filename
    STORE '?' TO command
    @  2, 0 SAY "--------------------------------------------------------------------------------"
    @  2,18 SAY "> > >  R E P O R T  M E N U  < < <"
    @  4,18 SAY "1. Print disk labels"
    @  6,18 SAY "2. Print inventory report"
    @  8,18 SAY "3. Print report of disks shipped and/or ordered"
    @ 10,18 SAY "4. Print requirements report"
    @ 12,18 SAY "5. Display Records on screen"
    @ 14,18 SAY "6. Return to Main Menu"
    @ 16, 0 SAY "--------------------------------------------------------------------------------"
    @ 18,30 SAY "WHAT NEXT"
    @ 18,40 GET command PICTURE '!'
    READ
    IF command  >'1' .AND. command <  '5'
        @ 19,22 SAY "Send Report to the Printer (Y\N)"
        @ 19,55 GET printer PICTURE '!'
        READ
        @ 21,22 SAY "Send Report to a Disk File (Y\N)"
        @ 21,55 GET wrfile PICTURE '!'
        READ
        IF wrfile ='Y'
            @ 21,00
            @ 21,22 SAY "Enter Disk File Name"
            @ 21,44 GET filename PICTURE '!!!!!!!!'
            @ 21,54 SAY "(.TXT will be added )"
            READ
            @ 21,00
            @ 21,22 SAY 'Select drive to put Files on  ' GET dr PICTURE '!'
            READ
            DO WHILE @(dr,'ABCDM') = 0
                @ 21,00
                @ 21,22 SAY 'Select drive to put Files on  ' GET dr PICTURE '!'
                READ
            ENDDO while @dr
        ENDIF wrfile = Y
        IF printer = 'Y'
            @ 23,00 SAY 'Make Printer Ready and hit any key'
            SET CONSOLE OFF
            WAIT
            SET CONSOLE ON
            SET print ON
        ENDIF printer = Y
        IF wrfile = 'Y' .AND. filename <> ' '
            * make a proper REPORT file name that is of type TXT
            STORE @('.',filename) TO length
            IF length = 0 .OR. length > 8
                STORE 9 TO length
            ENDIF length
            STORE $(filename,1,length-1) TO filename
            STORE '&dr.:'+filename+'.TXT' TO filename
            SET ALTERNATE TO &filename
            SET ALTERNATE ON
        ENDIF wrfile
    ENDIF command >1
    ERASE
    DO CASE
        CASE command = '1'
            DO labels.inv
        CASE command = '2'
            DO invent.inv
        CASE command = '3'
            DO ship.inv
        CASE command = '4'
            DO require.inv
        CASE command = '5'
            ERASE
            @ 02,12 SAY 'Records are displayed by Last names'
            @ 05,12 SAY 'You may choose the first letter'
            @ 06,12 SAY 'of the starting location of the records'
            @ 09,12 SAY 'When WAITING hit space bar to'
            @ 10,12 SAY 'Continue... or ESCape to Quit'
            * get a starting point in file
            STORE 'A' TO stletter
            @ 17,12 SAY 'Volume number at which to start display'
            store 0 to stnumber
            @ 17,57 Get stnumber
            READ
            * goto starting point or next if no find
            LOCATE FOR disk = stnumber
            IF EOF
                GOTO TOP
            ENDIF EOF
            * display selected list
            ERASE
            SET ESCAPE OFF
            DISPLAY NEXT 65000 disk, open:inv, back:ord, wait:ship, recvd, norm:stk, order, pend
            IF eof
                WAIT
            ENDIF eof
            SET ESCAPE ON
        CASE (command = '6' .OR. COMMAND = 'Q')
            STORE f TO more
    ENDCASE
    SET PRINT OFF
    SET ALTERNATE OFF
ENDDO while more
RELEASE ALL
STORE t TO more
STORE t TO first
STORE '?' TO command