home *** CD-ROM | disk | FTP | other *** search
/ Shareware Overload / ShartewareOverload.cdr / database / qkwrite.zip / QKWRITE.ASM
Assembly Source File  |  1987-02-22  |  3KB  |  107 lines
  1. ; QKWRITE.ASM    
  2. ;
  3. ; by Dirk Lesko 
  4. ; 
  5. ;
  6. ; Copyright (c) 1987 Dirk Andrew Lesko, All Rights Reserved
  7. ; * modified from a version by Michael Brill
  8. ;
  9.     PAGE     60,132
  10.         PUBLIC  QKWRITE    
  11.     extrn     _ret:far
  12.     include extenda.mac
  13. ;***************************************************
  14. dl_code segment byte public
  15.     assume     cs:dl_code,ds:nothing,es:nothing 
  16. ;---------------------------------------------------
  17. ;
  18. ;       Syntax: call qkwrite with <expN>,<expN>,<expC>,<expN>
  19. ;       Return: nothing
  20. ;       Params: <expN> - integer row
  21. ;        <expN> - integer col
  22. ;        <expC> - character string
  23. ;        <expN> - integer attribute
  24. ;
  25. ;       Notes :    none
  26. ;         
  27. ;                       
  28. ;
  29. ;-----------------
  30. QKWRITE    PROC      FAR
  31.     
  32.     push    bp        ;save
  33.     mov    bp,sp        ;
  34.     push    ds        ; Clippers
  35.     push    es        ;  registers
  36.       
  37.     get_pcount        ;how many params ?
  38.     cmp    ax,4        ;are their 4 ?
  39.     je    _cont        ; yes, go on
  40.     jmp    _done        ;  no go home
  41. _cont:
  42.     get_int 4        ;get attribute
  43.     push    ax        ; save it
  44.     get_char 3        ;get string
  45.     push    bx        ; and
  46.     push    ax        ; save it
  47.     get_int 2        ;get col
  48.     push    ax        ; save it
  49.     get_int 1        ;get row
  50.     push    ax        ; save it
  51.  
  52.     pop    ax        ;get row
  53.     mov    bl,160        ;160 bytes per row 
  54.     mul    bl        ; so multiply by that amount    
  55.     pop    cx        ;get column
  56.     shl    cx,1            ; ready it for screen offset
  57.     add    cx,ax        ; this is our offset into screen buffer
  58.     mov    di,cx        ;  di is dest. index of screen buffer
  59.     pop    ds        ;get string segment
  60.     pop    si        ;get string offset
  61.  
  62.     mov    ax,0b000h    ;assume mono 
  63.     mov    es,ax        ; screen buffer
  64.     cld            ;clear out the direction flag
  65.  
  66.     mov    ah,15        ;lets check monitor type
  67.     int    10h        ;video interrupt
  68.     cmp    al,7        ;is this mono?
  69.     pop    ax        ;(sneak the attribute in here)
  70.     xchg    ah,al        ; (and put it into ah)
  71.     je    _mono        ; if mono, go write the string 
  72.     mov    bx,0b800h    ;  otherwise, setup for color
  73.     mov    es,bx        ;   screen buffer
  74.     mov    dx,3dah        ;check this port for vertical retrace
  75.     jmp short _color    ;continue on for color 
  76.  
  77. _mono:    lodsb            ;get next byte of string, put in al
  78.     cmp    al,0        ;if null, end of string....
  79.     jz    _done         ;....so return to caller 
  80.     cmp    di,4000        ;if end of screen buffer.....
  81.     ja      _done        ;....return to caller too
  82.     stosw            ;if not null, word byte to monitor ram
  83.     jmp    _mono         ;and return for the next character
  84. _color:
  85.     in     al,dx          ;read in vertical retrace status
  86.     test    al,8        ;if retrace bit is set on....
  87.     je     _color         ;....go back and re-poll bit
  88.     lodsb            ;get next byte from string, put in al
  89.     cmp    al,0        ;if null, end of string......
  90.     jz    _done         ;....so return to caller 
  91.     cmp    di,4000        ;are we at the end of the screen?
  92.     ja    _done        ; yes, so we're done
  93.     stosw              ;otherwise, write word to monitor ram
  94.     jmp    _color        ;and return for the next character
  95. _done:
  96.     pop    es        ;restore
  97.     pop     ds        ; Clippers
  98.     pop     bp        ;  registers
  99.  
  100.     call _ret        ;let Clipper check stack
  101.     ret            ;far return to Clipper
  102. QKWRITE    ENDP
  103. ;-----------------------------------------------------------
  104. dl_code ends 
  105. ;***********************************************************
  106.         END  
  107.