Shareware Overload/ShartewareOverload.cdr/database/dbdict.zip/DICT.ADD

Text File | 1986-02-17 | 4KB | 132 lines

* DICT.ADD
* Paul Ferrara [70075,252]
* Bill Lonborg [70045,1237]
* Last Change: 02-17-86 00:05
*
SET COLOR TO &mtitl./&mnorb.,&menhf./&menhb.,&mbord
CLEAR
@  1, 0 SAY "ADD FILES TO THE DICTIONARY"
@  1,72 SAY date()
@  2, 0 SAY "═══════════════════════════════════════════════════════"
@  2,55 SAY "═════════════════════════"
SET COLOR TO &mnorf./&mnorb.,&menhf./&menhb.,&mbord
@  4, 4 SAY "Enter filename"
@  5, 4 SAY "File Description"
@  7, 4 SAY "Field #"
@  8, 4 SAY "Field name"
@  9, 4 SAY "Field type"
@ 10, 4 SAY "Field length"
@ 11, 4 SAY "Decimals places"
@ 12, 4 SAY "Field description"
@ 14,31 SAY "Select option"
@ 15, 0
SET COLOR TO &mtitl./&mnorb.,&menhf./&menhb.,&mbord
DIR *.DBF
@ row()-1, 0
@ row()-1, 0
@ 23, 0 SAY "═══════════════════════════════════════════════════════"
@ 23,55 SAY "═════════════════════════"
@ 24,16 SAY "1=next file  2=delete this file  0=exit to menu"
SET COLOR TO &mnorf./&mnorb.,&menhf./&menhb.,&mbord
SELECT 1
USE dbstru
IF .NOT. FILE("DICTNARY.DBF")
   COPY STRUCTURE TO dictnary
ENDIF
SELECT 2
USE dictnary
STORE 1 TO choice
DO WHILE .NOT. choice=0
   STORE SPACE(8) TO mfileinput
   @  4,22 GET mfileinput PICTURE "!!!!!!!!"
   READ
   * test filename
   STORE TRIM(mfileinput)+".DBF" TO mfilename
   IF .NOT. FILE(mfilename)
      * say file not found
      SET COLOR TO &mblnk.*/&mnorb.,&menhf./&menhb.,&mbord
      @ 21,31 SAY "Invalid filename."
      SET COLOR TO &mmess./&mnorb.,&menhf./&menhb.,&mbord
      @ 22,19 SAY "Press 'Q' to quit, or any key to continue."
      SET COLOR TO &mnorf./&mnorb.,&menhf./&menhb.,&mbord
      SET CONSOLE OFF
      WAIT TO option
      SET CONSOLE ON
      IF UPPER(option)="Q"
         EXIT
      ELSE
         @ 21, 0
         @ 22, 0
         LOOP
      ENDIF
   ELSE
      * say please wait
      SET COLOR TO &mblnk.*/&mnorb.,&menhf./&menhb.,&mbord
      @ 21,34 SAY "Please wait."
      SET COLOR TO &mnorf./&mnorb.,&menhf./&menhb.,&mbord
      SELECT 10
      USE &mfileinput
      COPY STRUCTURE EXTENDED TO temp.str
      SELECT dbstru
      COPY STRUCTURE TO temp
      SELECT 9
      USE temp
      APPEND BLANK
      REPLACE field_type WITH "X"
      APPEND FROM temp.str
      ERASE temp.str
      REPLACE ALL file_name WITH mfileinput
      @ 21, 0
      GO TOP
      @  5,22 GET field_desc
      READ
      SKIP
      STORE 0 TO mcounter
      DO WHILE .NOT. EOF()
         STORE mcounter+1 TO mcounter
         SET COLOR TO &mtitl./&mnorb.,&menhf./&menhb.,&mbord
         @  7,22 SAY mcounter PICTURE "999"
         @  8,22 SAY field_name
         @  9,24 SAY field_type
         @ 10,22 SAY field_len
         @ 11,22 SAY field_dec
         SET COLOR TO &mnorf./&mnorb.,&menhf./&menhb.,&mbord
         @ 12,22 GET field_desc
         READ
         SKIP
      ENDDO
      @ 14,45 GET choice PICTURE "9" RANGE 0,2
      READ
      IF choice=2
         *
         SELECT temp
         USE
         SET COLOR TO &mblnk.*/&mnorb.,&menhf./&menhb.,&mbord
         @ 21,33 SAY "File omitted."
         SET COLOR TO &mnorf./&mnorb.,&menhf./&menhb.,&mbord
         @ 14,45 GET choice PICTURE "9" RANGE 0,1
         READ
      ELSE
         * append to dictnary.dbf
         SET COLOR TO &mblnk.*/&mnorb.,&menhf./&menhb.,&mbord
         @ 21,34 SAY "Please wait."
         SET COLOR TO &mnorf./&mnorb.,&menhf./&menhb.,&mbord
         SELECT temp
         USE
         SELECT dictnary
         LOCATE FOR file_name=mfileinput
         IF .NOT. EOF()
            DELETE WHILE file_name=mfileinput
         ENDIF
         APPEND FROM temp
         @ 21, 0
      ENDIF
   ENDIF
ENDDO
CLOSE DATABASES
IF FILE("TEMP.DBF")
   ERASE temp.dbf
ENDIF
CLEAR
RETURN