home *** CD-ROM | disk | FTP | other *** search
/ Shareware Overload / ShartewareOverload.cdr / database / dbbooks.zip / CHECKS.CMD < prev    next >
OS/2 REXX Batch file  |  1987-02-14  |  3KB  |  118 lines
  1. ************************************ CHECKS.CMD
  2. **************** Write checks.
  3. ERASE
  4. SET TALK OFF
  5. ? "Preparing checks file"
  6. ?
  7. ? "Load checks into printer"
  8.  
  9. ***************** Save existing memory variables to THOUGHT,
  10. ***************** and bring in English-equivalent variables.
  11. SAVE TO THOUGHT
  12. RESTORE FROM ENGLISH
  13.  
  14. *************** Create little file of checks to be written.
  15. USE TRANS INDEX ACCT
  16. COPY TO TEMP FOR CHECK:NO>0 .AND. .NOT. WRITTEN
  17. USE TEMP
  18. INDEX ON CHECK:NO TO CHECKNOS
  19. GO TOP
  20. ? 
  21. ? "First check to be printed will be ",CHECK:NO 
  22. ? 
  23. ?
  24. ? "Press any key to begin writing checks"
  25. WAIT
  26.  
  27. ERASE
  28. *SET PRINT ON
  29. DO WHILE .NOT. EOF
  30.  
  31.    ************ Translate AMOUNT to English.
  32.    STORE 1 TO COUNTER,START
  33.    STORE STR(AMOUNT,9,2) TO STRING
  34.  
  35.    ****************************** Loop through thousands and hundreds. 
  36.    DO WHILE COUNTER < 3
  37.  
  38.       ************************** Split out hundreds, tens, and ones.
  39.       STORE $(STRING,START,3) TO CHUNK
  40.       STORE $(CHUNK,1,1) TO HUN
  41.       STORE $(CHUNK,2,2) TO TEN
  42.       STORE $(CHUNK,3,1) TO ONE
  43.  
  44.       ********************* Handle hundreds.
  45.       IF VAL(CHUNK) > 99
  46.          STORE ENGLISH + U&HUN + ' HUNDRED ' TO ENGLISH
  47.       ENDIF (chunk > 99)
  48.  
  49.       ********************* Handle second 2 digits.
  50.       STORE VAL(TEN) TO T
  51.       IF T > 0
  52.  
  53.         DO CASE
  54.  
  55.          ********** Case 1: Handle teens or even tens.
  56.          CASE (INT(T/10.0)=T/10.0) .OR. (T>9 .AND. T<20)
  57.               STORE ENGLISH + U&TEN TO ENGLISH
  58.  
  59.          ********** Case 2: Handle greater than 10 but not evenly divisible.
  60.          CASE T > 9 .AND. (INT(T/10.0)#T/10.0)
  61.               STORE $(TEN,1,1) +'0' TO TEN
  62.               STORE ENGLISH + U&TEN+' '+U&ONE TO ENGLISH
  63.  
  64.          ********** Case 3: Handle less than 10.
  65.          CASE T < 10
  66.               STORE ENGLISH + U&ONE TO ENGLISH
  67.  
  68.       ENDCASE
  69.  
  70.      ENDIF (T > 0)
  71.  
  72.      **************** Add "Thousand" if necessary.
  73.      IF AMOUNT > 999.99 .AND. COUNTER = 1
  74.         STORE ENGLISH+' THOUSAND ' TO ENGLISH
  75.      ENDIF (need to add "thousand")
  76.  
  77.      **************** Prepare for pass through hundreds.
  78.      STORE 4 TO START
  79.      STORE COUNTER+1 TO COUNTER
  80.  
  81.    ENDDO (while counter < 3.) 
  82.  
  83.    ***************** Tack on cents.
  84.    IF INT(AMOUNT) > 0    
  85.       STORE ENGLISH + " AND " TO ENGLISH
  86.    ENDIF
  87.  
  88.    STORE ENGLISH + $(STRING,8,2)+"/100" TO ENGLISH
  89.  
  90.    ? "                          ",DATE
  91.    ?
  92.    ? "   ",TO:WHOM,"     ",AMOUNT
  93.    ?
  94.    ? "  ",ENGLISH
  95.    ?
  96.    ?
  97.    ?
  98.    ?
  99.    ?
  100.    SKIP
  101.    STORE " " TO ENGLISH
  102. ENDDO   
  103. SET PRINT OFF
  104. ************************ Flag checks as written in TRANS
  105. USE TRANS
  106. REPLACE ALL WRITTEN WITH Y FOR CHECK:NO>0
  107. USE
  108.  
  109. ***************** Get rid of "English" memory
  110. ***************** variables, and bring back originals.
  111. RELEASE ALL
  112. RESTORE FROM THOUGHT
  113.  
  114. RETURN
  115.  
  116.  
  117.  
  118.