home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Shareware Overload
/
ShartewareOverload.cdr
/
comm
/
zcm_scrp.zip
/
GEFDL.T
< prev
next >
Wrap
Text File
|
1989-11-21
|
2KB
|
86 lines
:: Download a file from GEnie page given in s7 - see info at end REV 8-08-89
pat
open %item
dis -g
try2: grab s0
set ifs " "
split s0
if !%z0 goto done
setc s1 "\L%z1"
if !t goto failed
pq200
put "m %s7:3\r"
pat 1 "Enter #"
pat 2 "Item #"
wait
put "6\r"
again: pat 1 "Enter"
wait
put "%z0\r"
pat 1 "D>ownload"
pat 3 "Try again (Y/N)"
wait
if 3 put "N\r"; goto failed
put "d\r"
pat 2c "3. YMODEM"
pat 3 "Which item"
pat 4c "4. ZMODEM"
wait -f20
estimate z5
if 4 put "4\r"; set adlopts "r"; wait -T99; goto diddl
if f%s1 echo "%s1 Exists: Skipping File"; put "\r"; goback try2
put "3\r"
pat 3 "file!"
wait -f20
pat
p?0
rb -y
diddl:
if !? goto fail
pat 2 "another"
wait
try3: grab s0
split s0
if !%z0 goto done0
if !t goto done0
setc s1 "\L%z1"
put "y\r"; goback again
done0: put "n\r"
done: echoc "Processing of %item finished."
obey "!mv %item dow/done"
echoc "%item moved to dow/done"
pat 1 "Enter #"
pat 2 "Item #"
wait -f15
ena -gt
echoc "gefdl.t Finished"
return
fail: echoc "%s1 Download FAILED"
closetx
ena -gt
if !c fail
return
failed: echoc "gefdl.t FAILED: bad control file"
closetx
ena -gt
obey "!mv %item dow/failed"
echoc "%item moved to dow/failed"
return
************************************************************************
This script is called from the main GEnie script as:
set s7 "615"
expand %lib/gefdl.t dow/G615*
with the control files being in the "dow" subdirectory. "dow" must
itself have "done" and "failed" subdirectories. Control files have
one or more lines taken verbatim from the GEnie files listing:
6016 WEFAX.ARC X PJSPELLMAN 870830 39060 18 4
6005 ZANSI1.ARC X WHEISER 870830 34020 65 5
5952 ZD12.ARC X SHANNON 870825 27720 98 5
The files are fetched by their GEnie directory number, and are downloaded
to the filename given in the directory line. If the file already exists,
the download is skipped unless ZMODEM is available. ZMODEM downloads use
the -r option for Crash Recovery.