home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Shareware Overload
/
ShartewareOverload.cdr
/
comm
/
zcm_scrp.zip
/
CBBSCK.BAS
< prev
next >
Wrap
BASIC Source File
|
1989-11-21
|
1KB
|
38 lines
20 Rem Rev 9-05-84
50 PRINT "Check format of a file to upload to CBBS as a message using the"
53 PRINT "cbbs-r directory entry (Assumes CBBS has eXpert+Prompt set)"
70 PRINT
100 PRINT "Enter Pathname :";
150 LINE INPUT F$
195 ON ERROR GOTO 990
200 OPEN F$ FOR INPUT AS #1
240 PRINT
250 IF EOF(1) THEN PRINT "No To: line" : GOTO 950
300 LINE INPUT #1, A$
310 PRINT "To: "; A$
320 IF LEN(A$) > 24 THEN PRINT "To: line too long" : GOTO 950
330 IF EOF(1) THEN PRINT "No Subj: line" : GOTO 950
335 LINE INPUT #1, S$
336 PRINT "Subject: "; S$
340 IF LEN(S$) > 24 THEN PRINT "Subject line too long" : GOTO 950
345 IF EOF(1) THEN PRINT "No Password line" : GOTO 950
350 LINE INPUT #1, P$
355 PRINT "Password: ";P$
357 IF LEN(P$) = 0 THEN GOTO 400
360 IF LEN(P$) <> 4 THEN PRINT "Password must be 4 chars EXACTLY" : GOTO 950
400 FOR I = 1 TO 21
430 IF EOF(1) THEN 800
450 LINE INPUT #1, L$
460 PRINT L$
500 IF LEN(L$) > 80 THEN print : PRINT "Text line too long" : GOTO 950
600 NEXT I
650 print : PRINT "Too many lines in message"
655 goto 950
800 IF LEN(L$) > 0 THEN print : PRINT "Last line not empty" : GOTO 950
900 PRINT : PRINT "Messages file "; F$;" looks O.K."; : goto 999
949 PRINT
950 print chr$(7) : print "This won't hack it.", chr$(7)
960 GOTO 999
990 print : PRINT F$;" File not found"
999 SYSTEM