home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Shareware Overload
/
ShartewareOverload.cdr
/
comm
/
tm211_1.zip
/
QBBS-A.SCR
< prev
next >
Wrap
Text File
|
1990-05-25
|
2KB
|
76 lines
;
; QBBS-A.SCR, this is an advance version of QBBS.SCR
;
; It bypasses the 'Press [Enter] to continue' prompt and
; perform SEAlink auto download
;
ON = 1
OFF = 0
AutoDownload = ON ; set this to OFF if you
; don't need Auto Download SEAlink
when "Press [Enter]","~^M" ; set response strings
when "Press <Enter>","~^M"
name="first last" ; put your name here
count = 1
repeat ; wait for log on prompt
waitfor "last name?","processing mail",2
if not found
put "^[~S"
endif
if found=2 ; if BBS is processing mail
alarm "Processing mail" ; then alarm, hangup and stop
hangup
stop
endif
if count=20 ; quit if no response in 60 seconds
alarm "No response in 60 seconds"
hangup
stop
endif
count = count+1
until found
put name,"^M", ; put name
repeat ; wait for password request
waitfor "password",5
if not found
put
endif
until found
put "^&" ; put password (defined in Dial window)
delay 10 ; try going to main menu
put "S"
waitfor "Sorry, no new mail to you.",5
put
if AutoDownload ; if ON then wait for download prompt
while connected
waitfor "protocol:",15
if found
waitfor "sealink",5
if found
waitfor "send","last chance",5
if found
if found=2 ; test for FileDoor
put "~^M",
waitfor "receiving",5
endif
endif
if found
delay 20
receive "s" ; receive SEAlink
endif
endif
endif
endwhile
else
repeat ; wait until disconnected
until not connected ; make use of the WHEN "Press ..."
endif