home *** CD-ROM | disk | FTP | other *** search
/ Shareware Overload / ShartewareOverload.cdr / comm / tm211_1.zip / OPUS-A.SCR < prev    next >
Text File  |  1990-05-25  |  2KB  |  81 lines
  1. ;
  2. ; OPUS-A.SCR, this is an advance version of OPUS.SCR
  3. ;
  4. ; 1. Check if BBS is processing mail
  5. ; 2. Quick log on by sending Ctrl-C and ESC to bypass welcome message
  6. ; 3. Go to message section and read messages automatically
  7. ; 4. Simulate Auto Download feature for SEAlink, Telink and Modem7
  8. ; 5. Automatically send ENTER key when you are told to do so
  9. ;
  10.  
  11. name = "first last"          ; put your name here
  12.  
  13. ON = 1
  14. OFF = 0
  15.  
  16. AutoDownload = ON            ; set this to OFF if you don't need
  17.                              ;  Auto Download SEAlink, Telink and Modem7
  18.  
  19. when "Press ENTER to continue","^M"
  20. when "try again","q^M"       ; set response strings
  21.  
  22. count = 1
  23. repeat                       ; wait for log on prompt
  24.   waitfor "first name","processing mail",2
  25.   if not found
  26.     put "^C~^["              ; put ^C, Esc, Enter
  27.   endif
  28.   if found=2                 ; if BBS is processing mail
  29.     alarm "Processing mail"  ; then alarm, hangup and stop
  30.     hangup
  31.     stop
  32.   endif
  33.   if count=20                 ; quit if no response in 60 seconds
  34.      alarm "No response in 60 seconds"
  35.      hangup
  36.      stop
  37.   endif
  38.   count = count+1
  39. until found
  40. put name," y"                ; put name and confirm
  41.  
  42. repeat                       ; wait for password request
  43.   waitfor "password",2
  44.   if not found
  45.     put "^C"
  46.   endif
  47. until found
  48. put "^&"                     ; put password (defined in Dial window)
  49.  
  50. repeat                       ; wait for main menu
  51.   waitfor "main menu:",2
  52.   if not found
  53.     put "^C"
  54.   endif
  55. until found
  56. put "m"                      ; select message section
  57. waitfor "select",5
  58. put "="                      ; read messages
  59.  
  60. when "try again",""          ; cancel this WHEN statement
  61.  
  62.  
  63. if AutoDownload              ; if ON then wait for download prompt
  64.    while connected
  65.       waitfor "mode:  sealink","mode:  telink","mode:  modem7",15
  66.       if found
  67.          switch found
  68.             case 1: protocol="s"
  69.             case 2: protocol="t"
  70.             case 3: protocol="m"
  71.          endswitch
  72.          delay 20
  73.          receive protocol
  74.       endif
  75.    endwhile
  76. else
  77.    repeat                    ; wait until disconnected
  78.    until not connected       ; make use of WHEN "Press ENTER ..."
  79. endif
  80.  
  81.