home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Shareware Overload
/
ShartewareOverload.cdr
/
comm
/
qns311.zip
/
QNS.BAT
< prev
next >
Wrap
DOS Batch File
|
1991-02-19
|
5KB
|
165 lines
@echo OFF
cls
:┌──────────────────────────────────────────────────────────────────────────┐
:│ QNS.BAT Copyright 1988-1991 by Rik Brown │
:│ │
:│ QNS.BAT main batch file for Qmodem Networking Script │
:└──────────────────────────────────────────────────────────────────────────┘
:------------------------------------------------------------------------
: BE SURE TO REVISE THE DRIVE/DIRECTORIES TO MATCH YOUR OWN REQUIREMENTS.
:------------------------------------------------------------------------
if [%1]==[] goto ERRORPARM
rem Make environment variables
set QNSMAIL=
set QNS%1=@
if [%QNSMIDI%]==[@] set QNSMAIL=RELAY
if [%QNSMUSIC%]==[@] set QNSMAIL=RNET
if [%QNSSALTAIR%]==[@] set QNSMAIL=RNET
if [%QNSTRAVEL%]==[@] set QNSMAIL=RNET
:----------------------------------------------------------------------------
: You may add/change/delete support for any PCBoard BBS by changing the name
: of the CONFIGFILEs above. For example, the name of the CONFIGFILE embedded
: in [%QNSTRAVEL%] is TRAVEL. For a board with a CONFIGFILE named HOWARD
: and using RNET you could add above the following line:
:
: if [%QNSHOWARD%]==[@] set QNSMAIL=RNET
:----------------------------------------------------------------------------
set QNSCALL=
set QNSIMPORT=
if not [%2]==[] set QNS%2=#
if [%QNSCALL%]==[#] set QNSOPTION=CALL
if [%QNSIMPORT%]==[#] set QNSOPTION=IMPORT
if [%QNSMAIL%]==[RNET] goto RNET%QNSOPTION%
if [%QNSMAIL%]==[RELAY] goto RELAY%QNSOPTION%
if [%QNSMAIL%]==[USER] goto USER
rem Otherwise drop to ERRORPARM
:ERRORPARM
echo Your command: QNS.BAT %1 %2
echo ▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓
echo ▓▓▓┌──────────────────────────────────────────────────────────┐▓▓▓▓
echo ▓▓▓│ (1) (2) │░░▓▓
echo ▓▓▓│ Usage: QNS.BAT CONFIGFILE [IMPORT/CALL/USER] │░░▓▓
echo ▓▓▓│ │░░▓▓
echo ▓▓▓│ PARAMETER 1 The QNS configfile in your Qmodem script │░░▓▓
echo ▓▓▓│ (Required) directory. It must be pre-configured for │░░▓▓
echo ▓▓▓│ the BBS to which you are calling. │░░▓▓
echo ▓▓▓│ │░░▓▓
echo ▓▓▓│ PARAMETER 2 If you are a NETWORK SYSOP who will not │░░▓▓
echo ▓▓▓│ (Optional) be exporting messages (or have already │░░▓▓
echo ▓▓▓│ done so manually or from a previous mail │░░▓▓
echo ▓▓▓│ run) and wish to jump directly to the │░░▓▓
echo ▓▓▓│ network IMPORT or CALL phase of this │░░▓▓
echo ▓▓▓│ batch file, then indicate IMPORT or CALL. │░░▓▓
echo ▓▓▓│ │░░▓▓
echo ▓▓▓│ If you are a USER utilizing an offline │░░▓▓
echo ▓▓▓│ reader to up/download messages, indicate │░░▓▓
echo ▓▓▓│ USER for this parameter. │░░▓▓
echo ▓▓▓│ │░░▓▓
echo ▓▓▓└──────────────────────────────────────────────────────────┘░░▓▓
echo ▓▓▓▓▓▓░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░▓▓
echo ▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓▓
goto end
:----------------------------------------------------------------------------
: Those calling in a non-network sysop capacity should edit the DRIVE &
: DIRECTORY locations between here and the next line to match the proper
: locations on your hard disk.
:USER
C:
cd \QWKMAIL
echo Backing up %1.QWK files....
if exist %1.qwk copy %1.qwk %1.qw1 >nul
if exist %1.qwk del %1.qwk
if exist c:\QWKMAIL\%1.cap del c:\QWKMAIL\%1.cap
R:
cd \QMODEM\SCRIPT
copy %1 Q-SETUP.CFG >nul
R:
cd \QMODEM
QMODEM.EXE /s=Q-SETUP.CMD
goto END
:----------------------------------------------------------------------------
:RELAY
R:
cd \RELAY\NODEMIDI
if not exist IN.RLY goto RELAYEXPORT
echo Backing up IN.RLY files....
if exist IN.RLY copy IN.RLY IN.RL1 >nul
if exist IN.RLY del IN.RLY
goto relayexport
:RELAYEXPORT
R:
cd \RELAY
if exist R:\RELAY\NODEMIDI\TRAVEL.RLY goto RELAYCALL
EXPORT.EXE
goto relaycall
:RELAYCALL
if exist R:\RELAY\NODEMIDI\%1.CAP del R:\RELAY\NODEMIDI\%1.CAP
R:
cd \QMODEM\SCRIPT
copy %1 Q-SETUP.CFG >nul
R:
cd \QMODEM
QMODEM.EXE /s=Q-SETUP.CMD
goto relayimport
:RELAYIMPORT
R:
cd \RELAY\NODEMIDI
if not exist IN.RLY goto end
copy IN.RLY IN.RL1 >nul
R:
cd \RELAY
IMPORT.EXE
goto end
:RNET
C:
cd \RNET
if not exist %1.qwk goto RNETEXPORT
echo Backing up %1.QWK files....
if exist %1.qwk copy %1.qwk %1.qw1 >nul
if exist %1.qwk del %1.qwk
goto rnetexport
:RNETEXPORT
rnet export %1
goto rnetcall
:RNETCALL
if exist c:\rnet\%1.cap del c:\rnet\%1.cap
R:
cd \QMODEM\SCRIPT
copy %1 Q-SETUP.CFG >nul
R:
cd \QMODEM
QMODEM.EXE /s=Q-SETUP.CMD
goto rnetimport
:RNETIMPORT
c:
cd \rnet
if not exist %1.qwk goto end
rnet import %1
goto end
:END
for %%A in (MAIL OPTION CALL IMPORT %1 %2) do set QNS%%A=
echo * * * QNS Routine Completed * * *