home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Shareware Overload
/
ShartewareOverload.cdr
/
comm
/
hpbqmqm.zip
/
HPBQMQM.SCR
Wrap
Text File
|
1991-01-09
|
5KB
|
110 lines
;DOWNLOAD SCRIPT for QMODEM, PCB14.5, and QMAIL4 by Bob Jacobson
; (inspired by Joe Sheppard and Nancy Hattaway)
; PLEASE NOTE - The script will not function properly unless the
; following instructions and settings are followed!
;"Extended prompts" (Option 11) must be turned ON in the Qmail Door
;"1 Second Delay" (Option ) must be turned ON in the Qmail Door
;"Repeat Scanning" (Option ) must be turned ON in the Qmail Door
; AND Expert Mode (enter X, return) must be selected.
;Uses the following Qmodem script variable, which must be set in your
;QMODEM.FON file: $PASSWORD
;If you are using this script from the ALT-F command and do not wish
;to Exit Qmodem after the transfer, then delete the two "System Y"
;commands
;If you intend to use this script as a "linked" script to the dialing
;entry in Qmodem, then delete the "Send "ATH0M0^M" line and delete
;the Dial line as well.
String BBSID FON SIGNON CAPATH PROT MAIL_PATH CONF ; don't change these
;Six board/user specific variables must also be assigned:
Assign SIGNON "Bob Jacobson" ;Your Users Name on the BBS
Assign BBSID HPB ;BBS Qmail Door ID w/out Extension
Assign FON "29" ;Fill in the Qmodem Dir # of the BBS
Assign CAPATH C:\qmodem\ ;Session Log capture file path
Assign PROT Z ;One letter transfer protocol type
Assign MAIL_PATH "D:\PROD\" ;Your path to the QWKS and REPS with trailing \
Assign CONF "0" ;Conference number to open Door from
TimeOut 300 HALT ;5 minutes - do HALT on timeout
Send "ATH0M0^M" ;make sure modem is off-hook & silent
;When <first expression> is true, do <second expression>
When "nter)=yes?" "n^M" ;one form of this
When "ENTER = (Y)es?" "n^M" ;another form of the same
When "no change?" "^M" ;when Enter = no change
When "to continue?" "^M" ;Press Enter to continue
When "More?" "n^M" ;typically, (H)elp, More?
When "messages since" "n^M" ;don't check for messages
When "=no?" "^~n q ns^M" ;no graphics, skip welcome, non-stop
When "continue)?" "N^M" ;Press Enter to continue
When "white" "^~n Q NS^M" ;another no graphics form
CALLOUT:
Capture $CAPATH$BBSID.CAP ;open capture file
Dial "$FON" ;call the BBS
Waitfor "name?"
Send "$SIGNON $PASSWORD^M" ;log on with name and password
Waitfor "Command"
Send "J $CONF^M" ;join proper conference
Waitfor "Command"
Delay 500
Send "QMAIL4^M" ;Open Qmail Door - Change if needed
When ;clear previous When statements
Exist $MAIL_PATH$BBSID.rep UL_SESS ;upload .rep only if it exists
Goto DL_SESS ;otherwise go to download routine
UL_SESS: ;Upload Routine
Waitfor "<COMMAND>"
Send "U^M"
Waitfor "<UPLOAD>"
Delay 500
Upload $PROT $MAIL_PATH$BBSID.rep ;upload .REP file
When "<MESSAGES INSERTED>" DL_SESS ;If successful, delete and backup rep
Goto UL_SESS ;If not successful, repeat upload
DL_SESS:
Waitfor "<COMMAND>"
Send "D;Y^M" ;Download Session Start
DL_CYCLE: ;Cycling through download
When "<NO TRANSFER>" GOODBYE
Waitfor "<DOWNLOAD>"
Delay 1000
Download $PROT $MAIL_PATH ;download .QWK files
When "<REPEAT>" DL_CYCLE ;if multiple QWK's download the rest
GOODBYE:
Waitfor "<COMMAND>"
Send "G^M" ;log off
Turnoff Capture
Waitfor "NO CARRIER"
Hangup
Gosub CLEANUP_REP ;delete and back up rep files
System Y ;Exit QModem and go to Dos
Exit
CLEANUP_REP:
DOS "del $MAIL_PATH$BBSID.bak" ;delete old .BAK
DOS "ren $MAIL_PATH$BBSID.rep $BBSID.bak" ;rename file after u/l
Return
HALT: ;if unsuccessful, halt script
Note Unsuccessful attempt
Note Script halted
Turnoff Capture
Hangup
System Y ;exit Qmodem and go to Dos
Exit