home *** CD-ROM | disk | FTP | other *** search
/ 64'er Special 83 / 64er_Magazin_Sonderheft_83_19xx_Markt__Technik_de_Side_B.d64 / trackwrite (.txt) < prev    next >
Commodore BASIC  |  2022-10-26  |  1KB  |  52 lines
  1. 10 t=37     :rem track
  2. 20 s=12     :rem sector
  3. 30 w=144    :rem schreiben eines blocks
  4. 40 r=128    :rem lesen eines blocks
  5. 70 v=1      :rem verzoegerung bei compilierten programmen (>=10)
  6. 72 poke53280,1:poke53281,1:poke646,0
  7. 74 print"[147]  [211][197][203][212][207][210] [211][195][200][210][197][201][194][197][206] [201][206] [211][208][213][210] 36 [194][201][211] 40 "
  8. 76 print"[210]ichtige [196]iskette einlegen, dann"
  9. 77 print"sechs [194]ildschirmzeilen [212]ext eingeben."
  10. 78 print"[202]ede [218]eile mit <[210][197][212][213][210][206]> abschliessen!"
  11. 80 tx$="":ax$="":gosub2000:rem texteingabe
  12. 100 open1,8,15,"i"
  13. 120 :
  14. 121 rem eintragen informationen in block
  15. 122 :
  16. 130 fori=1tolen(tx$)
  17. 140 x$=mid$(tx$,i,1)
  18. 150 print#1,"m-w"+chr$(i+2)+chr$(3)+chr$(1)+x$
  19. 160 nexti
  20. 170 :
  21. 180 rem schreiben auf diskette
  22. 190 :
  23. 200 p=0:b=w:gosub1000
  24. 380 close1
  25. 390 end
  26. 400 :
  27. 1000 :
  28. 1010 rem parameter an diskcontroller
  29. 1020 :
  30. 1030 rem track und sector fuer puffer 0
  31. 1040 :
  32. 1050 print#1,"m-w"+chr$(6)+chr$(0)+chr$(2)+chr$(t)+chr$(s)
  33. 1060 :
  34. 1070 rem befehlscode lesen oder schreiben fuer puffer 0
  35. 1080 :
  36. 1090 print#1,"m-w"+chr$(0)+chr$(0)+chr$(1)+chr$(b)
  37. 1100 :
  38. 1110 rem warten
  39. 1120 :
  40. 1130 fori=1to5000*v:nexti
  41. 1140 :
  42. 1150 rem returncode
  43. 1160 :
  44. 1170 print#1,"m-r"+chr$(0)+chr$(0)+chr$(1)
  45. 1180 get#1,x$:x=asc(x$+chr$(0))
  46. 1190 return
  47. 2000 print""
  48. 2010 fori=1to6:poke19,64:inputax$:poke19,0:print:ax$=ax$+chr$(13)
  49. 2011 tx$=tx$+ax$:next
  50. 2020 iflen(tx$)<252thenfori=len(tx$)to252:tx$=tx$+chr$(32):next
  51. 2030 return
  52.