home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er Special 69
/
64er_Magazin_Sonderheft_69_19xx_Markt__Technik_de_Side_B.d64
/
setpixel
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2022-10-26
|
1KB
|
48 lines
4 rem ----------------------------
5 rem originalwerte fuer textmodus
6 rem in adressen 251/252 retten
7 rem ----------------------------
10 poke251,peek(53272)
20 poke252,peek(53265)
30 ba=8192:sys58692
40 gosub 1000
119 rem -------------------------
120 rem hires-bildschirm loeschen
121 rem -------------------------
130 for i=ba to ba+7999
140 poke i,0
150 next
160 sys58692
165 gosub 2000: rem textmodus ein
170 input"x-koordinate (0-319)";x
180 input"y-koordinate (0-199)";y
190 gosub 1000: rem hires-grafik ein
200 gosub 3000: rem farbram weiss
210 ro=int(y/8)
220 ch=int(x/8)
230 li=yand7
240 bi=7-(xand7)
250 by=ba+ro*320+ch*8+li
260 poke by,peek(by)or2^bi
280 poke198,0:wait198,1
281 ifpeek(631)=asc("_")thengosub2000:sys58692:poke198,0:end
290 goto160
994 rem ------------------------
995 rem unterprogramm
996 rem hires-grafik einschalten
997 rem ------------------------
1000 poke53272,peek(53272)or8
1010 poke53265,peek(53265)or32
1020 return
1994 rem ------------------------
1995 rem unterprogramm
1996 rem hires-grafik abschalten
1997 rem textmodus wieder aktivieren
1998 rem ------------------------
2000 poke53272,peek(251)
2010 poke53265,peek(252)
2020 return
3000 for i=1024 to 2023
3010 poke i,1
3020 next: return