home *** CD-ROM | disk | FTP | other *** search
/ 64'er Special 31 / 64er_Magazin_Sonderheft_31_19xx_Markt__Technik_de.d64 / bearbeitung (.txt) next >
Commodore BASIC  |  2022-10-26  |  11KB  |  361 lines
  1. 10 rem---------------------------------
  2. 20 rem
  3. 30 rem   mdatailbox bearbeitung v2.6
  4. 40 rem
  5. 50 rem  (c) copyright by paddle-soft
  6. 60 rem         oktober 1985
  7. 70 rem---------------------------------
  8. 80 clr:f1=8:f2=8:poke53272,23
  9. 90 sp$="                                     "
  10. 100 dimna$(250),pa$(250),a(250)
  11. 105 dimme$(10,9),ty(9,9),ss$(140),mn$(9,9)
  12. 110 poke 53280,2:poke53281,2:printchr$(144)
  13. 111 print"[147]":print"               [193][195][200][212][213][206][199]             [146]"
  14. 112 print:print"    [213]nbedingt [198]astload ausschalten !!!"
  15. 113 print:print"      [196]ieses programm arbeitet mit"
  16. 114 print"           relativen [196]ateien !"
  17. 115 print:print:print"      [198]astload kann das nicht !!!"
  18. 116 print:print:print:print:print:input"      [206]ochmals anfangen?  (j/n)";e$
  19. 117 print"[147]":poke 53280,6:poke 53281,6:printchr(5)
  20. 118 if e$="j"then:end
  21. 120 poke53280,15:poke53281,12:poke646,6
  22. 130 forx=1to10:readmb$(x):next
  23. 140 print"[147]          [205]ailbox [194]earbeitung          [146]":forx=1to10
  24. 150 printtab(5)mb$(x)"":nextx
  25. 160 wait198,1:geta$
  26. 170 a=val(a$)
  27. 180 close1:open1,f1,15,"i":close1
  28. 190 iff2<>f1thenopen1,f2,15,"i":close1
  29. 200 onagosub2000,900,2350,370,2840,3060,3280,8000,9000
  30. 210 goto140
  31. 220 rem
  32. 230 rem-----datas--------------------
  33. 240 rem
  34. 250 data"[158][208]asswoerter [213][199] editieren..1"
  35. 260 data"[205]enumacher................2"
  36. 270 data"[144][210]enaming,[211]cratching.......3"
  37. 280 data"[201]nstall..................(4)"
  38. 290 data"[196]irectory.................5"
  39. 300 data"[213]ser-[204]oeschen.............6"
  40. 310 data"[213]serl.+[208]assw. ansehen.....7"
  41. 317 data"[144][213]serliste.................8"
  42. 319 data"[200]ackerpass zeigen.........9"
  43. 320 data"[196]atendiskette(n) einlegen"
  44. 340 rem
  45. 350 rem-----install--------------------
  46. 360 rem
  47. 370 print"[147]              [201]nstall                  [146]":close2
  48. 380 print"[193]chtung: [206]ur am [212]age 00 benutzen!"
  49. 390 print"[215]ollen [211]ie [201]nstallieren ? (j/n)":wait198,1:geta$:ifa$<>"j"thenreturn
  50. 400 print""sp$:print""sp$:print"[206]ur [203]leinbuchstaben!"
  51. 410 input"[201]hr [208]seudonym ";na$:input"[201]hr [208]asswort  ";pa$
  52. 420 print"menues     einlesen."
  53. 430 print"[201]nstall [198]iles:"
  54. 440 print"[163][163][163][163][163][163][163][163][163][163][163][163][163]"
  55. 450 close1:open1,f2,3,"menues,s,r"
  56. 460 input#1,a$:ifa$=chr$(255)then560
  57. 470 input#1,x,y,z:ifz=4then520
  58. 480 ifz=12thenopen2,f1,4,a$+",s,w":print#2,"[204]eer":printx"[157]"right$(str$(y),1)"/";
  59. 490 ifz=3thenopen2,f1,4,a$+",s,w":print#2,chr$(255):printx"[157]"right$(str$(y),1)"/";
  60. 500 close2:goto460
  61. 510 rem-------------------------------
  62. 520 open2,f1,4,a$+",s,w"
  63. 530 print#2,"zeitlos":print#2,"sysop":print#2,chr$(13)+"file init"+chr$(13)
  64. 540 print#2,chr$(255):close2:printx"[157]"right$(str$(y),1)"/";:goto460
  65. 550 rem-------------------------------
  66. 560 print:print"[193]nfang      install."
  67. 570 close1:open2,f2,4,"anfang,s,w":print#2,chr$(255):close2
  68. 580 rem-------------------------------
  69. 590 print"userliste   install."
  70. 600 print"ulist.index install."
  71. 610 open2,f2,3,"userliste,s,w":print#2,na$:print#2,1:close2
  72. 620 open2,f2,3,"ulist.index,s,w"
  73. 630 print#2,1:close2
  74. 640 rem-------------------------------
  75. 650 rem
  76. 660 open2,f2,3,"protokol,s,w":close2
  77. 670 rem-------------------------------
  78. 680 print"anmeldung   install."
  79. 690 open2,f2,3,"anmeldung,s,w"
  80. 700 print#2,"[204]eer":close2
  81. 710 close1:open1,f2,3,"userfile,s,w":print#1,"*":close1
  82. 720 open1,f2,3,"[204]eer,s,w":print#1,chr$(255):close1
  83. 730 rem-------------------------------
  84. 740 rem
  85. 810 close3:close1
  86. 820 rem-------------------------------
  87. 830 print"callers     install."
  88. 840 open2,f2,3,"@:callers,s,w":print#2,1
  89. 850 rem-------------------------------
  90. 860 print"usergroups  install."
  91. 870 close2:gosub1730
  92. 875 open2,f2,3,"@:hackerpass,s,w":print#2,chr$(255):close2
  93. 877 open2,f2,3,"@:filebox,s,w":print#2,chr$(255):print#2,chr$(255):close2
  94. 880 open2,f2,3,"@:anleitung,s,w":print#2,chr$(255):close2
  95. 882 open2,f2,3,"@:files,s,w":print#2,chr$(255):close2
  96. 884 open2,f2,15,"s:userliste.*":print#2,"c:userliste.backup=userliste":close2
  97. 886 open2,f2,2,"@:meckerecke,s,w":print#2,chr$(255):close2
  98. 888 open2,f2,2,"misthaufen,s,w":close2:return
  99. 890 rem-----menumacher----------------
  100. 900 rem
  101. 910 print"[147]              [205]enumacher                [146]":close1:close15
  102. 920 print"menues einlesen."
  103. 930 open1,f2,3,"menues,s,r":open15,f2,15
  104. 940 input#15,c,s$,d,f:ifc<>0thenin=1:goto980
  105. 950 input#1,me$:ifme$=chr$(255)then980
  106. 960 input#1,a,b,ty:me$(a,b)=me$:ty(a,b)=ty:goto950
  107. 970 rem-------------------------------
  108. 980 close15:close1:print"[147]              [205]enumacher                [146]":close1
  109. 990 z=0:print"[206]r"tab(3)"[201]nhalt"tab(35)"[198]kt."
  110. 1000 print"[163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163]"
  111. 1010 fora=1to9:forb=0to9
  112. 1020 ifme$(a,b)<>""thenprintme$(a,b)tab(34)ty(a,b):z=z+1:ifz>13thengosub1490
  113. 1030 nextb:ifme$(a+1,0)<>""thenprint:z=z+1:ifz>13thengosub1490
  114. 1040 nexta
  115. 1050 print"[164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164]":print
  116. 1060 print"[l]esen[160][e]dit[160][s]cratch[160][m]ove  [q]uit"
  117. 1070 wait198,1:getx$
  118. 1080 ifx$="l"orx$=chr$(13)then980
  119. 1090 ifx$="m"then1600
  120. 1100 ifx$="e"then1150
  121. 1110 ifx$="s"then1400
  122. 1120 ifx$="q"then1320
  123. 1130 goto1070
  124. 1140 rem-------------------------------
  125. 1150 gosub1550:iffl=1then980
  126. 1160 l=len(me$(a,b)):ifl<3thenl=3
  127. 1170 print"[157][157][157][157][157][157][157][157][157][157][157][157][157][157][157][157][193]lt>[160]"right$(me$(a,b),l-3)left$(sp$,37-l):n$=me$(a,b)
  128. 1180 input"[206]ame:";me$(a,b)
  129. 1190 input"[198][203][212]-[206]r:";ty(a,b)
  130. 1200 me$(a,b)=mid$(str$(a),2,1)+mid$(str$(b),2,1)+" "+me$(a,b)
  131. 1210 print"[145][145][145]"sp$:printsp$:printsp$:print"[145][145][145][145]";:ifin=1then1150
  132. 1220 close1:ifl=3then1240
  133. 1230 open1,f1,15,"s:"+n$:close1
  134. 1240 ifty(a,b)=4then1280
  135. 1250 ifty(a,b)=12thenopen1,f2,4,me$(a,b)+",s,w":print#1,"[204]eer":close1
  136. 1260 ifty(a,b)=3thenopen1,f1,4,me$(a,b)+",s,w":print#1,chr$(255):close1
  137. 1270 goto1150
  138. 1280 open1,f1,4,me$(a,b)+",s,w"
  139. 1290 print#1,"zeitlos":print#1,"sysop":print#1,chr$(13)+"file[160]init"+chr$(13)
  140. 1300 print#1,chr$(255):close1:goto1150
  141. 1310 rem-------------------------------
  142. 1320 close15:open15,f2,15,"s:menues"
  143. 1330 close1:open1,f2,3,"menues,s,w"
  144. 1340 fora=1to9:forb=0to9
  145. 1350 ifme$(a,b)<>""thenprint#1,me$(a,b):print#1,a:print#1,b:print#1,ty(a,b)
  146. 1360 nextb:nexta
  147. 1370 print#1,chr$(255):close1:close15
  148. 1380 return
  149. 1390 rem-------------------------------
  150. 1400 fl=0:gosub1550:iffl=1then980
  151. 1410 l=len(me$(a,b)):ifl<3thenl=3
  152. 1420 print"[157][157][157][157][157][157][157][157][157][157][157][157][157][157][157][157][206]ame>[160]"right$(me$(a,b),l-3)left$(sp$,34-l)
  153. 1430 ty=ty(a,b):print"[211]icher (j/n)?":wait198,1:geta$:ifa$<>"j"then1470
  154. 1440 ty(a,b)=0:n$=me$(a,b):me$(a,b)=""
  155. 1450 if(ty<>3andty<>4andty<>8andty<>12)orin=1then1470
  156. 1460 close1:open1,f1,15,"s:"+n$:n$=""
  157. 1470 close1:goto980
  158. 1480 rem-------------------------------
  159. 1490 print"[164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164]"
  160. 1500 print:printtab(25)"<[195][210]>=weiter":wait198,1:geta$:
  161. 1510 print"[147]              [205]enumacher                [146]"
  162. 1520 z=0:print"[206]r"tab(3)"[201]nhalt"tab(35)"[198]kt."
  163. 1530 print"[163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163]":return
  164. 1540 rem-------------------------------
  165. 1550 fl=0:print"[211]eitennummer >";:wait198,1:geta$:printa$;:a=val(a$)
  166. 1560 ifa=0thenfl=1:return
  167. 1570 wait198,1:getb$:printb$;:b=val(b$)
  168. 1580 return
  169. 1590 rem-------------------------------
  170. 1600 gosub1550:iffl=1then980
  171. 1610 l=len(me$(a,b)):ifl<3thenl=3
  172. 1620 print"[157][157][157][157][157][157][157][157][157][157][157][157][157][157][157][157][193]lt?[160]"me$(a,b)left$(sp$,34-l):n$=me$(a,b):ty=ty(a,b)
  173. 1630 printtab(8)right$(me$(a,b),l-3)
  174. 1640 input"[145][206]eu";ns$
  175. 1650 me$(a,b)="":ty(a,b)=0
  176. 1660 a=val(left$(ns$,1)):b=val(mid$(ns$,2,1)):me$(a,b)=ns$:ty(a,b)=ty
  177. 1670 if(ty<>3andty<>4andty<>8andty<>12)orin=1then1690
  178. 1680 open15,f1,15,"r:"+ns$+"="+n$:input#15,c,s$,d,f:close15
  179. 1690 print"[145][145][145]"sp$:printsp$:printsp$:print"[145][145][145]";:goto980
  180. 1700 rem
  181. 1710 rem-----usergroup init------------
  182. 1720 rem
  183. 1730 close1:open1,f2,15,"s:usergroups"
  184. 1740 gosub1860
  185. 1750 rn=100:p=1:i$=chr$(255):gosub1840:close1:close3
  186. 1760 gosub1860
  187. 1770 p=1:i$="\":forrn=1to99:gosub1840:nextrn
  188. 1780 p=22:i$="0":forrn=1to99:gosub1840:nextrn
  189. 1790 p=18:i$="\":forrn=10to99step10:gosub1840:nextrn
  190. 1800 p=1:i$="remote":forrn=19to99step10:gosub1840:nextrn
  191. 1810 p=22:i$="3":forrn=19to99step10:gosub1840:nextrn
  192. 1820 close1:close3:return
  193. 1830 rem------------------------------
  194. 1840 print#3,"p"+chr$(3)+chr$(rn)+chr$(0)+chr$(p):print#1,i$:return
  195. 1850 rem-----------------------------
  196. 1860 close1:close3
  197. 1870 open1,f2,3,"usergroups,l,"+chr$(25)
  198. 1880 open3,f2,15:return
  199. 1890 rem find user
  200. 1900 forx=0toau
  201. 1910 ifsb$=na$(x)thenff=0:return
  202. 1920 next:ff=1
  203. 1930 return
  204. 1970 rem
  205. 1980 rem-----passwoerter ug----------
  206. 1990 rem
  207. 2000 print"[147]       [208]asswoerter [213][199] editieren        [146]"
  208. 2010 print"usergroups  einlesen."
  209. 2020 close3:close1:open1,f2,3,"usergroups,l,"+chr$(25):open3,f2,15
  210. 2030 forun=1to9:gosub2220:input#1,ug$(un):nextun
  211. 2040 forun=1to9:gosub2240:input#1,rp$(un):nextun
  212. 2050 print"[147]       [208]asswoerter [213][199] editieren        [146]"
  213. 2060 print" [206]r"tab(5)"[213]sergroup"tab(23)"[210]emote"
  214. 2070 print"[163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163]"
  215. 2080 forx=1to9:printxtab(5)ug$(x)tab(23)rp$(x):nextx
  216. 2090 print"[164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164]"
  217. 2100 print"[?] [213]sergroupnummer        [[197]] [197]xit >":wait198,1:geta$
  218. 2110 a=val(a$):ifa$="e"ora$="[197]"thenclose1:close3:return
  219. 2120 ifa=0thena=1
  220. 2130 print"[206]ur [203]leinbuchstaben!"
  221. 2140 print"[213][199]-[208]asswort  "ug$(a)
  222. 2150 input"[145]";ug$(a)
  223. 2160 iflen(ug$(a))>16then2150
  224. 2170 print"[210][205]-[208]asswort  "rp$(a)
  225. 2180 input"[145]";rp$(a)
  226. 2190 iflen(rp$(a))>6then2180
  227. 2200 un=a:gosub2220:print#1,ug$(a):gosub2240:print#1,rp$(a):goto2050
  228. 2210 rem------------------------------
  229. 2220 print#3,"p"+chr$(3)+chr$(un*10)+chr$(0)+chr$(1):return
  230. 2230 rem-----------------------------
  231. 2240 print#3,"p"+chr$(3)+chr$(un*10)+chr$(0)+chr$(18):return
  232. 2250 z=z0:m=z-1:z=2^z:x=z/2:
  233. 2260 ifm<0thenff=1:return
  234. 2270 m=m-1:ifx>authenx=x-2^m:goto2260
  235. 2280 ifsb$=na$(x)thenff=0:return
  236. 2290 ifsb$<na$(x)thenx=x-2^m:goto2260
  237. 2300 x=x+2^m:ifx>zthenff=1:return
  238. 2310 goto2260
  239. 2320 rem
  240. 2330 rem-----renamsing scratching------
  241. 2340 rem
  242. 2350 print"[147]         [210]enaming,[211]cratching           [146]":fr=0
  243. 2360 print"[211]oll ein chr$(255) angehaengt werden ?";:wait198,1:getb$:printb$
  244. 2370 ifb$="j"thenfr=1
  245. 2380 print"menues    einlesen."
  246. 2390 close1:open1,f2,4,"menues,s,r"
  247. 2400 input#1,a$:ifa$=chr$(255)then2420
  248. 2410 input#1,z1,z2,z3:mn$(z1,z2)=a$:ty(z1,z2)=z3:goto2400
  249. 2420 close1:close15:close2
  250. 2430 print"directory einlesen.":poke198,0:wait198,1
  251. 2440 rem------------------------------
  252. 2450 open15,f1,15,"i":open2,f1,2,"#"
  253. 2460 t=18:s=1:f=0:zs=1
  254. 2470 print#15,"u1:2 0"t;s
  255. 2480 get#2,a$:get#2,a$
  256. 2490 s=asc(a$+chr$(0)):fori=1to8
  257. 2500 print#15,"b-p 2"i*32+2
  258. 2510 get#2,a$:ifa$<>chr$(129)then2560
  259. 2520 print#15,"b-p 2"i*32+5
  260. 2530 f$="":forj=1to16:get#2,a$
  261. 2540 f$=f$+a$:nextj
  262. 2550 ifleft$(f$,1)="("andmid$(f$,4,1)=")"thenss$(zs)=f$:zs=zs+1
  263. 2560 nexti:ifs<19then2470
  264. 2570 zs=zs-1:close2:close15
  265. 2580 rem-----------------------------
  266. 2590 ifss$(1)=""andzs<2then2720
  267. 2600 print"[198]iles:":print"[163][163][163][163][163]"
  268. 2610 close1:open1,f1,15:forx=1tozs
  269. 2620 z1$=mid$(ss$(x),2,1):z2$=mid$(ss$(x),3,1):z1=val(z1$):z2=val(z2$)
  270. 2630 print#1,"s:"+mn$(z1,z2)
  271. 2640 print#1,"r:"+mn$(z1,z2)+"="+left$(ss$(x),4):printz1$z2$"/";:nextx:close1
  272. 2650 iffr=0then2720
  273. 2660 forx=1tozs
  274. 2670 z1$=mid$(ss$(x),2,1):z2$=mid$(ss$(x),3,1):z1=val(z1$):z2=val(z2$)
  275. 2680 ifty(z1,z2)<>3then2700
  276. 2690 open1,f1,3,mn$(z1,z2)+",s,a":print#1,chr$(255):close1
  277. 2700 nextx:close1
  278. 2710 rem-----------------------------
  279. 2720 print:print"[206]och[160]andere[160][198]iles (von [198]loppy"f1") ?":wait198,1:geta$
  280. 2730 ifa$="j"ora$="[202]"then2750
  281. 2740 return
  282. 2750 input"[211]eitenname";sn$
  283. 2760 input"[208]seudoname";pn$
  284. 2770 close1:open1,f1,15,"s:"+sn$
  285. 2780 print#1,"r:"+sn$+"="+pn$
  286. 2790 input#1,c,s$,d,f:ifc<>0thenprint""s$:goto2820
  287. 2800 iffr=0then2820
  288. 2810 close1:open1,f1,3,sn$+",s,a":print#1,chr$(255)
  289. 2820 close1:goto2720
  290. 2830 rem-----------------------------
  291. 2840 print"[147]          [211]eq. [196]irectory               [146]":close2:close15
  292. 2850 open15,f1,15:open2,f1,2,"#"
  293. 2860 t=18:s=1:f=0:printtab(10);:f8=0
  294. 2870 print#15,"u1:2 0"t;s
  295. 2880 get#2,a$:get#2,a$
  296. 2890 s=asc(a$+chr$(0)):fori=1to8
  297. 2900 print#15,"b-p 2"i*32+2
  298. 2910 get#2,a$:ifa$<>chr$(129)then2960
  299. 2920 print#15,"b-p 2"i*32+5
  300. 2930 f$="":forj=1to16:get#2,a$
  301. 2940 printa$;:nextj
  302. 2950 print:printtab(10);
  303. 2960 nexti:f8=f8+1:iff8=2ands<19then3000
  304. 2970 ifs<19then2870
  305. 2980 close2:close15
  306. 2990 printtab(10)"[212]aste druecken.":wait198,1:geta$:return
  307. 3000 printtab(10)"[212]aste druecken."
  308. 3010 printtab(10)"[205]it <[195][210]> abbrechen.":wait198,1:geta$
  309. 3020 ifa$=chr$(13)thenclose2:close15:return
  310. 3030 print"[147]          [211]eq. [196]irectory               [146]":printtab(10);
  311. 3040 f8=0:goto2970
  312. 3050 rem-------------------------------
  313. 3060 print"[147]              [213]ser-[204]oeschen          [146]"
  314. 3070 x=0
  315. 3080 open1,f2,3,"ulist.index,s,r":input#1,uo:close1:open3,f2,4,"userliste,s,r"
  316. 3090 x=x+1:input#3,na$(x),pa$(x):ifst=0then3090
  317. 3100 close3:au=x:a1=au:goto3140
  318. 3140 au=a1:close1:close3:open3,f2,15
  319. 3150 print"[147]              [213]ser-[204]oeschen          [146]"
  320. 3160 input"[213]sername[160]>";a$:iflen(a$)>20then3150
  321. 3170 ifa$=""then3240
  322. 3180 sb$=a$:gosub1890:ifff=1thenprint"[213]ser existiert nicht.":a$="":goto3150
  323. 3190 print"[204]oesche[160]";a$;"."
  324. 3200 ni=val(pa$(x))
  325. 3210 fory=xtoau+1:na$(y)=na$(y+1):pa$(y)=pa$(y+1):nexty:au=au-1
  326. 3220 print#3,"s:\"+sb$
  327. 3230 a$="":goto3150
  328. 3240 close1:print#3,"s:userliste,ulist.index":close3
  329. 3250 close1:open1,f2,3,"userliste,s,w":forx=1toau
  330. 3260 print#1,na$(x):print#1,pa$(x):nextx:close1
  331. 3270 open1,f2,5,"ulist.index,s,w":print#1,au:close1:return
  332. 3280 print"[147]           [213]serliste ansehen          [146]"
  333. 3290 close2:open2,f2,4,"userliste,s,r":close1:close3:mm=0
  334. 3300 open3,f2,15
  335. 3305 dr=0:input"[193]uf [196]rucker[160]>(j/n)";a$
  336. 3307 ifa$="j"ora$="[202]"thenclose4:open4,4,7:dr=1
  337. 3308 ifdr=1thenprint#4,"[213]sername             [208]asswort"
  338. 3309 ifdr=1thenprint#4,"========================================"
  339. 3310 print"[213]sername             [208]asswort"
  340. 3315 print"                                  "
  341. 3320 print"======================================="
  342. 3330 input#2,na$:input#2,pa$
  343. 3340 ifst=64thenmm=1
  344. 3360 ifpeek(198)=1thenmm=1:goto3380
  345. 3370 printna$;tab(21)pa$
  346. 3376 ifdr=1then4000
  347. 3380 ifmm=1thenclose1:close2:close3:poke198,0:wait198,1:poke198,0:return
  348. 3390 goto3330
  349. 4000 print#4,na$;
  350. 4010 print#4,chr$(16)"21"pa$;
  351. 4030 print#4,chr$(16)"42"la$
  352. 4040 goto3380
  353. 8000 print"[147]            [213]serliste                   [146]"
  354. 8010 open2,8,2,"userliste,s,r":print:print:print:print
  355. 8020 x=x+1:input#2,a$:input#2,b$:printa$:ifst<>64then8020
  356. 8040 print"[144][212]aste":poke198,0:wait 198,1:close2:poke198,0:return
  357. 9000 print"[147]            [200]ackerpass                  [146]"
  358. 9010 open2,8,2,"hackerpass,s,r":print:print:print:print
  359. 9020 input#2,a$:printa$:ifst<>64 and a$<>"="then9020
  360. 9040 print"[144][212]aste":poke198,0:wait 198,1:close2:poke198,0:return
  361.