Boot Disc 1/boot-disc-1996-08.iso/bootcd.dir/00171_Script_171

Text File | 1996-07-02 | 8KB | 251 lines

--Just a simple bit of code by...
--John F. Williams
--Midnight Design
--Moraga, CA
--With a little honorary help from Kurt Cagle
--6/28/96

on startMovie
  global gLastSelected,gPopupSerialNum,gJustFinishedAnim,gXlibPath
  set the actorlist=[]
  setpuppets 1,48,false
  set the colorDepth = 16
  set gJustFinishedAnim = FALSE
  set the soundLevel = 3
  if not(the quickTimePresent) then
    set theText = "BootCD makes use of Quicktime for Windows 2.11.  This program will launch the installer for Quicktime."
    alert theText
    open (the moviepath)&"Qtw211\Qt32.exe"
    halt
  end if
  if the colorDepth = 8 then
    set the colorDepth = 16 --for convenience on Macs only
    set theText = "The interface of BootCD is designed to be viewed" &&¼
                  "in 16-bit color (thousands of colors). Please" &&¼
                  "set your monitor to this color depth and restart" &&¼
                  "BootCD."
    alert theText
  end if

  -- Open external libraries
  if the machineType = 256 then
    set gXlibPath = "@\PCFILES\"
    openxlib gXlibPath & "POPUP.DLL"
    set gPopupSerialNum = "PPXW200-3134962971"
  else
    set gXlibPath = "@:Mac Specific Stuff:"
    openxlib gXlibPath & "Popup XObject"
    set gPopupSerialNum = "PPXM200-3076188936"
  end if

  set gLastSelected = 0

end startMovie

on stopMovie
  global gPopupObj,gXlibPath
  if objectP(gPopupObj) then gPopupObj(mDispose)
  if the machineType = 256 then
    closexlib gXlibPath & "Popup.DLL"
  else
    closexlib gXlibPath & "Popup XObject"
  end if
end stopMovie

on DoPopup whichPopup
  global gPopupObj,gPopupSerialNum,gLastSelected,gSubCategory,gCategory
  --Create and process the popup menus in the Workbench section
  --whichPopup can be one of 3 integers currently, representing the following menus
  --1 = Workbench:Utilities
  --2 = Workbench:Resources
  --3 = Workbench:Shareware

  if objectP(gPopupObj) then gPopupObj(mDispose)
  -- Initialize the right popup menu
  if whichPopup = 1 then
    set gPopupObj = Popup(mNew, the text of member "Util Popup Menu")
    set gCategory = "Utilities"
  else if whichPopup = 2 then
    set gPopupObj = Popup(mNew, the text of member "Resource Popup Menu")
    set gCategory = "Resources"
  else if whichPopup = 3 then
    set gPopupObj = Popup(mNew, the text of member "Shareware Popup Menu")
    set gCategory = "Shareware"
  end if

  -- This popup registration line MUST be left in final code
  gPopupObj(mRegister,gPopupSerialNum)

  --if the hilite of cast "auto-align" = true then
  --  set itemAlign = gLastSelected
  --  set h = the right of sprite (the clickOn) - 27
  --  set v = the top of sprite (the clickOn)
  --else
  set itemAlign = 0
  set h = the right of sprite (the clickOn) - 26
  set v = the top of sprite (the clickOn) + 5
  --end if
  set result = gPopupObj(mPopupSpec,  h, v, itemAlign)
  cursor 4
  if result <> "" then
    -- This will only grab the item number off of the fist item
    set gLastSelected = value(result) --the item number
    set gSubCategory = gPopupObj(mGetItem, result)  --the item text
    put "gCategory =" && gCategory
    put "gSubCategory =" && gSubCategory
    set the memberNum of sprite 8 = the number of member (gCategory && "Text Frame")
    set the memberNum of sprite 12 = the number of member "Workbench Install"
    updateStage
    go to frame "Workbench Selection"
    set subMenuText = "WB" && gSubCategory && "Menu"
    put "Looking for submenu in" && subMenuText
    --put member subMenuText into field "Workbench Text"
    set the text of member "Workbench Text" = the text of member subMenuText
    --set the text of member "Workbench Text" = "Hello"
  end if
  cursor -1
end DoPopup

on CheckMouseOvers
  global gHiliteableButtons,gLastButton,gThisButton,gHilitedButton
  set gThisButton = the mouseCast
  --put "gThisButton =" && gThisButton && "and gHilitedButton =" && gHilitedButton
  if (gHilitedButton = gThisButton) or (gLastButton = gThisButton) then
    --if getOne (gHiliteableButtons,gThisButton) then
    --mouseWithin (script gThisButton)
    --end if
  else
    if getOne (gHiliteableButtons,gHilitedButton) then
      repeat with btn in gHiliteableButtons
        mouseExit (script btn)
      end repeat
      set gHilitedButton = gThisButton
      --put "Just sent mouseExit to gHilitedButton" && gHilitedButton
    end if
    if getOne (gHiliteableButtons,gThisButton) then
      repeat with btn in gHiliteableButtons
        if btn<>gThisButton then
          mouseExit (script btn)
        end if
      end repeat
      mouseEnter (script gThisButton)
      set gHilitedButton = gThisButton + 1
      --put "Now sending mouseEnter to gThisButton" && gThisButton
    end if
    set gLastButton = gThisButton
  end if
  updateStage
end CheckMouseOvers

on CheckRandomAnim animChoices,section
  --if 2 secs has elapsed, start a new anim
  global gJustFinishedAnim

  if gJustFinishedAnim then
    startTimer
    set gJustFinishedAnim = FALSE
  else
    if the timer > (2 * 60) then
      set nextAnim = section && "Anim" && random(animChoices)
      go to frame nextAnim
    end if
  end if

end CheckRandomAnim

on TurnOnPuppets firstSprite,lastSprite
  repeat with i = firstSprite to lastSprite
    puppetSprite i,TRUE
  end repeat
end

on TurnOffPuppets firstSprite,lastSprite
  repeat with i = firstSprite to lastSprite
    puppetSprite i,FALSE
  end repeat
end

on pressbtn
  set spritenum=the clickon
  set upcast=the membernum of sprite spritenum
  set downcastname=the name of member (upcast)&"down"
  set downcast=the number of member (downcastname)
  puppetsprite spritenum,1
  set the membernum of sprite spritenum to downcast
  updatestage
  repeat while the mousedown
  end repeat
  set the membernum of sprite spritenum to upcast
  updateStage
  puppetsprite spritenum,false
  return rollover(spritenum)
end

on setpuppets startpuppet,endpuppet,state
  repeat with spritenum=startpuppet to endpuppet
    puppetsprite spritenum,state
  end repeat
end

on getObj objname
  set oldDelimiter=the itemDelimiter
  set the itemDelimiter=quote
  set foundobj=0
  repeat with obj in the actorlist
    if item 2 of string(obj)=objname then
      set foundobj=obj
      exit repeat
    end if
  end repeat
  set the itemDelimiter=oldDelimiter
  return foundobj
end

on SelectDemo whichmid
  puppetSound 0
  set soundlist=["Games":"LED01.AIF","Leisure":"LED05.AIF","Apps":"LED02.AIF"]
  puppetSound getprop(soundlist,whichmid),1
  repeat with index=1 to 3
    set prop=getpropat(soundlist,index)
    if prop=whichmid then
      set the membernum of sprite index+1 to the number of member (prop&"Hi")
    else
      set the membernum of sprite index+1 to the number of member prop
    end if
  end repeat
  UpdateStage
end

on SelectWorkbench whichmid
  puppetSound 0
  set soundlist=["Utilities":"LED01.AIF","Resources":"LED05.AIF","Shareware":"LED02.AIF"]
  puppetSound getprop(soundlist,whichmid),1
  repeat with index=1 to 3
    set prop=getpropat(soundlist,index)
    if prop=whichmid then
      set the membernum of sprite index+1 to the number of member (prop&"Hi")
    else
      set the membernum of sprite index+1 to the number of member prop
    end if
  end repeat
  UpdateStage
end


on makeDescr startcast,endcast,prefix
  repeat with index=startcast to endcast
    set text=the text of member index
    set the name of member index to prefix&(line 1 of text)
  end repeat
end

on getDrive
  set drive=the moviepath
  set oldDelimiter=the itemdelimiter
  set the itemdelimiter=":"
  set drive=(item 1 of drive)&":"
  set the itemdelimiter=oldDelimiter
  return drive
end