home *** CD-ROM | disk | FTP | other *** search
/ 64'er 1988 June / 64er_Magazin_88-06_1988_Markt__Technik_de_Side_A.d64 / kompl.bestenlist (.txt) < prev    next >
Commodore BASIC  |  2022-10-26  |  3KB  |  141 lines
  1. 5 rem******************************
  2. 6 rem******* bestenlisten *********
  3. 7 rem******************************
  4. 8 :
  5. 10 dim pl(60,2),nl$(60,2)
  6. 14 :
  7. 15 rem---------- menue -------------
  8. 16 :
  9. 20 printchr$(147) chr$(17) chr$(17) tab(10)"menue"
  10. 25 print:print:print "  n = neues spiel"
  11. 30 print:print "  e = ewige bestenliste"
  12. 35 print:print "  p = persoenliche bestenliste"
  13. 40 print:print "  t = tagesbestenliste"
  14. 45 print:print "  s = speichern der listen"
  15. 50 print:print "  l = laden der listen"
  16. 55 print:print "  q = ende"
  17. 60 print spc(180) "bitte waehlen"
  18. 65 print:print
  19. 70 get a$:if a$="" then 70
  20. 75 for x=1 to 7
  21. 80 if a$=mid$("neptslq",x,1) then 95
  22. 85 next x
  23. 90 goto 20
  24. 95 on x goto 110,400,500,600,700,800,900
  25. 99 :
  26. 100 rem----- neues spiel ------
  27. 102 :
  28. 110 input "name";sn$
  29. 120 input"resultat =";re
  30. 125 :
  31. 130 f=0:rem----- persoenliche liste-----
  32. 133 :
  33. 140 nl$=sn$:pz=re
  34. 150 for k=1 to 60
  35. 160 if nl$=nl$(k,f) and pz<=pl(k,f) then pz=0
  36. 170 if nl$=nl$(k,f) and pz>pl(k,f) then pl(k,f)=0:nl$(k,f)=""
  37. 180 next k
  38. 190 gosub 1000
  39. 199 :
  40. 230 f=1:rem----- ewige besten-liste-----
  41. 233 :
  42. 240 nl$=sn$:pz=re
  43. 250 gosub 1000
  44. 299 :
  45. 330 f=2:rem----- tages-besten-liste-----
  46. 333 :
  47. 340 nl$=sn$:pz=re
  48. 350 gosub 1000
  49. 360 goto 20
  50. 399 :
  51. 400 rem--- drucken der ewigen liste ---
  52. 405 :
  53. 410 f=1
  54. 420 print chr$(147):print
  55. 430 print tab(3)"ewige bestenliste"
  56. 440 print
  57. 450 gosub 1200
  58. 460 goto 20
  59. 499 :
  60. 500 rem--- drucken der person.liste ---
  61. 505 :
  62. 510 f=0
  63. 520 print chr$(147):print
  64. 530 print tab(3)"persoenl. liste"
  65. 540 print
  66. 550 gosub 1200
  67. 560 goto 20
  68. 599 :
  69. 600 rem--- drucken der tages  liste ---
  70. 605 :
  71. 610 f=2
  72. 620 print chr$(147):print
  73. 630 print tab(3)"tages-bestenliste"
  74. 640 print
  75. 650 gosub 1200
  76. 660 goto 20
  77. 699 :
  78. 700 rem----- speichern der liste ------
  79. 705 :
  80. 710 open1,8,3,"tab.,s,w"
  81. 720 for k=1 to 60
  82. 730 if nl$(k,0)=""then nl$(k,0)="."
  83. 740 if nl$(k,1)=""then nl$(k,1)="."
  84. 750 print#1,nl$(k,0):print#1,nl$(k,1)
  85. 760 print#1,str$(pl(k,0)):print#1,str$(pl(k,1))
  86. 770 next k
  87. 780 close 1
  88. 790 goto 20
  89. 799 :
  90. 800 rem----- laden der listen --------
  91. 805 :
  92. 810 open 1,8,4,"tab.,s,r"
  93. 820 for k=1 to 60
  94. 830 input#1,nl$(k,0):if nl$(k,0)="."then nl$(k,0)=""
  95. 840 input#1,nl$(k,1):if nl$(k,1)="."then nl$(k,1)=""
  96. 850 input#1,pl$(0),pl$(1)
  97. 860 pl(k,0)=val(pl$(0))
  98. 870 pl(k,1)=val(pl$(1))
  99. 880 next k
  100. 890 close1
  101. 895 goto 20
  102. 899 :
  103. 900 rem------spiel-ende --------
  104. 905 :
  105. 910 end
  106. 994 rem********************************
  107. 995 :
  108. 996 rem******* unterprogramme *********
  109. 997 :
  110. 998 rem------- sortieren 1 ---------
  111. 999 :
  112. 1000 for k=1 to 60
  113. 1010 if pz>pl(k,f) then gosub 1100
  114. 1020 next k
  115. 1030 return
  116. 1097 :
  117. 1098 rem------- sortieren 2 ---------
  118. 1099 :
  119. 1100 a=pl(k,f)
  120. 1110 pl(k,f)=pz
  121. 1120 pz=a
  122. 1125 :
  123. 1130 b$=nl$(k,f)
  124. 1140 nl$(k,f)=nl$
  125. 1150 nl$=b$
  126. 1160 return
  127. 1199 :
  128. 1200 rem---- drucken der listen -----
  129. 1205 :
  130. 1210 for k=1 to 60
  131. 1215 if k/21=int(k/21) then get a$:if a$="" then 1215
  132. 1220 j=1: if k>9 then j=2
  133. 1230 print tab(2) mid$(str$(k),j);
  134. 1240 print". ";
  135. 1250 lz=len(str$(pl(1,f)))
  136. 1260 print left$(nl$(k,f),14-lz);
  137. 1270 print tab(20-len(str$(pl(k,f))));pl(k,f)
  138. 1280 next k
  139. 1290 get a$:if a$=""then 1290
  140. 1295 return
  141.