home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er 1987 October
/
64er_Magazin_87-10_1987_Markt__Technik_de.d64
/
2d-berge
(
.txt
)
next >
Wrap
Commodore BASIC
|
2022-10-26
|
1KB
|
49 lines
10 rem ****************************
20 rem * 2d-berge *
30 rem * 1987 by stefan vilsmeier *
40 rem ****************************
50 :
60 if a=0 then a=1:load "fractal.obj",8,1
70 open 1,8,15,"u9":close 1: rem diese zeile kann bei problemen mit dem
80 rem floppyspeeder weggelassen werden!
90 poke53280,0:poke53281,0:dimh%(128)
100 input "[147]grad ";gr
110 w=128
120 sys 50176,14,0:sys 50179,1:sys 50194:rem grafik ein
130 :
140 for i=1 to gr:gosub 300:w=w/2:next: rem 'berg' aufrufen
150 gosub 400:rem darstellen
160 sys 50185,0,0,319,0,1:sys 50185,319,0,319,199,1
170 sys 50185,319,199,0,199,1:sys 50185,0,199,0,0,1
180 get a$:if a$="" goto 180
190 sys 50179,0:if a$="s" then gosub 500: rem 'grafik speichern'
200 goto 100: rem neustart
260 :
270 :
280 rem ***************************
290 rem * 'berg' *
300 rem ***************************
310 :
320 br=w*16
330 w2=w/2
340 for t=0 to 127 step w
350 :b=(h%(t)+h%(t+w))/2
360 :h%(t+w2)=b+(rnd(1)-.5)*br
370 next t
380 return
390 rem ******** darstellen *******
400 for i=0 to 126 step w
410 :x1=i*2+32:x2=(i+w)*2+32
420 :y1=100-h%(i)/10:y2=100-h%(i+w)/10
430 :sys 50185,x1,y1,x2,y2,1
440 next i
450 return
460 :
470 rem ***************************
480 rem * 'grafik speichern' *
490 rem ***************************
500 :
510 input "grafik-name ";n$
520 open 2,8,2,"pi."+n$+",p,w":sys 50191:close 2
530 return