home *** CD-ROM | disk | FTP | other *** search
/ Monster Media 1993 #2 / Image.iso / os2 / gtak212b.zip / SOURCE.ZIP / OS2-ST01 / st_tape.asm < prev    next >
Assembly Source File  |  1992-05-23  |  16KB  |  709 lines
  1.     SUBTTL    Main Module
  2.         INCLUDE DEFS.INC                    ; which includes some other .incs
  3.  
  4.     include    debug.inc
  5.  
  6. StartData
  7.  
  8. ;====================================================
  9. ;
  10. ; Device Header -
  11. ;
  12. ;====================================================
  13.  
  14. TAPE_DEV LABEL WORD
  15.     DD    -1            ; SYSINIT handles the segment part
  16.     DW    DEV_CHAR_DEV or DEV_PROTECT or DEV_OPEN or DEVLEV_2 or DEV_GIOCTL
  17.                     ; Use equates in DEVHDR.INC
  18.                     ; to define Attribute word
  19.     DW    STRAT            ; offset to strategy routine entry point
  20.     DW    0            ; IDC entry point
  21.     DB    'TAPE$4  '        ; Name of device
  22. DPS    DB    8 DUP (?)        ; More reserved
  23.  
  24. ; End of the device header.
  25. ; 
  26. ;============================================================================
  27.  
  28. ;
  29. ;  data structure used by this device driver
  30. ;
  31.  
  32.     EVEN
  33. DISPTAB LABEL WORD
  34.  
  35.     DW    TAPE_INIT    ;00: Init
  36.     DW    TAPE_EXIT1    ;01: Media Check (Block Devices Only)
  37.     DW    TAPE_EXIT1    ;02: Build BPB (Block Devices Only)
  38.     DW    TAPE_EXIT1    ;03: Reserved (used to be Ioctl Input)
  39.     DW    TAPE_INPUT    ;04: Input (Read)
  40.     DW    TAPE_INPNOWAIT     ;05: Non-Destructive Input, no wait.
  41.     DW    TAPE_INPSTATUS     ;06: Input Status
  42.     DW    TAPE_INPFLUSH    ;07: Input Flush
  43.     DW    TAPE_OUTPUT    ;08: Output (Write)
  44.     DW    TAPE_OUTVERIFY    ;09: Output (Write) with verify
  45.     DW    TAPE_OUTSTATUS    ;0A: Output Status
  46.     DW    TAPE_OUTFLUSH    ;0B: Output Flush
  47.     DW    TAPE_EXIT1    ;0C: Reserved (used to be Ioctl Output)
  48.     DW    TAPE_OPEN    ;0D: Device Open
  49.     DW    TAPE_CLOSE    ;0E: Device Close
  50.     DW    TAPE_EXIT1    ;0F: Removable Media
  51.     DW    TAPE_GIOCTL    ;10: Generic Ioctl
  52.     DW    TAPE_EXIT1    ;11: Reset Media
  53.     DW    TAPE_EXIT1    ;12: Get Logical Drive Map
  54.     DW    TAPE_EXIT1    ;13: Set Logical Drive Map
  55.     DW    TAPE_EXIT1    ;14: DeInstall
  56.     DW    TAPE_EXIT1    ;15: Port Access
  57.     DW    TAPE_EXIT1    ;16: Partitionable HDs
  58.     DW    TAPE_EXIT1    ;17: Logical Unit Mal
  59.     DW    TAPE_EXIT1    ;18: -
  60.     DW    TAPE_EXIT1    ;19: -
  61.     DW    TAPE_EXIT1    ;1A: -
  62.     DW    TAPE_EXIT1    ;1B: -
  63.  
  64. MAXCMD = (($ - DispTab)/2) - 1
  65.  
  66.     public    DevHlpPtr
  67.  
  68.         even
  69. DevHlpPtr    dd    0
  70. ReqPkt        dd    0
  71.  
  72. waiting        db    0    ;someone is waiting
  73. lock_flag    db    0    ;[0]: parm, [1]: data
  74.  
  75.         even
  76. para_handle    dd    0    ;ioctl param handle
  77. data_handle    dd    0    ;ioctl data handle
  78. data_ptr    dd    0    ;data pointer
  79.  
  80. cmd_read    db    08h, 01h, 0, 0,  0, 0
  81. cmd_write    db    0Ah, 01h, 0, 0,  0, 0
  82. cmd_sense    db    03h, 00h, 0, 0, 16, 0
  83. sense_data    db    16 dup(?)
  84. cmd_block    db    10 dup(?)
  85. sense_data_ptr    dd    offset sense_data
  86.  
  87.     if SCSI_LVL
  88. errcode        equ    12    ;SCSI standard
  89.     else
  90. errcode        equ    14    ;Tandberg
  91.     endif
  92.  
  93. EndData
  94.  
  95. StartIData
  96.     public    end_data
  97. end_data    db    0
  98. EndIData
  99.  
  100. StartICode
  101.     public    end_code
  102. end_code    db    0
  103. EndICode
  104.  
  105. StartCode
  106.  
  107.     extrn    command:near
  108.     extrn    bus_reset:near
  109.     extrn    device_reset:near
  110.     extrn    delay:near
  111.  
  112. page
  113. ;============================================================================
  114. ;
  115. ; - TAPE_STRAT -
  116. ;
  117. ;    Device Driver strategy entry point.
  118. ;    Parameters    - es:bx = Pointer to the request block
  119. ;
  120.  
  121. STRAT    PROC    FAR
  122.     push    DevHlpPtr        ;Make DevHlp callable w/o using DS/ES
  123.     mov    bp, sp
  124.  
  125.     mov    ax, es
  126.     mov    fs, ax
  127.     mov    di, bx
  128.  
  129.     cmp    fs:[di].PktCmd, 0    ;INIT command? Debug is not yet
  130.     je    short str_1        ;initialized.
  131.  
  132.     outtext    2, 'Strategy '
  133.     outbyte    2, fs:[di].PktCmd
  134.     outchar    2, '$'
  135.  
  136. str_loop:
  137.     cmp    ReqPkt._seg, 0        ;Driver busy?
  138.     jne    str_busy
  139.  
  140. str_1:    mov    ReqPkt._off, di        ;Save the bimodal address
  141.     mov    ReqPkt._seg, fs        ;of the request packet.
  142.     movzx    eax, fs:[di].PktCmd    ;Get command from packet and execute.
  143.     cmp    al, MAXCMD
  144.     ja    str_bad
  145.     call    DISPTAB[eax*2]
  146.  
  147. str_x:    xor    ax, STDONE        ;Mark operation complete.
  148.     mov    fs:[di].PktStatus, ax
  149.  
  150.     outtext    2, 'Strategy return '
  151.     outword    2, ax
  152.     outchar    2, '$'
  153.  
  154.     cmp    waiting, 0        ;Release waiting threads.
  155.     je    short str_x1
  156.     outtext    3, 'Wakeup waiting driver$'
  157.     mov    ax, ReqPkt._seg
  158.     mov    bx, ReqPkt._off
  159.     mov    ReqPkt._seg, 0
  160.     DevHlp    DevHlp_Run
  161.     jmp    short str_r
  162. str_x1:    mov    ReqPkt._seg, 0
  163. str_r:    lea    sp, [bp+4]
  164.     ret
  165.  
  166. str_busy:                ;Driver is busy. Wait.
  167.     outtext    2, 'Driver busy$'
  168.     inc    waiting
  169.     push    fs
  170.     push    di
  171.     mov    ax, ReqPkt._seg        ;Use bimodal pointer of running
  172.     mov    bx, ReqPkt._off        ;request packet as event ID.
  173.     mov    di, 0            ;No timeout.
  174.     mov    cx, 1000
  175.     mov    dh, 0            ;Interruptible.
  176.     DevHlp    DevHlp_Block
  177.     pop    di
  178.     pop    fs
  179.     pushf
  180.     dec    waiting
  181.     popf
  182.     jnc    str_loop        ;Retry on event or timeout wakeup.
  183.     jz    str_loop
  184.  
  185.     mov    ax, STDONE+STERR+11h    ;Character I/O call interrupted.
  186.     mov    fs:[di].PktStatus, ax
  187.     jmp    short str_r
  188.  
  189. str_bad:
  190.     mov    ax, STERR+03h        ;Unknown command.
  191.     jmp    str_x
  192.  
  193. STRAT        ENDP
  194.  
  195. TAPE_EXIT1    proc near
  196.     mov    ax, STERR+03h        ;Unknown command.
  197.     ret
  198. TAPE_EXIT1    endp
  199.  
  200. ;====================================================
  201. ;
  202. ; Operations
  203. ; ----------
  204. ;
  205. ; In:    FS:DI    = ptr to request block
  206. ; Out:    AX    = exit code (incl. DONE)
  207. ;
  208. ;====================================================
  209.  
  210. TAPE_INPUT    proc near    ;04: Input (Read)
  211.     smsw    ax            ;Protected mode only.
  212.     test    al, 1
  213.     jz    short terr_1
  214.     mov    dx, offset cmd_read
  215.     jmp    rw_command
  216. terr_1:    mov    ax, STERR+01h        ;Unknown unit.
  217.     ret
  218. TAPE_INPUT    endp
  219.  
  220. TAPE_INPNOWAIT    proc near    ;05: Non-Destructive Input, no wait.
  221.     mov    ax, STBUSY    ;busy = none avail
  222.     ret
  223. TAPE_INPNOWAIT    endp
  224.  
  225. TAPE_INPSTATUS    proc near    ;06: Input Status
  226.     mov    ax, STBUSY    ;busy = none avail
  227.     ret
  228. TAPE_INPSTATUS    endp
  229.  
  230. TAPE_INPFLUSH    proc near    ;07: Input Flush
  231.     sub    ax, ax
  232.     ret
  233. TAPE_INPFLUSH    endp
  234.  
  235. TAPE_OUTPUT    proc near    ;08: Output (Write)
  236.     smsw    ax            ;Protected mode only.
  237.     test    al, 1
  238.     jz    short terr_1
  239.     mov    dx, offset cmd_write
  240.     jmp    rw_command
  241. TAPE_OUTPUT    endp
  242.  
  243. TAPE_OUTVERIFY    proc near    ;09: Output (Write) with verify
  244.     smsw    ax            ;Protected mode only.
  245.     test    al, 1
  246.     jz    short terr_1
  247.     mov    dx, offset cmd_write
  248.     jmp    rw_command
  249. TAPE_OUTVERIFY    endp
  250.  
  251. TAPE_OUTSTATUS    proc near    ;0A: Output Status
  252.     sub    ax, ax        ;no wait
  253.     cmp    waiting, 0
  254.     je    short ost_r
  255.     mov    ax, STBUSY    ;busy + done = wait required
  256. ost_r:    ret
  257. TAPE_OUTSTATUS    endp
  258.  
  259. TAPE_OUTFLUSH    proc near    ;0B: Output Flush
  260.     sub    ax, ax
  261.     ret
  262. TAPE_OUTFLUSH    endp
  263.  
  264. TAPE_OPEN    proc near    ;0D: Device Open
  265.     smsw    ax        ;Protected mode only.
  266.     test    al, 1
  267.     jz    short terr_1
  268.     sub    ax, ax
  269.     ret
  270. TAPE_OPEN    endp
  271.  
  272. TAPE_CLOSE    proc near    ;0E: Device Close
  273.     sub    ax, ax
  274.     ret
  275. TAPE_CLOSE    endp
  276.  
  277. ;====================================================
  278. ;
  279. ; Generic IOCtl
  280. ;
  281. ;====================================================
  282.  
  283. TAPE_GIOCTL    proc near    ;10: Generic Ioctl
  284.     push    si
  285.  
  286.     outtext    2, 'IOCtl '
  287.     outbyte    2, fs:[di].GIOCategory
  288.     outchar    2, ' '
  289.     outbyte    2, fs:[di].GIOFunction
  290.     outchar    2, '$'
  291.  
  292.     mov    lock_flag, 0
  293.  
  294.     movzx    eax, fs:[di].GIOFunction
  295.     cmp    fs:[di].GIOCategory, 80h    ;Own IOCtl codes?
  296.     je    short gio_cat_own
  297.     cmp    fs:[di].GIOCategory, 11        ;general IOCtl codes?
  298.     je    short gio_cat_11
  299.  
  300. gio_bad:
  301.     test    fs:[di].GIOFunction, 80h    ;Ignore invalid command?
  302.     jnz    short gio_r0
  303.     mov    ax, STERR+03h            ;No, unknown command.
  304.     jmp    short gio_r
  305.  
  306. gio_cat_11:                ;Category 11: general device control.
  307.     cmp    al, 01h            ;Flush input.
  308.     je    short gio_r0
  309.     cmp    al, 02h            ;Flush output.
  310.     je    short gio_r0
  311.     cmp    ax, 41h            ;Session switch notification?
  312.     je    short gio_r0
  313.     cmp    ax, 60h            ;Query monitor support?
  314.     mov    ax, STERR+12h        ;Monitor calls not supported.
  315.     je    short gio_r
  316.     jmp    gio_bad
  317.  
  318.     even
  319. giotab    dw    gio_scsi_slow        ;0
  320.     dw    gio_scsi_fast        ;1
  321.     dw    gio_bus_reset        ;2
  322.     dw    gio_dev_reset        ;3
  323.     dw    gio_set_trace        ;4
  324.  
  325. gio_cat_own:                ;Own IOCtl commands.
  326.     and    al, 1Fh
  327.     cmp    al, 04h
  328.     ja    short gio_bad
  329.     jmp    giotab[eax*2]
  330.  
  331. gio_scsi_slow:                ;SCSI command - slow transfer.
  332.     mov    al, 0
  333.     call    gen_scsi_cmd
  334.     jmp    short gio_r
  335.  
  336. gio_scsi_fast:                ;SCSI command - fast transfer.
  337.     mov    al, 1
  338.     call    gen_scsi_cmd
  339.     jmp    short gio_r
  340.  
  341. gio_bus_reset:                ;SCSI bus reset.
  342.     call    bus_reset
  343.     jc    short gio_r
  344.     jmp    short gio_r0
  345.  
  346. gio_dev_reset:                ;SCSI device reset.
  347.     call    device_reset
  348.     jc    short gio_r
  349.     jmp    short gio_r0
  350.  
  351. gio_set_trace:
  352.     if    trace
  353.     push    di
  354.     mov    ax, fs:[di].GIOParaPack._seg
  355.     mov    di, fs:[di].GIOParaPack._off
  356.     mov    cx, 1
  357.     mov    dl, 0            ;read-only
  358.     DevHlp    DevHlp_VerifyAccess
  359.     pop    di
  360.     jc    gio_seg
  361.     les    bx, fs:[di].GIOParaPack
  362.     mov    al, es:[bx]
  363.     mov    tracelvl, al
  364.     endif
  365.     jmp    short gio_r0
  366.  
  367. gio_r0:    sub    ax, ax
  368. gio_r:    push    ax
  369.  
  370.     test    lock_flag, 1        ;Unlock parameter and data segment.
  371.     jz    short gio_r1
  372.     mov    ax, para_handle._hi
  373.     mov    bx, para_handle._lo
  374.     DevHlp    DevHlp_Unlock
  375. gio_r1:
  376.     test    lock_flag, 2
  377.     jz    short gio_r2
  378.     mov    ax, data_handle._hi
  379.     mov    bx, data_handle._lo
  380.     DevHlp    DevHlp_Unlock
  381. gio_r2:
  382.     mov    lock_flag, 0
  383.     pop    ax
  384.     pop    si
  385.     ret
  386.  
  387. gio_seg:mov    ax, STERR+13h        ;iInvalid parameter.
  388.     jmp    short gio_r
  389. TAPE_GIOCTL    endp
  390.  
  391. ;====================================================
  392. ;
  393. ; Command Subroutines
  394. ;
  395. ;====================================================
  396.  
  397. ;
  398. ; Request sense
  399. ;
  400. ; AX = device driver error status
  401. ; CX = number from information bytes
  402. ;
  403. req_sense    proc near
  404.     push    si
  405.  
  406.     mov    al, 0                ;Execute "request sense"
  407.     mov    ebx, sense_data_ptr
  408.     mov    cx, 16
  409.     mov    dx, offset cmd_sense
  410.     call    command
  411.     jc    reqs_no_stat
  412.     cmp    cx, 4
  413.     jb    reqs_no_stat
  414.  
  415.     if    trace ge 1
  416.     outtext    1, 'Sense data:'
  417.     mov    si, offset sense_data
  418. reqs_0:        lodsb
  419.         outchar    1, ' '
  420.         outbyte    1, al
  421.         loop    reqs_0
  422.     outchar    1, '$'
  423.     endif
  424.  
  425.     mov    al, sense_data+0        ;Check for unexpected
  426.     and    al, 7Fh                ;small sense block
  427.     cmp    al, 70h
  428.     jne    short reqs_short
  429.  
  430.     cmp    sense_data+errcode, 0Ah        ;Insufficient Capacity?
  431.     jne    short reqs_std
  432.     mov    al, sense_data+2        ;EOM set but sense key
  433.     and    al, 4Fh                ;set to "NO SENSE"?
  434.     cmp    al, 40h
  435.     je    short reqs_ew
  436.  
  437. reqs_std:
  438.     mov    al, sense_data+errcode        ;Translate error class & code.
  439.     jmp    short reqs_scan
  440. reqs_short:
  441.     mov    al, sense_data+0
  442. reqs_scan:
  443.     and    al, 7Fh
  444.     mov    bx, offset reqs_t
  445.     mov    cx, reqs_tlen
  446. reqs_1:        mov    ah, cs:[bx+0]
  447.         mov    dx, cs:[bx+1]
  448.         add    bx, 3
  449.         cmp    al, ah
  450.         loopnz    reqs_1
  451.     jnz    short reqs_unknown
  452.     mov    ax, dx
  453.  
  454. reqs_r:    mov    cx, word ptr sense_data+5
  455.     xchg    ch, cl
  456.     pop    si
  457.     ret
  458.  
  459. reqs_unknown:
  460.     mov    ax, STERR+07h            ;Any other: unknown media.
  461.     jmp    reqs_r
  462.  
  463. reqs_no_stat:
  464.     mov    ax, STERR+07h            ;No sense block
  465.     mov    cx, 0FFFFh
  466.     pop    si
  467.     ret
  468.  
  469. reqs_ew:                    ;Early EOT indication
  470.     outtext    1, 'Early Warning$'
  471.     mov    ax, STERR+09h            ;"Out of paper" :-)
  472.     jmp    short reqs_r
  473.  
  474. sxlat    macro    sense, system
  475.     db    sense
  476.     dw    system
  477.     endm
  478.  
  479. reqs_t    label    byte
  480.     sxlat 00h, 0         ;no sense            no error
  481.     sxlat 02h, STERR+02h ;hardware error        drive not ready    
  482.     sxlat 04h, STERR+02h ;drive not ready        drive not ready
  483.     sxlat 09h, STERR+02h ;media not loaded        drive not ready
  484.     sxlat 0Ah, STERR+0Ah ;insufficient capacity    write fault
  485.     sxlat 11h, STERR+04h ;uncorrectable data error    CRC error
  486.     sxlat 14h, STERR+08h ;no record found        sector not found
  487.     sxlat 17h, STERR+00h ;write protected        write protect violation
  488.     sxlat 19h, STERR+04h ;bad block found        CRC error
  489.     sxlat 1Ch, 0         ;file mark detected    EOF
  490.     sxlat 1Dh, STERR+04h ;compare error        CRC error
  491.     sxlat 20h, STERR+03h ;invalid command        unknown command
  492.     sxlat 30h, STERR+0Dh ;unit attention        change disk
  493.     sxlat 33h, STERR+0Ah ;append error        write fault
  494.     sxlat 34h, STERR+0Bh ;read EOM            read fault
  495. reqs_tlen    equ    ($ - offset reqs_t) / 3
  496.  
  497. req_sense    endp
  498.  
  499. ;
  500. ; Generic R/W command
  501. ; DX = command record
  502. ;
  503. rw_command    proc near
  504.     push    si
  505.  
  506.     outtext    3, 'R/W '
  507.     outword    3, fs:[di].IOpData._hi
  508.     outword    3, fs:[di].IOpData._lo
  509.     outchar    3, ' '
  510.     outword    3, fs:[di].IOcount
  511.     outchar    3, '$'
  512.  
  513.     push    dx            ;Make virtual address
  514.     mov    ax, fs:[di].IOpData._hi
  515.     mov    bx, fs:[di].IOpData._lo
  516.     mov    cx, fs:[di].IOcount
  517.     mov    si, data_ptr._seg
  518.     DevHlp    DevHlp_PhysToGDTSel
  519.     pop    dx
  520.     mov    ax, STERR+13h        ;Invalid parameter.
  521.     jc    rw_e
  522.  
  523.     test    cx, 01FFh        ;Verify block alignment
  524.     mov    ax, STERR+13h        ;Invalid parameter.
  525.     stc
  526.     jnz    short rw_e
  527.  
  528.     mov    al, ch            ;Insert block count into command.
  529.     shr    al, 1
  530.     mov    bx, dx
  531.     mov    [bx+4], al
  532.  
  533.     mov    al, 1            ;Run the command.
  534.     mov    ebx, data_ptr
  535.     call    command
  536.     jc    short rw_ret
  537.     cmp    dl, 00h
  538.     je    short rw_ret
  539.  
  540.     stc
  541.     cmp    dl, 02h            ;Check status?
  542.     mov    ax, STERR+02h        ;No -> not ready.
  543.     jne    short rw_ret
  544.     call    req_sense        ;Do check status.
  545.     shl    cx, 9            ;Convert number of blocks not handled
  546.     sub    fs:[di].IOcount, cx    ;to number of bytes actually xferred.
  547.     pop    si
  548.     ret
  549.  
  550. rw_ret:    mov    fs:[di].IOcount, cx    ;Number of bytes actually transferred.
  551.     pop    si
  552.     ret
  553.  
  554. rw_e:    mov    fs:[di].IOcount, 0
  555.     pop    si
  556.     ret
  557. rw_command    endp
  558.  
  559. ;
  560. ; Verify and lock ioctl parameter block.
  561. ;
  562. vfy_para    proc near
  563.     cmp    fs:[di].GIOParaLength, 0
  564.     je    vfyp_1
  565.     and    lock_flag, not 1
  566.     mov    ax, fs:[di].GIOParaPack._seg
  567.     mov    bh, 0                ;Lock, short-term, any memory.
  568.     mov    bl, 0                ;Block until available.
  569.     DevHlp    DevHlp_Lock
  570.     jc    short vfyp_1
  571.     mov    para_handle._hi, ax
  572.     mov    para_handle._lo, bx
  573.     or    lock_flag, 1
  574.     push    di
  575.     mov    cx, fs:[di].GIOParaLength    ;Verify access.
  576.     mov    ax, fs:[di].GIOParaPack._seg
  577.     mov    di, fs:[di].GIOParaPack._off
  578.     mov    dh, 0                ;Read-only.
  579.     DevHlp    DevHlp_VerifyAccess
  580.     pop    di
  581. vfyp_1:    ret
  582. vfy_para    endp
  583.  
  584. ;
  585. ; Verify and lock ioctl data block.
  586. ; The data block can be NULL.
  587. ;
  588. vfy_data    proc near
  589.     cmp    fs:[di].GIODataLength, 0
  590.     je    vfyd_1
  591.     and    lock_flag, not 2
  592.     movzx    eax, fs:[di].GIODataLength    ;NULL pointer & length?
  593.     or    eax, fs:[di].GIODataPack
  594.     jz    short vfyd_1
  595.     mov    ax, fs:[di].GIODataPack._seg
  596.     mov    bh, 0                ;Lock, short-term, any memory.
  597.     mov    bl, 0                ;Block until available.
  598.     DevHlp    DevHlp_Lock
  599.     jc    short vfyd_1
  600.     mov    data_handle._hi, ax
  601.     mov    data_handle._lo, bx
  602.     or    lock_flag, 2
  603.     push    di
  604.     mov    cx, fs:[di].GIODataLength    ;Verify access.
  605.     mov    ax, fs:[di].GIODataPack._seg
  606.     mov    di, fs:[di].GIODataPack._off
  607.     mov    dh, 1                ;Read+write.
  608.     DevHlp    DevHlp_VerifyAccess
  609.     pop    di
  610. vfyd_1:    ret
  611. vfy_data    endp
  612.  
  613. ;
  614. ; Generic IOCTL,  Subfunction "general SCSI command"
  615. ; AL = 0 for slow, 1 for fast xfer
  616. ;
  617. gen_scsi_cmd    proc near
  618.     push    ax                ;Slow/fast flag.
  619.  
  620.     call    vfy_para
  621.     jc    short gen_e1
  622.     call    vfy_data
  623.     jc    short gen_e1
  624.  
  625.     mov    cx, fs:[di].GIOParaLength    ;Copy command to data segment.
  626.     cmp    cx, 10
  627.     ja    short gen_e1
  628.     push    di
  629.     push    si
  630.     lgs    si, fs:[di].GIOParaPack
  631.     mov    ax, ds
  632.     mov    es, ax
  633.     mov    di, offset cmd_block
  634.     cld
  635.     rep    movs byte ptr es:[di], byte ptr gs:[si]
  636.     pop    si
  637.     pop    di
  638.  
  639.     pop    ax                ;Slow/fast flag
  640.     mov    ebx, fs:[di].GIODataPack    ;Data pointer
  641.     mov    cx, fs:[di].GIODataLength
  642.     mov    dx, offset cmd_block        ;Execute command
  643.     call    command
  644.     jc    short gen_r
  645.     cmp    dl, 0                ;Is ok, test SCSI status byte.
  646.     je    short gen_r
  647.     mov    al, 80h                ;Not ok, return SCSI status byte.
  648.     or    al, dl
  649.     jmp    short gen_r
  650.  
  651. gen_e1:    add    sp, 2
  652. gen_e:    mov    ax, STERR+13h            ;Invalid parameters.
  653. gen_r:    ret
  654. gen_scsi_cmd    endp
  655.  
  656. ;====================================================
  657. ;
  658. ; Initialization
  659. ;
  660. ;====================================================
  661.  
  662.     extrn    init_io:near
  663.     extrn    init_debug:near
  664.  
  665. TAPE_INIT    proc near    ;00: Init
  666.     mov    eax, fs:[di].InitDevHlp    ;Set device helper vector.
  667.     mov    DevHlpPtr, eax
  668.     mov    ss:[bp], eax
  669.  
  670.     mov    sense_data_ptr._seg, ds    ;Fixup.
  671.  
  672.     push    di            ;Allocate selector for data pointer.
  673.     mov    ax, ds
  674.     mov    es, ax
  675.     mov    di, offset data_ptr._seg
  676.     mov    cx, 1
  677.     DevHlp    DevHlp_AllocGDTSel
  678.     pop    di
  679.     jc    init_e
  680.  
  681. ;    les    bx, fs:[di].InitParms
  682. ;    FIXME: Interpret command line.
  683.  
  684.     call    init_debug
  685.     jc    init_e
  686.  
  687.     call    init_io
  688.     jc    init_e
  689.  
  690.      outtext    2, 'ST_Tape Init done$'
  691.  
  692. init_r:    mov    fs:[di].InitcUnit, 0
  693.     mov    fs:[di].InitEcode, offset end_code
  694.     mov    fs:[di].InitEdata, offset end_data
  695.     mov    fs:[di].InitpBPB, 0
  696.     sub    ax, ax
  697.     ret
  698.  
  699. init_e:    mov    fs:[di].InitcUnit, 0
  700.     mov    fs:[di].InitEcode, 0
  701.     mov    fs:[di].InitEdata, 0
  702.     mov    ax, STERR+0Ch
  703.     ret
  704. TAPE_INIT    endp
  705.  
  706. EndCode
  707.  
  708.     end
  709.