Monster Media 1993 #2/Image.iso/games1/agt15.zip/AGT15.ZIP/SAMPLE.DAT

Text File | 1988-04-25 | 20KB | 600 lines

rem  (********************************)
rem  (*            ROOMS             *)
rem  (********************************)

ROOM 2
Dark Pit
WEST 3  (* Storage Room *)
END_ROOM

ROOM_DESCR 2  (* Dark Pit *)
You are in a deep pit.  Climbing back up is simply impossible: the side of the
pit is far too steep and is too slippery to grip.  Through a shattered wooden
door, you can faintly make out an exit to the west.
END_ROOM_DESCR

ROOM 3
Storage Room
EAST 2  (* Dark Pit *)
WEST 4  (* Middle of Corridor *)
LIGHT 1  (* Any light will do *)
POINTS 1
END_ROOM

ROOM_DESCR 3  (* Storage Room *)
You are in a small, dimly-lit room.  Empty shelves line the wall; this must
have been a storage room of some sort.  A broken plastic door leads east, back
to the pit you fell into.  Another open door leads west.
END_ROOM_DESCR

ROOM 4
Middle of Corridor
NORTH 5  (* N End of Corridor *)
SOUTH 7  (* S End of Corridor *)
EAST 3  (* Storage Room *)
LOCKED_DOOR (west)
LIGHT 201  (* Iron Crowbar *)
END_ROOM

ROOM_DESCR 4  (* Middle of Corridor *)
This is a large long corridor, leading north and south.  To the east, an open
door leads to a storage room of some kind.  A door to the west is securely
locked.  The flashlight flickers on and off and finally goes out completely.
However, the iron bar gives off a strange orange glow in this room, lighting
up what would otherwise be a very dark place.
END_ROOM_DESCR

ROOM 5
N End of Corridor
NORTH 8  (* Entry Hall *)
SOUTH 4  (* Middle of Corridor *)
EAST 6  (* Storage Room *)
LIGHT 1  (* Any light will do *)
END_ROOM

ROOM_DESCR 5  (* N End of Corridor *)
This is the north end of a long corridor.  An open doorway leads east; an arch
leads north.  The flashlight flickers on and off, but finally stays on.
END_ROOM_DESCR

ROOM 6
Storage Room
WEST 5  (* N End of Corridor *)
LIGHT 1  (* Any light will do *)
END_ROOM

ROOM_DESCR 6  (* Storage Room *)
This is another storage room.  The shelves on the walls are empty.  The only
exit leads west.  The flashlight flickers on and off, but finally stays on.
END_ROOM_DESCR

ROOM 7
S End of Corridor
NORTH 4  (* Middle of Corridor *)
SOUTH 11  (* Elevator *)
LIGHT 1  (* Any light will do *)
END_ROOM

ROOM_DESCR 7  (* S End of Corridor *)
This is the south end of a long north-south corridor.  You see a large red
triangle painted on the wall next to a doorway to the south.  The flashlight
flickers on and off, but finally stays on.
END_ROOM_DESCR

ROOM 8
Entry Hall
SOUTH 5  (* N End of Corridor *)
EAST 9  (* Collapsed Room *)
WEST 10  (* Dead End *)
NORTH 10  (* Dead End *)
LIGHT 1  (* Any light will do *)
END_ROOM

ROOM_DESCR 8  (* Entry Hall *)
This is a small entry hall.  An arch leads south to a corridor; smaller arches
lead east and west.  Another passage goes north.
END_ROOM_DESCR

ROOM 9
Collapsed Room
WEST 8  (* Entry Hall *)
POINTS 1
LIGHT 1  (* Any light will do *)
END_ROOM

ROOM_DESCR 9  (* Collapsed Room *)
Something terrible has happened here, probably a cave-in.  The walls have
collapsed, and all exits are blocked except the door to the west through which
you entered.  Dirt and mud cover much of the floor.
END_ROOM_DESCR

ROOM 10
Dead End
SOUTH 8  (* Entry Hall *)
EAST 8  (* Entry Hall *)
LIGHT 1  (* Any light will do *)
END_ROOM

ROOM_DESCR 10  (* Dead End *)
Rocks, dirt and concrete fill the area.  There has been a cave-in.  You can
only go back the way you came.
END_ROOM_DESCR

ROOM 11
Elevator
NORTH 7  (* S End of Corridor *)
SPECIAL 12  (* Go to Room 12 -- Elevator by 'Push square' *)
KEY 209  (* blue square *)
LIGHT 1  (* Any light will do *)
END_ROOM

ROOM_DESCR 11  (* Elevator *)
This is an elevator car, with an electroluminescent control panel.  The
turbo-thrusters hum quietly beneath your feet, ready to rush you to your
destination.
END_ROOM_DESCR

SPECIAL 11  (* Elevator *)
As soon as you press the red triangle image, the doors slide shut and you are
jerked against the west wall.  The elevator car cuts to the north and west a
moment later, and you relax for a few minutes as it seems to rise and move
steadily to the northwest.  Abruptly, the car slows down and rises more
sharply.  It comes almost to a stop, then begins moving toward the west.  As
you massage the bruises you're received from the trip, the door opens to the
south.
END_SPECIAL

ROOM 12
Elevator
SOUTH 13  (* Shuttle Platform *)
SPECIAL 11  (* Go to Room 11 -- Elevator by 'Push triangle' *)
KEY 210  (* red triangle *)
POINTS 1
LIGHT 1  (* Any light will do *)
END_ROOM

ROOM_DESCR 12  (* Elevator *)
This is an elevator car, with an electroluminescent control panel.  The
turbo-thrusters hum quietly beneath your feet, ready to rush you to your
destination.
END_ROOM_DESCR

SPECIAL 12  (* Elevator *)
As soon as your finger touches the blue square image on the control panel,
the doors slide shut and you are slammed violently against the west wall as
the car begins moving sideways, toward the east.  Just as you get used to that
motion, the car begins dropping, then seems to be both dropping and moving to
the south.  Panicked, you poke at the control panel, but nothing is displayed
on it and it rudely ignores your whimpering.
   After a few minutes, the car's motion settles into a southeast direction,
and seems to stop dropping.  There's no way to tell how fast -- or far -- the
car is traveling.
   As suddenly as it started, the car brakes, cuts to the west, and stops.  To
your surprise and confusion, the door opens behind you, to the south.
END_SPECIAL

ROOM 13
Shuttle Platform
ENTER 14  (* Bridge *)
SOUTH 14  (* Bridge *)
NORTH 12  (* Elevator *)
END_ROOM

ROOM_DESCR 13  (* Shuttle Platform *)
You are on a platform outside the hatch leading into a space shuttle.
The shuttle hatch is open to the south.  An elevator is to the north.
END_ROOM_DESCR

ROOM 14
Bridge
NORTH 13  (* Shuttle Platform *)
EXIT 13  (* Shuttle Platform *)
SPECIAL 15  (* Go to Bridge by INSERT or TURN KEY *)
KEY 207  (* plastic key *)
END_ROOM

ROOM_DESCR 14  (* Bridge *)
This is the bridge, the command hub of the shuttle.  The only visible exit is
to the north.  Like most space vehicles, this one runs almost entirely
automatically, with all flight parameters pre-programmed.  There is a command
console here, but it is dark.  Mounted just below it is a small keyhole.  It is
currently set to 'off.'
END_ROOM_DESCR

ROOM 15
Bridge
WEST 16  (* Escape Pod *)
END_ROOM

ROOM_DESCR 15  (* Bridge *)
This is the bridge.  The exit to the north has been damaged by the vibrations
and is twisted into an impossible position.  An escape pod is visible to the
west.
END_ROOM_DESCR

SPECIAL 15  (* Bridge *)
As you turn the key in the keyhole, you feel a surge as the ion drives prepare
for a long-awaited takeoff.  The whole ship begins to rumble and shake as the
overhead bay doors are opened by huge motors built into the hillside, and you
hear and feel vibrations as debris from above bounces off the shuttle.
    Out of fear, you reach to turn the key off, but it twists and breaks in
the lock.  The engines surge more violently, and you are slammed against the
floor as the shuttle begins to rise into the air.
    Instantly, you realize that the bay doors have failed at something,
because you can feel the shuttle collide with something as it ascends.  The
computer corrects for the damage somehow and the shuttle continues to rise,
but is vibrating violently.  The ion drives begin to squeal abnormally, and you
realize that the shuttle cannot possibly remain in one piece for more than a
few minutes.
    As if expecting your panic, a wall panel suddenly slides to one side,
revealing an escape pod.
END_SPECIAL

ROOM 16
Escape Pod
POINTS 1
SPECIAL 17  (* Go to Escape Pod by INSERT or TURN MODULE *)
KEY 208  (* RT Module *)
END_ROOM

ROOM_DESCR 16  (* Escape Pod *)
You are now in the escape pod.  As you sit in the command couch, the door
slides shut behind you and you feel the pod automatically ejecting from the
shuttle.  Not surprisingly, it hits something on the way out, and spins out of
control for a moment before its thrusters regain control.  You can hear the
wind rushing by, and then the sound of an explosion -- very near by -- drowns
out all other sounds.  The escape pod rises for a few minutes, then begins to
move horizontally.  It's hard to tell what is happening, but it's certainly not
as bad as what was happening just a few seconds ago.
  Directly before you is an extremely simple manual console with a small
socket, above which are instructions which say "insert command module here."
END_ROOM_DESCR

ROOM 17
Escape Pod
EAST 18  (* You win game! *)
EXIT 18  (* You win game! *)
END_ROOM

ROOM_DESCR 17  (* Escape Pod *)
You are in the escape pod, which is not moving.  An open door leads east.
END_ROOM_DESCR

SPECIAL 17  (* Escape Pod *)
As you insert the RT-584 module, it exerts some sort of magnetic force which
pulls it from your fingers and snugly into the RT-500 socket.  The escape pod
changes direction and velocity -- almost seeming to stop for a moment -- and
then accelerates again toward some unknown destination.
  After a few minutes, you feel the pod turning and then decelerating and
descending.  Before you expected it, the pod touches down roughly, causing you
to bump your head against the side of the pod.  The pod's engines begin whining
as they reduce power.  The door suddenly clicks and swings open, revealing
bright sunlight outside.  Once the door is locked open, the pod's engines shut
down completely, leaving you in complete silence.
END_SPECIAL

ROOM 18
You win game!
GAME_WIN
POINTS 10
END_ROOM

ROOM_DESCR 18  (* You win game! *)
You emerge from the pod to find the sun shinning brightly.  The air is fresh
and clean and smells like spring flowers.  For the first time in a long while,
you feel good about being alive.
END_ROOM_DESCR

rem  (********************************)
rem  (*           NOUNS              *)
rem  (********************************)

NOUN 201
Crowbar
Iron
There is an iron crowbar here.
WEIGHT 10
SIZE 20
LOCATION 2  (* Dark Pit *)
(everything else is default)
NOUN_SYNONYMS rod bar
END_NOUN

NOUN_DESCR 201  (* Iron Crowbar *)
The iron crowbar is about three feet long and weighs about eight pounds.
It might be useful as a weapon or as a tool, depending on the circumstances.
END_NOUN_DESCR

NOUN 202
Crate
Wooden
There is a large wooden crate here.
LOCATION 3  (* Storage Room *)
CLOSABLE
CLOSED
LOCKABLE
LOCKED
READABLE
KEY 201  (* iron crowbar *)
UNMOVABLE
NOUN_SYNONYMS lettering side writing box lid nail nails
END_NOUN

NOUN_DESCR 202  (* Wooden Crate *)
The crate is about eight feet long by six feet wide by six feet high.  It is
extremely heavy and quite solid.  There is lettering on the side.  It has a
lid that is nailed to the top of the crate.
END_NOUN_DESCR

TEXT 202  (* Wooden Crate *)
The side of the crate says, "U.S.  Emergency Radiation Supplies.  Do Not Open."
END_TEXT

NOUN 203
Cube
Metal
There is a huge solid metal cube here.
WEIGHT 91  (* can only be carried by itself *)
SIZE 91
LOCATION 202  (* inside crate *)
END_NOUN

NOUN_DESCR 203  (* Metal Cube *)
The huge metal cube may contain something, but you'd need a heck of a knife --
or a laser -- to cut into it.
END_NOUN_DESCR

NOUN 204
Sign
Cardboard
Over the arch is a sign.
LOCATION 5  (* N End of Corridor *)
UNMOVABLE
NOUN_SYNONYMS writing
READABLE
END_NOUN

NOUN_DESCR 204  (* Sign *)
The sign is black with white lettering.
END_NOUN_DESCR

TEXT 204  (* Sign *)
"Enlisted Personnel Only.  No Visitors."
END_TEXT

NOUN 205
Desk
Metal
There is a metal desk near the door.
WEIGHT 80
SIZE 90
LOCATION 8  (* Entry Hall *)
CLOSABLE
OPEN
UNMOVABLE
END_NOUN

NOUN_DESCR 205  (* Metal Desk *)
This is a rather ordinary metal desk with a single metal drawer.
END_NOUN_DESCR

NOUN 206
Drawer
Metal
There is a small drawer.
WEIGHT 10
SIZE 10
LOCATION 205  (* inside desk *)
CLOSED
CLOSABLE
END_NOUN

NOUN_DESCR 206  (* Drawer *)
The drawer looks like most drawers.
END_NOUN_DESCR

NOUN 207
Key
Plastic
There is a small plastic key here.
WEIGHT 1
SIZE 1
LOCATION 206  (* inside drawer *)
PUSHABLE  (* will cause 'special' *)
TURNABLE  (* will cause 'special' *)
END_NOUN

NOUN_DESCR 207
The plastic key is like most keys you've seen.  It is cylindrical and has many
tiny holes through it; optical sensors in the correct lock will respond to it
by opening a door or doing whatever it is the key is meant to do.
END_NOUN_DESCR

NOUN 208
Module
RT
There is a small, square, electronic module here.
WEIGHT 2
SIZE 2
LOCATION 9  (* Collapsed Room *)
POINTS 1  (* worth 1 point *)
PUSHABLE  (* will cause 'special' *)
TURNABLE  (* will cause 'special' *)
END_NOUN

NOUN_DESCR 208  (* RT Module *)
This is a standard-design RT-584 module.  Like all RT-584s, it is the
functional equivalent of a complete supercomputer with gigabytes of storage
and a knowledge base of some sort.  All you need to do is plug it into an
RT-934 console and push it to access its information.
END_NOUN_DESCR

NOUN 209
Square
Blue
There is a blue square visible on the control console.
LOCATION 11  (* Elevator *)
UNMOVABLE
PUSHABLE  (* will cause 'special' *)
END_NOUN

NOUN_DESCR 209
The blue square is an image on the touchscreen of the elevator command
console.  The command console is intended to be useful to anyone who can
recognize simple graphic icons, even if they don't speak English.
END_NOUN_DESCR

NOUN 210
Triangle
Red
There is a red triangle visible on the control console.
LOCATION 12  (* Elevator *)
UNMOVABLE
PUSHABLE  (* will cause 'special' *)
END_NOUN

NOUN_DESCR 210  (* Red Triangle *)
The red triangle is an image on the touchscreen of the elevator command
console.  The command console is intended to be useful to anyone who can
recognize simple graphic icons, even if they don't speak English.
END_NOUN_DESCR

NOUN 211
Flashlight
Atomic
There is a disposable atomic flashlight here.
LOCATION 2  (* Dark Pit *)
WEIGHT 5
SIZE 5
MOVABLE
IS_LIGHT
OFF
NOUN_SYNONYMS light switch
END_NOUN

NOUN_DESCR 211  (* Flashlight *)
The flashlight looks like a standard disposable atomic flashlight.
It has an on/off switch.
END_NOUN_DESCR

NOUN 212
Gun
Laser
There is a small laser-powered handgun here.
LOCATION 3  (* Storage Room *)
WEIGHT 3
SIZE 3
MOVABLE
CAN_SHOOT
NUM_SHOTS 3
NOUN_SYNONYMS laser handgun
END_NOUN

NOUN_DESCR 212  (* Laser Gun *)
The gun looks like a standard military-issue medium-power laser weapon.  These
weapons can usually fire eight or ten times; there's no way to know what the
charge level is without a voltmeter.
END_NOUN_DESCR

rem  (************************************)
rem  (*            CREATURES             *)
rem  (************************************)

CREATURE 301
Wolf
Grey
There is a grey wolf here, snarling and growling at you.
LOCATION 3  (* Storage Room *)
WEAPON 201  (* crowbar *)
HOSTILE
THRESHHOLD 3  (* can attack it 3 times *)
TIME_THRESH 5  (* can be in room for 5 turns *)
END_CREATURE

CREATURE_DESCR 301  (* Grey Wolf *)
The wolf is grey, with a few white spots on its belly.  It is also quite large,
almost as tall as you are.  Its claws look sharp.  The wolf does not look
friendly; it growls and snarls, plainly upset that you have disturbed it.
END_CREATURE_DESCR

CREATURE 302
Mutant
Hideous
There is a hideous mutant here.  It is hissing and cursing at you.
LOCATION 6  (* Storage Room *)
WEAPON 212  (* laser gun *)
HOSTILE
THRESHHOLD 3  (* can attack it 3 times *)
TIME_THRESH 5  (* can be in room for 5 turns *)
END_CREATURE

CREATURE_DESCR 302  (* Hideous Mutant *)
The mutant is really ugly!  It looks like it was once a man, but it is
horribly disfigured and has open sores covering most of its body.
It is very nervous and angry at you for disturbing its lair.
END_CREATURE_DESCR

rem  (************************************)
rem  (*          Verb Synonyms           *)
rem  (************************************)

VERB
UNLOCK PRY
TURN INSERT SWITCH FLIP
END_VERB

rem  (************************************)
rem  (*           Intro Text             *)
rem  (************************************)

INTRODUCTION

It is the year 2093.  You, a foolish explorer, decided to wander the
radiation-filled areas near what used to be the nation's capital:
Washington, D.C.  You've found the adventure you sought, though few of your
exploits turned out as you'd expected.
  In your six-month travels, you've been attacked by packs of wild dogs and
a few wilder humans.  Your supplies were stolen weeks ago, and you've been
existing by eating the few surviving vegetables in long-abandoned gardens,
despite the risks of eating food grown in this area.  When you finally tried
to leave this restricted region, you were shot at by patrols who detected
too much radiation in your body.
  In your ever-more-desperate search for either a safe temporary home or a
way out of the danger-zone, you've begun exploring the hills where other
wanderers have said there are caves and tunnels.  Somewhere here, it is
rumored, there was once an underground complex where the elite few hid
during the atomic cataclysm.  No trace has ever been found of those hidden
politicians and millionaires, though the mysterious roars of explosions were
heard two years after the Last War ended, suggesting that the survivors
above ground might have found and destroyed the survivors who hid below.
  After several weeks of living off the land, you discovered a deep pit,
apparently man-made, at the center of a neatly-rounded hill.  For two days,
you explored the hill, trying to find another cave or even an out-of-place
pile of dirt, to no avail.  Far away to the south are five blackened pits in
the earth, burned, ash-covered remnants of a few days of sheer hell; you've
wondered if their target might have been hills like this.
  Finally, you locate a much-used rope and tie one end around some rocks
near the pit, hoping to lower yourself into it.  As you explore the top few
feet of the cave, you drop your disposable atomic flashlight, and can hear it
bounce against the sides of the cave for several seconds before striking the
bottom.  Slowly, in darkness, you lower yourself down the rope.  Wisely, you
started at noon, and the light is bright enough for you to see above you,
though your body blocks most of the light below.
  As you approach what you think is the bottom of the pit, your legs push
aside a clump of earth and suddenly you are hanging in empty space: the thin
vertical tunnel has widened.  As you turn awkwardly, you try to stop moving
by reaching a hand out to touch the side of the tunnel, only to suddenly
lose your grip with the other hand.  You grab for the rope, but gain only
rope burns as you feel the end of the rope slip from your fingers, hardly
slowing your fall.
  Luckily, you were only about fifteen feet from the bottom of the pit.  Of
course, "only" is a relative term: in this case, it means you'll suffer from
extreme pain and bruises, not broken bones.
  It takes you only a minute to realize that the sides of the pit are too
steep and muddy to climb; the rope is dimly visible twenty feet above.  By
feeling the side of the pit, you can make out some sort of wooden or plastic
door to the west.  Despite the pain you still feel from the fall, you manage
to kick the door open, leading to a dark room.
END_INTRO