home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Monster Media 1993 #2
/
Image.iso
/
comm
/
uc_cis.zip
/
WINFILE.SCR
< prev
Wrap
Text File
|
1993-07-15
|
4KB
|
174 lines
Delay 2000
Send "^C"
Waitfor "ID"
Delay 150
Send "XXXXX,XXX^M"
Waitfor "Password"
Delay 200
Send "XXXXXX.XXXXX^M"
Waitfor "!"
ALARM
Clear
;
; Variables - easily modified.
;
szTargetFile = "C:\WINDOWS\UNICOM\WINFILE.LOG"
szBackFile = "C:\WINDOWS\UNICOM\WINF_BAK.LOG"
szForumOptions = "OPT;INI;1;MOD;3;EDI EDIT;PAU N;REP LIST;TYPE N;SKIP N;CHAR;S^M"
;
IF (strlen(DirLastOnDate()) > 5)
DisplayString(1,20,"This script was last used")
DisplayString(28,20,DirLastOnDate())
ENDIF
DisplayString(1,22,"Hit <ENTER> to find only the most recent files!")
i = 0
WHILE (i < 1)
SWITCH(InputString(szDateString, "WINDOW'S FILES: ENTER day(s) to search back . . . "))
CASE (StrisNumeric(szDateString))==0
Clear
DisplayString(1,22,"No, it must be a number, e.g. 10, 3, etc.")
ENDCASE
CASE (StrisSpace(szDateString))==1
Clear
DisplayString(1,22,"That defaults to finding files added within the last day.")
szDateString = "1"
Delay 1500
i = 1
ENDCASE
CASE (StrisNumeric(szDateString))==1
i = 1
ENDCASE
ENDSWITCH
ENDWHILE
Delay 10
Clear
;
DisplayString(1,22,"Hit <ENTER> to search for all new files in the selected forums.")
InputString(szKeyString, "ENTER A KEYWORD (or leave blank for ALL)")
IF (StrisAlphaNum(szKeyString))==0
Clear
DisplayString(1,22,"Okay! . . . but only the first KEYWORD is actually used.")
Alarm
Delay 1500
Clear
ENDIF
Clear
;
Delay 10
send "SET BRIEF YES^M"
CLEAR
Waitfor "!"
Delay 10
send "SET PAGED NO^M"
CLEAR
Waitfor "!"
Delay 10
send "SET BLANK YES^M"
CLEAR
Waitfor "!"
CLEAR
ALARM(1)
;
Delay 10
IF FindFile(szTargetFile)
DisplayString(1,20,"Save the existing LOG generated by this script as a separate file?")
DisplayString(1,22," (NO simply deletes the existing file; CANCEL appends to it.)")
SWITCH(Response = Message("Save the existing LOG?","YESNOCANCEL","ICONQUESTION"))
CASE (Response == 2)
Log("OPEN",szTargetFile)
ENDCASE
CASE (Response == 6)
IF FindFile(szBackFile)
FileDelete(szBackFile)
ENDIF
IF (FileRename(szTargetFile,szBackFile))
CLEAR
DisplayString(1,22,"Existing LOG saved as ")
DisplayString(23,22,szBackFile)
Delay 1500
ENDIF
Log("OPEN",szTargetFile)
ENDCASE
CASE (Response == 7)
Log("TRUNC",szTargetFile)
ENDCASE
ENDSWITCH
CLEAR
ENDIF
;
; Okay, that should collect or set up everything that we need. Let's do it!
;
GOSUB MODULES
;
Delay 1000
Log("CLOSE")
StatusMessage("DONE, AND NOW LOGGING OFF!")
Send ("OFF^M")
Delay 10
szEditor = Strtok(WinReadIni("Extensions","txt")," ")
Delay 10
Run(szEditor ,szTargetFile)
Delay 10
QUIT
:FORUMLOOP
Send "go "
Send(szForumString)
Send "^M "
Delay 10
Waitfor("Press <CR> !",90)
Log("CLOSE")
Delay 10
Send "^M"
Waitfor( "!",120)
Delay 10
Send(szForumOptions)
Waitfor "New prompt:"
Delay 10
Send "!^M"
Waitfor "!!"
Delay 10
Send "LIB 1^M"
Waitfor( "!!",120)
Delay 10
Send "SCAN *.* DES LIB:ALL AGE:"
Send(szDateString)
IF (strlen(szKeyString)) > 1)
Send" KEYWORD:"
Send(szKeyString)
ENDIF
Send"^M"
Delay 1000
Log("OPEN",szTargetFile)
Waitfor("LIB 1 !!",900)
Delay 10
RETURN
;_______________________________________________________________
;
:MODULES
;enter the forums that you wish to search here,
;in the following pattern -
;
;Module1: Start WINSHARE Forum
Assign(szForumString,"CIS:WINSHARE")
GOSUB FORUMLOOP
Delay 10
;
;Module2: Start WINFUN Forum
Assign(szForumString,"CIS:WINFUN")
GOSUB FORUMLOOP
Delay 10
;
;Module3: Start Windows' User Group Forum
Assign(szForumString,"CIS:WUGNET")
GOSUB FORUMLOOP
Delay 10
;
;Module4: Start WINDOWS SOURCES Forum
Assign(szForumString,"ZNT:WINSOU")
GOSUB FORUMLOOP
Delay 10
;
RETURN