home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Monster Media 1993 #2
/
Image.iso
/
comm
/
mbbs25a4.zip
/
MACROCFG.MAC
< prev
next >
Wrap
Text File
|
1993-05-30
|
34KB
|
1,133 lines
MACROCFG.MAC 2.5 ALPHA
by Jeff Oberlee (C)opyright 1992,93
{:alr} {MACL MACROBBS.MAC,WF3} {:alu} {MACL MACROBBS.MAC,bbs}
{:start}
{SPOC n} {CURS y} {LOCA y}
{SETV bbs,BBS's name here}
{SETV sysop,Sysop}
{SETV syspass,system}
{SETV datadir,c:\commo\macrobbs\}
{SETV msgsdir,c:\commo\msgs\}
{SETV max,100}
{SETV userdir,c:\commo\callers\}
{SETV filedir,c:\commo\files\}
{SETV mspeed,2400}
{SETV initstr,ATE0H0M0Q0V1X4}
{SETV bw,y}
{SETV term,a}
{SETV cb,y}
{SETV dal,200}
{SETV sal,100}
{SETV nual,0}
{SETV ring,RING}
{SETV connect,CONNECT}
{SETV tlc,60}
{SETV lock,n}
{SETV bink,n}
{SETV para,8n1}
{SETV nicd,0}
{SETV uicd,1}
{SETV pp,1}
{SETV busy,ATM0H1}
{SETV maindir,c:\commo}
{SETV clr1,n}
{SETV hang,y}
{IFEX %_hom%MACROBBS.CFG,,RC1}
{ROPE %_hom%MACROBBS.CFG,RC1}
{READ bbs}
{READ sysop}
{READ syspass}
{READ datadir}
{READ msgsdir}
{READ max}
{READ userdir}
{READ filedir}
{READ mspeed}
{READ initstr}
{READ bw}
{READ term}
{READ cb}
{READ dal}
{READ sal}
{READ ring}
{READ connect}
{READ tlc}
{READ lock}
{READ bink}
{READ para}
{READ nicd}
{READ uicd}
{READ pp}
{READ busy}
{READ nual}
{READ maindir}
{READ clr1}
{READ hflo}
{READ hang}
{COMP bink,y} {IFCO ,RC1}
{READ myno}
{READ tagline}
{:RC1} {RCLO}
{PUSH}
{:I}
{RTRA-I n}
{SETE-P0 exit2}
{CLEA} {STAT n}
{DISP 2,36,4E, ╔ ▄ ▄ ▄▄▄ ▄▄▄ ▄▄▄ ▄▄▄▄ (tm) ═══════════╗}
{DISP 3,36,4E, ║ ██▄██ █▄█ █ █▄█▄ █ █ Version 2.5 ║}
{DISP 4,36,4E, ║ █ ▀ █ █ █ █▄▄ █ █ █▄▄█ CONFIGURATION ║}
{DISP 5,36,4E, ╚═════════ B B S ═════════════════════════╝
{DISP 7 ,2,0F,1.} {DISP 7 ,5,07,BBS System Data}
{DISP 8 ,2,0F,2.} {DISP 8 ,5,07,Modem/Term Config}
{DISP 9 ,2,0F,3.} {DISP 9,5,07,System Toggles/Fido}
{DISP 10,2,0F,4.} {DISP 10,5,07,Ext. Protocol Config (optional)}
{DISP 11,2,0F,5.} {DISP 11,5,07,Ext. Program Config (optional)}
{DISP 13,2,0F,D.} {DISP 13,5,0F,DONE!}
{DISP 14,2,0F,X.} {DISP 14,5,0C,ABORT to ^(COMMO^)}
{DISP 16,5,0E,Your choice? }
{SETG 0,,}
{:I1} {GETS ch,1,I1}
{COMP ch,1} {IFCO C}
{COMP ch,2} {IFCO M}
{COMP ch,3} {IFCO T}
{COMP ch,4} {IFCO P}
{COMP ch,5} {IFCO D}
{COMP ch,D} {IFCO S}
{COMP ch,X} {IFCO exit3}
{SEND ^H} {GOTO I1}
{:C} {CLEA}
{DISP 1,35,4E,System Data}
{SETV ch,50}
{COMP bink,y} {IFCO ,C0}
{SETV ch,64}
{LENG %tagline} {DECR ch,%_len} {LENG %myno} {DECR ch,%_len}
{DISP 3,1,09, * Origin: <BBS NAME> %tagline (%myno)}
{COMP ch,50} {IFCO-LE C0}
{SETV ch,50}
{:C0}
{SETV temp,13} {INCR temp,%ch}
{DISP 4,2,0F,BBS name? }
{DISP 4,%temp,0F,(Upto %ch chars.)}
{DISP 4,12,0E,%bbs}
{:C1} {GETS-A bbs,%ch,C1}
{LENG %bbs} {COMP _len,%ch} {IFCO-LE C9}
{SETV bbs} {GOTO C}
{:C9} {DISP 5,2,0F,Sysop handle? (the name you wish to go by)}
{DISP 5,16,0E,%sysop}
{:C2} {GETS-A sysop,30,C2}
{DISP 6,2,0F,System password? (word that protects important stuff)}
{DISP 6,19,0E,%syspass}
{:C3} {GETS-A syspass,15,C3}
{DISP 8,2,0F,Disk directory containing your ^(COMMO^) files: (Full path - NO "\" at end.)}
{DISP 9,2,0E,%maindir}
{:C14} {GETS-A maindir,70,C14}
{DISP 10,2,0F,Disk directory for BBS system data files: (Full path WITH "\" at end.)}
{DISP 11,2,0E,%datadir}
{:C4} {GETS-A datadir,70,C4}
{DISP 12,2,0F,Disk directory for MESSAGE BASE data files: (Full path WITH "\" at end.)}
{DISP 13,2,0E,%msgsdir}
{:C5} {GETS-A msgsdir,70,C5}
{DISP 14,2,0F,Disk directory for FILE BASE data files: (Full path WITH "\" at end.)}
{DISP 15,2,0E,%filedir}
{:C8} {GETS-A filedir,70,C8}
{DISP 16,2,0F,Disk directory for the userfiles: (Full path WITH "\" at end.)}
{DISP 17,2,0E,%userdir}
{:C7} {GETS-A userdir,70,C7}
{DISP 19,2,0F,Default NEW USER access level (0-999, '0' recommended) : }
{DISP 19,59,0E,%nual}
{:C13} {GETS-A nual,3,C13}
{DISP 20,2,0F,(D)OS DOORWAY Access Level (0-999) : }
{DISP 20,39,0E,%dal}
{:C10} {GETS-A dal,3,C10}
{DISP 21,2,0F,MESSAGE (S)ysop functions Access Level (0-999) : }
{DISP 21,51,0E,%sal}
{:C11} {GETS-A sal,3,C11}
{SETV ch,%max}
{DISP 22,2,0F,Maximum message length (1-100 lines) : }
{:C6} {SETV ch,%max}
{DISP 22,41,0E,%ch}
{GETS-A ch,3,C6}
{COMP ch,1} {IFCO-L C6}
{COMP ch,100} {IFCO-G C6}
{SETV max,%ch}
{DISP 23,2,0F,Time limit per call (in minutes) : }
{DISP 23,37,0E,%tlc}
{:C12} {GETS-A tlc,3,C12}
{GOTO I}
{:M} {CLEA}
{SETV dline,yn}
{DISP 1,34,4E,Modem/Terminal}
{:M1} {DISP 4,2,0F,Lock serial port at highest baud rate? (y/n) [%lock] : ^H}
{GETS ch,1,M13}
{INST dline,%ch} {IFCO ,M1}
{SETV lock,%ch}
{:M13}
{SETV ch,%mspeed}
{COMP lock,y} {IFCO ,M14}
{DISP 5,2,0F,Lock serial port at what speed? : }
{DISP 5,36,0E,%mspeed}
{SETV hflo,y}
{GETS-A ch,6,M10}
{COMP ch,1} {IFCO-L M13}
{SETV %mspeed,%ch} {GOTO M10}
{:M14} {DISP 5,2,0F,What's your modem's highest CONNECT speed? : }
{DISP 5,47,0E,%mspeed}
{SETV hflo,n}
{GETS-A ch,6,M10}
{COMP ch,1} {IFCO-L M14}
{SETV %mspeed,%ch}
{:M10} {DISP 6,2,0F,Data format parameters? (Eg. 8n1, 7e1, etc) : }
{DISP 6,49,0E,%para}
{:M6} {GETS-A para,3,M6}
{:M11} {SETV dline,atv}
{DISP 7,2,0F,Terminal type? A=ANSI, T=TTY, V=VT100 [%term] : ^H}
{GETS ch,1,M12}
{INST %dline,%ch} {IFCO ,M11}
{SETV term,%ch}
{:M12} {INST %dline,%term} {IFCO ,M11}
{DISP 8,2,0F,Normal inter-character delay? (see COMMO.DOC) : }
{DISP 8,50,0E,%nicd}
{:M7} {GETS-A nicd,3,M7}
{DISP 9,2,0F,ASCII UPLOAD inter-character delay? (for logon/off screens) : }
{DISP 9,64,0E,%uicd}
{:M8} {GETS-A uicd,3,M8}
{DISP 10,2,0F,Delay (in seconds) before the Off-line Options PASSWORD prompt?}
{DISP 11,2,0F,(Slower modems may need more time) : }
{DISP 11,39,0E,%pp}
{:M9} {GETS-A pp,2,M9}
{DISP 13,2,0F,Modem init string? }
{DISP 13,21,0E,%initstr}
{:M2} {GETS-A initstr,40,M2}
{DISP 14,2,0F,Modem BUSY string? }
{DISP 14,21,0E,%busy}
{:M5} {GETS-A busy,20,M5}
{DISP 15,2,0F,The string your modem returns when the phone rings?}
{DISP 16,2,0F,(Eg. RING) : }
{DISP 16,15,0E,%ring}
{:M3} {GETS-A ring,15,M3}
{DISP 17,2,0F,The string your modem returns upon connection? (Excluding speed)}
{DISP 18,2,0F,(Eg. CONNECT) : }
{DISP 18,18,0E,%connect}
{:M4} {GETS-A connect,15,M4}
{GOTO I}
{:T} {CLEA}
{SETV dline,yn}
{DISP 1,33,4E,System Toggles}
{:T1} {DISP 4,2,0F,Would you like the Wait Screen to blank? (ScreenSaver) (y/n) [%bw] : ^H}
{GETS ch,1,T10}
{INST %dline,%ch} {IFCO ,T1}
{SETV bw,%ch}
{:T10} {DISP 5,2,0F,Clear the Offline Wait Screen before pop-up menu display? (y/n) [%clr1] : ^H}
{GETS ch,1,T3}
{INST %dline,%ch} {IFCO ,T10}
{SETV clr1,%ch}
{:T3} {DISP 6,2,0F,Capture chat sessions? (y/n) [%cb] : ^H}
{GETS ch,1,T12}
{INST %dline,%ch} {IFCO ,T3}
{SETV cb,%ch}
{:T12} {DISP 7,2,0E,If you use MacroBBS as a door off znother BBS, you may not want to HANG-UP}
{DISP 8,2,0E,when a Caller exits MacroBBS. For NORMAL operation, however, answer 'Yes'.}
{DISP 9,2,0F,Should MacroBBS HANG-UP when a Caller logs off? (y/n) [%hang] : ^H}
{GETS ch,1,T5}
{INST %dline,%ch} {IFCO ,T3}
{SETV hang,%ch}
{:T5} {DISP 11,2,0F,Utilize a front-end mailer? (Eg. BinkleyTerm) (y/n) [%bink] : ^H}
{GETS ch,1,T6}
{INST %dline,%ch} {IFCO ,T12}
{SETV bink,%ch}
{:T6} {COMP bink,y} {IFCO ,TEX}
{:T7} {DISP 12,2,0F,Your FidoNet node address? [%myno] : }
{GETS ch,20,T8}
{SETV myno,%ch}
{:T8} {COMP myno,} {IFCO T7}
{:T9} {SETV ch,64}
{LENG %bbs} {DECR ch,%_len} {LENG %myno} {DECR ch,%_len}
{DISP 13,2,0F,The origin TagLine appears between BBS NAME & NODE# in Fido msgs:}
{DISP 14,1,09, * Origin: %bbs <TAGLINE> (%myno)}
{DISP 15,2,0F,You may use upto %ch characters for the TagLine.}
{DISP 16,2,09,: }
{DISP 16,4,, }
{DISP 16,4,0E,%tagline}
{GETS-A tagline,%ch}
{LENG %tagline} {COMP _len,%ch} {IFCO-LE TEX}
{SETV tagline} {GOTO T9}
{:TEX}
{GOTO I}
{:P} {CLEA}
{SETV dline,abcdefghijklmnopqrstuvwxyz}
{SETV sym} {SETV pname} {SETV path} {SETV send} {SETV recv} {SETV ch}
{DISP 1,23,4E,External Protocol Config}
{RTRA y,#26,97,65}
{:P7} {DISP 4,2,0F,Menu selection letter? } {DISP 4,25,07,(A-Z, ?=help, ENTER=quit] : ^H}
{GETS-H sym,1,I}
{COMP sym,?} {IFCO H}
{INST dline,%sym} {IFCO ,P7}
{RTRA-I n}
{IFEX MBXPRO-%sym.MAC,,P3}
{:P4}
{DISP 6,2,0F,%sym - Protocol definition exists! Options: A=ABORT, D=DELETE, E=EDIT: ^H}
{GETS-H ch,1,P4}
{COMP ch,a} {IFCO P}
{COMP ch,e} {IFCO P5}
{COMP ch,d} {IFCO ,P4}
{EXEC-N DEL MBXPRO-%sym.MAC}
{DISP 8,2,07,Deleted.} {PAUS 1}
{GOTO P}
{:P5}
{CLEA}
{ROPE MBXPRO-%sym.MAC,P6}
{READ sym} {READ pname} {READ path} {READ send} {READ recv} {RCLO}
{:P6} {DISP 1,23,4E,EDIT Protocol Definition}
{RTRA y,#26,97,65}
{:P8}
{DISP 3,2,0E,Editing %pname}
{DISP 4,2,0F,Menu selection letter? } {DISP 4,25,07,(A-Z, ?=help, ENTER=quit] : }
{GETS-H ch,1,I}
{COMP ch,?} {IFCO H}
{INST dline,%ch} {IFCO ,P8}
{SETV sym,%ch}
{RTRA-I n}
{:P3}
{DISP 6,2,0F,PROTOCOL English name? (Eg. ZMODEM)} {DISP 6,37,09, : }
{DISP 6,40,0E,%pname}
{GETS-A pname,20,P}
{DISP 8,2,0F,Protocol PATH\Name.ext (Eg. C:\COMMO\dsz.com)}
{DISP 9,2,09,: } {DISP 9,4,0E,%path}
{GETS-A path,50,P}
{DISP 11,2,0F,SEND FILE: DOS command line EXCLUDING THE PROTOCOL NAME.}
{DISP 12,2,07,Eg. port %%_por ha both sz %%filepath}
{DISP 13,2,09,: } {DISP 13,4,0E,%send}
{GETS-A send,73,P9}
{:P9} {DISP 15,2,0F,RECEIVE FILE: DOS command line EXCLUDING THE PROTOCOL NAME.
{DISP 16,2,07,Eg. port %%_por ha both rz %%filepath}
{DISP 17,2,09,: } {DISP 17,4,0E,%recv}
{GETS-A recv,73}
{:P1}
{DISP 19,5,0C,Ok to save? (Y,n) : ^H}
{GETS-H %ch,1,P2}
{COMP ch,y} {IFCO P2}
{COMP ch,n} {IFCO P,P1}
{:P2} {DISP 21,5,0C,Saving...}
{WOPE MBXPRO-%sym.MAC}
{WRIT %sym} {WRIT %pname} {WRIT %path} {WRIT %send} {WRIT %recv}
{WRIT }
{WRIT ^(:start^) ^(SEND ^J^M^J%%an0%%Start your%%an7 %pname %%an0%%transfer now.^) ^(GOTO %%proto^) ^(:exit^) ^(MACL MACRO%%mac.MAC,pdoor^)}
{WRIT }
{WRIT %pname ***************************}
{WRIT ^(:S%sym^) ^(EXEC %path %send^)} {SETV send}
{WRIT ^(GOTO exit^)}
{WRIT ^(:R%sym^) ^(EXEC %path %recv^)} {SETV recv}
{WRIT ^(GOTO exit^)}
{WCLO}
{DISP 21,14,07,OK} {PAUS 1}
{WOPE-A MBBSPROT.LST} {WRIT %sym} {WRIT %pname} {WCLO}
{DISP 21,14,07,OK} {PAUS 1}
{CALL warn}
{EDIT MBBSPROT.LST}
{GOTO P}
{:H} {CLEA}
{DISP 1,22,4E,MacroBBS Variable Usage Description}
{DISP 4 ,2,0F,VARIABLE DESCRIPTION}
{DISP 5 ,2,0F,---------- -------------------------------------------}
{DISP 7 ,2,09,%%files - contains the FILENAME only. Eg. MBBS20.ZIP}
{DISP 9 ,2,09,%%filepath - contains the FULL path including the filename}.
{DISP 10,2,09, Eg. C:\COMMO\FILES\F1\mbbs20.zip}
{DISP 12,2,09,%%transdir - contains the UPLOAD or DOWNLOAD path only.}
{DISP 13,2,09, Eg. C:\COMMO\FILES\F1}
{DISP 15,5 ,0F,Use the above variables as needed to define a protocol's DOS command lines.}
{DISP 16,5 ,0F,The following line is an exaple of a Zmodem RECEIVE command line:}
{DISP 17,13,0E, port %%_por ha both rz %%filepath}
{DISP 18,5 ,0F,(a ^(COMMO^) variable) -^^ ^^- (a MacroBBS variable)}
{:H1} {DISP 21,5,0F,Press the SPACEBAR to continue... ^H}
{GETS-H %ch,1,H1}
{COMP ch, } {IFCO P,H1}
{:D} {CLEA}
{SETV dline,abcdefghijklmnoprstuvwxyz}
{SETV sym} {SETV pname} {SETV path} {SETV cmd}
{DISP 1,29,4E,External Program Config}
{RTRA y,#26,97,65}
{:D7} {DISP 4,2,0F,Menu selection letter? } {DISP 4,25,07,(A-Z, ENTER=quit] : ^H}
{GETS-H sym,1,I}
{INST dline,%sym} {IFCO ,D7}
{RTRA-I n}
{IFEX MBDOOR-%sym.MAC,,D3}
{:D4}
{DISP 6,2,0F,%sym - Door definition exists! Options: A=ABORT, D=DELETE, E=EDIT: ^H}
{GETS-H ch,1,D4}
{COMP ch,a} {IFCO D}
{COMP ch,e} {IFCO D5}
{COMP ch,d} {IFCO ,D4}
{EXEC-N DEL MBDOOR-%sym.MAC}
{DISP 8,2,07,Deleted.} {PAUS 1}
{GOTO D}
{:D5}
{CLEA}
{ROPE MBDOOR-%sym.MAC,D6}
{READ sym} {READ dr} {READ pname} {READ path} {READ cmd} {RCLO}
{EXEC-N DEL MBDOOR-%sym.MAC}
{:D6} {DISP 1,30,4E,EDIT Door Definition}
{RTRA y,#26,97,65}
{:D8}
{DISP 3,2,0E,Editing %pname}
{DISP 4,2,0F,Menu selection letter? } {DISP 4,25,07,(A-Z, ENTER=quit] : }
{GETS-H ch,1,I}
{INST dline,%ch} {IFCO ,D8}
{SETV sym,%ch}
{RTRA-I n}
{:D3}
{DISP 6,2,0F,PROGRAM English name? (Eg. Draw Poker)} {DISP 6,40,09, : }
{DISP 6,43,0E,%pname}
{GETS-A pname,20,D}
{DISP 8,2,0F,Program PATH? (Eg. C:\GAMES) NO "\" at end.}
{DISP 9,2,09,: } {DISP 9,4,0E,%path}
{GETS-A path,50,D}
{DISP 11,2,0F,Enter the COMPLETE command line OR a batch file name.
{DISP 12,2,07,Eg. DRAWPOKE DRAWPOKE.CFG (or just DRAWPOKR if a batch file)
{DISP 13,2,09,: } {DISP 13,4,0E,%cmd}
{GETS-A cmd,73,D}
{DISP 15,2,0F,Which UserInfo file should be created for this door program?
{DISP 16,2,0E,1. DOOR.SYS 2. DORINFO1.DEF 3. CHAIN.TXT 4. CALLINFO.BBS}
{:D9} {DISP 17,2,09,(1-4): } {DISP 17,9,0E, ^H}
{GETS-H dr,1,I}
{COMP dr,1} {IFCO-L D9}
{COMP dr,4} {IFCO-G D9}
{:D1}
{DISP 19,5,0C,Ok to save? (Y,n) : ^H}
{GETS-H ch,1,D2}
{COMP ch,y} {IFCO D2}
{COMP ch,n} {IFCO D,D1}
{:D2} {DISP 17,5,0C,Saving...}
{WOPE MBDOOR-%sym.MAC}
{WRIT %sym} {WRIT %dr} {WRIT %pname} {WRIT %path} {WRIT %cmd}
{WRIT }
{WRIT ^(:start^) ^(CLEA^)
{WRIT %pname ***************************}
{WRIT ^(EXEC-N CD %path^)}
{WRIT ^(EXEC %cmd^)
{WRIT ^(EXEC-N CD %maindir^)}
{WRIT ^(MACL MACRODOR.MAC,start^)}
{WCLO}
{WOPE-A MBBSDOOR.LST} {WRIT %sym} {WRIT %pname} {WCLO}
{DISP 17,14,07,OK} {PAUS 1}
{CALL warn}
{EDIT MBBSDOOR.LST}
{GOTO D}
{:S} {DISP 18,5,0F,Ok to save? (Y,n) : ^H}
{GETS-H %ch,1,S1}
{COMP ch,y} {IFCO S1}
{COMP ch,n} {IFCO exit,S}
{:S1} {DISP 19,5,03,Saving...} {PAUS 1}
{WOPE %_hom%MACROBBS.CFG}
{WRIT %bbs}
{WRIT %sysop}
{WRIT %syspass}
{WRIT %datadir}
{WRIT %msgsdir}
{WRIT %max}
{WRIT %userdir}
{WRIT %filedir}
{WRIT %mspeed}
{WRIT %initstr}
{WRIT %bw}
{WRIT %term}
{WRIT %cb}
{WRIT %dal}
{WRIT %sal}
{WRIT %ring}
{WRIT %connect}
{WRIT %tlc}
{WRIT %lock}
{WRIT %bink}
{WRIT %para}
{WRIT %nicd}
{WRIT %uicd}
{WRIT %pp}
{WRIT %busy}
{WRIT %nual}
{WRIT %maindir}
{WRIT %clr1}
{WRIT %hflo}
{WRIT %hang}
{COMP bink,y} {IFCO ,WC1}
{WRIT %myno}
{WRIT %tagline}
{:WC1} {WCLO}
{:exit}
{RCLO}
{MACL MACROBBS.MAC,bbs}
{:exit2}
{SETE-P0 EX1} {SETV ch}
{INPU ch,Return to MacroBBS now? (no save) y/N}
{COMP ch,y} {IFCO exit}
{:EX1} {RETURN}
{:exit3} {CLEA} {STAT y} {SPOC y}
{DISP 2,1,0E,Exiting to ^(COMMO^) ...^J^M}
{LOCA n} {INIT}
{MACL COMMO.MAC}
{:warn}
{CLEA}
{DISP 3,1,0E, You are about to enter ^(COMMO^)'s text editor to customize a list}
{DISP 4,1,0E,which will be used by MacroBBS.}
{DISP 6,1,0F,Press any key to continue...}
{SETG ,,n} {GETS-H ch,1}
{RETURN}
///////////////////////////////////////////////////////////////////////////
{:read_user}
{ROPE %userdir%%userno.USR,RU1}
{READ login_name}
{READ password}
{READ al}
{READ protocol}
{READ expert}
{READ a}
{READ fa}
{READ l_call}
{READ rname}
{READ from}
{READ pcpd}
{READ clr2}
{READ arcer}
{READ arc}
{RCLO}
{:RU1} {RETURN}
{:write_user}
{WOPE %userdir%%userno.USR}
{WRIT %login_name}
{WRIT %password}
{WRIT %al}
{WRIT %protocol}
{WRIT %expert}
{WRIT %a}
{WRIT %fa}
{WRIT %l_call}
{WRIT %rname}
{WRIT %from}
{WRIT %pcpd}
{WRIT %clr2}
{WRIT %arcer}
{WRIT %arc}
{WCLO}
{RETURN}
{:update_clist}
{ROPE %datadir%CALLERS.LST,UC1}
{WOPE %datadir%TEMP.000}
{:UC2} {READ ch} {READ cline} {READ dline}
{COMP ch,%userno} {IFCO UC3}
{WRIT %ch} {WRIT %cline} {WRIT %dline} {GOTO UC2}
{:UC3} {COMP s,1} {IFCO UC5}
{:UC4} {WRIT %ch}
{WRIT %login_name}
{WRIT %password}
{:UC5} {READ dline} {WRIT %dline} {GOTO UC5}
{:UC1} {WCLO}
{EXEC-N COPY %datadir%TEMP.000 %datadir%CALLERS.LST}
{EXEC-N DEL %datadir%TEMP.000}
{RETURN}
{:read_data}
{ROPE %datadir%CALLER.DAT,RD1}
{READ %callno}
{READ %tdcalls}
{READ pub}
{READ pvt}
{READ ttu}
{READ tf}
{READ ldate}
{READ stime}
{READ ftime}
{READ l_caller}
{READ luserno}
{READ uhigh}
{READ mhigh}
{READ fhigh}
{RCLO}
{:RD1} {RETURN}
{:write_data}
{WOPE %datadir%CALLER.DAT}
{WRIT %callno}
{WRIT %tdcalls}
{WRIT %pub}
{WRIT %pvt}
{WRIT %ttu}
{WRIT %tf}
{WRIT %ldate}
{WRIT %stime}
{WRIT %ftime}
{WRIT %login_name}
{WRIT %userno}
{WRIT %uhigh}
{WRIT %mhigh}
{WRIT %fhigh}
{WCLO}
{RETURN}
{:read_baseinfo}
{SETV fido}
{ROPE %msgsdir%A%a.BAS,RB1}
{READ bname}
{READ %bal}
{READ maxmsg}
{READ lomsgno}
{READ himsgno}
{READ fido}
{RCLO}
{:RB1} {RETURN}
{:update_baseinfo}
{WOPE %msgsdir%A%a.BAS}
{WRIT %bname}
{WRIT %bal}
{WRIT %maxmsg}
{WRIT %lomsgno}
{WRIT %himsgno}
{WRIT %fido}
{WCLO}
{RETURN}
{:match_name_userno}
{IFEX %datadir%CALLERS.LST,,MNU2}
{ROPE %datadir%CALLERS.LST,MNU2}
{:MNU1} {READ ch} {READ lname} {READ dline}
{COMP to,%ch} {IFCO MNU5}
{COMP to,%lname} {IFCO ,MNU1}
{:MNU5} {SETV to,%lname}
{SETV tono,%ch}
{RCLO}
{SETV t,1}
{GOTO MNU4}
{:MNU2} {SEND %an1%ID not found.} {PAUS 1}
{:MNU4} {RETURN}
{:EO2}
{DISP 14,1,07, ╔════════════════════════════════╗}
{DISP 15,1,07, ║ ║}
{DISP 16,1,07, ╚════════════════════════════════╝}
{DISP 17,1,, }
{RETURN}
///////////////////////////////////////////////////////////////////////////
{:menu}
{SETE exit5}
{SETG 0}
{COMP clr1,y} {IFCO ,CLR1}
{CLEA}
{:CLR1}
{CALL blank_box}
{DISP 7 ,46,0F, Master SysMenu}
{DISP 9 ,46,07,1.%an4 File Areas}
{DISP 10,46,07,2.%an4 Edit a FileList}
{DISP 11,46,07,3.%an4 Message Areas}
{DISP 12,46,07,4.%an4 Caller Records}
{:ME2} {DISP 15,46,07, (1-4, ENTER=quit) ^H}
{GETS-H ch,1,ME1}
{COMP ch,1} {IFCO-L ME2}
{COMP ch,4} {IFCO-G ME2}
{CALL blank_box}
{COMP ch,1} {IFCO EFA}
{COMP ch,2} {IFCO list_ed}
{COMP ch,3} {IFCO EMA}
{COMP ch,4} {IFCO ECA}
{:ME1} {SETV total} {SETV high} {SETV temp} {SETV na}
{COMP clr1,y} {IFCO exit5}
{CALL WF5}
{:exit4}
{MACL MACROBBS.MAC,m_init_w}
{:exit5}
{MACL MACROBBS.MAC,m_init}
{:EMA}
{SEND %an0}
{DISP 15,3,,%an7%%an9 Scanning...}
{SETV dline,Message Area(s)}
{CALL get_minfo}
{CALL EO2}
{:EM2} {SEND %an0}
{SETV dline,Message Area(s)}
{CALL AE1}
{COMP ch,e} {IFCO EM6}
{COMP ch,r} {IFCO EM21}
{COMP ch,d} {IFCO EM3,EM4}
{:get_minfo}
{SETV high,0} {SETV total,0} {SETV na,0} {SETV temp,0}
{:EM} {INCR temp} {COMP temp,%mhigh} {IFCO-G EM0}
{IFEX %msgsdir%A%temp.BAS,,EM}
{SETV high,%temp}
{INCR total} {GOTO EM}
{:EM0} {INCR na} {IFEX %msgsdir%A%na.BAS,EM0}
{RETURN}
{:EM21}
{CALL blank_box}
{DISP 7 ,46,0E,Review Message Area(s)}
{:EM22} {DISP 9 ,38,0F,Begin at which area? %an0(1-%mhigh) : ^H^H}
{GETS a,2,EM2}
{IFEX %msgsdir%A%a.BAS,,EM22}
{:EM23}
{CALL read_baseinfo}
{CALL msgdspl}
{DISP 11,38,07,LOmsg #: %an7%%lomsgno}
{DISP 12,38,07,HImsg #: %an7%%himsgno}
{CALL spacebar}
{COMP ch, } {IFCO ,EM2}
{:EM24} {INCR a}
{COMP a,%mhigh} {IFCO-G EM2}
{IFEX %msgsdir%A%a.BAS,EM23,EM24}
{:EM4} {CALL blank_box}
{DISP 7 ,49,0E,Add a Message Area}
{DISP 9 ,38,07,Name: %an7%%an12 } {DISP 9 ,44,,} {SEND %an7%%an12}
{GETS bname,30,EM2} {SEND %an0}
{:EM25} {DISP 10,38,07,FidoNet msg format? (y,n): ^H}
{GETS-H fido,1,EM25}
{COMP fido,y} {IFCO EM20}
{COMP fido,n} {IFCO ,EM25}
{:EM20} {DISP 11,38,07,Access Level: ^H^H^H}
{GETS bal,3,EM20}
{:EM1} {DISP 12,38,07,MAX msg #: ^H^H^H}
{GETS maxmsg,3,EM1}
{:EM10} {DISP 14,38,0C,Ok to save? (%an0%Y%an1,n) :%an0 ^H}
{GETS-H ch,1,EM5}
{COMP ch,y} {IFCO EM5}
{COMP ch,n} {IFCO EM4,EM10}
{:EM5} {SETV lomsgno,1} {SETV himsgno,0}
{SETV a,%na}
{DISP 15,38,07,Saving area #%a...}
{COMP a,%mhigh} {IFCO-LE EM19}
{CALL read_data}
{SETV mhigh,%a} {SETV login_name,%l_caller} {SETV userno,%luserno}
{CALL write_data}
{SETV count,0}
{:EM13} {INCR count}
{COMP count,%uhigh} {IFCO-G EM19}
{IFEX %msgsdir%INDEX\%count.IDX,,EM13}
{WOPE-A %msgsdir%INDEX\%count.IDX} {WRIT 1} {WCLO}
{GOTO EM13}
{:EM19} {CALL update_baseinfo}
{EXEC-N MD %msgsdir%A%a}
{GOTO EMA}
{:EM6} {CALL blank_box}
{DISP 7 ,49,0E,Edit a Message Area}
{DISP 9 ,38,0F,Edit which? (1 - %mhigh) : }
{GETS a,2,EM2}
{COMP a,1} {IFCO-L EM6}
{COMP a,%mhigh} {IFCO-G EM6}
{IFEX %msgsdir%A%a.BAS,,EM6}
{CALL read_baseinfo}
{CALL msgdspl}
{DISP 11,38,0D,(Press ENTER to keep same info)}
{:EM8} {DISP 12,38,07,Name: %an7%%an12 } {DISP 12,44,,} {SEND %an7%%an12}
{GETS ch,30,EM15}
{SETV bname,%ch}
{:EM15} {SEND %an0}
{DISP 13,38,07,Access Level: }
{GETS ch,3,EM9}
{SETV bal,%ch}
{:EM9} {SEND %an0} {DISP 14,38,07,MAX msg #: }
{GETS ch,3,EM12}
{SETV maxmsg,%ch}
{:EM12} {DISP 15,38,0C,Saving...}
{CALL update_baseinfo}
{GOTO EM6}
{:EM11} {SEND %an0}
{GOTO ME1}
{:EM3} {CALL blank_box}
{DISP 7 ,49,,%an7%%an9%DELETE%an3 a Message Area}
{DISP 9 ,38,0F,Delete which? (1 - %mhigh) : }
{GETS a,2,EM2}
{COMP a,1} {IFCO-L EM3}
{COMP a,%mhigh} {IFCO-G EM3}
{IFEX %msgsdir%A%a.BAS,,EM3}
{CALL read_baseinfo}
{CALL msgdspl}
{:EM14} {DISP 12,38,,%an7%DELETE%an3 this area? %an0(y,%an7%N%an0) ; ^H}
{GETS ch,1,EM2}
{COMP ch,n} {IFCO EM2}
{COMP ch,y} {IFCO ,EM14}
{DISP 14,38,,%an7%%an9%DELETING}
{EXEC-N DEL %msgsdir%A%a.*}
{EXEC-N DEL %msgsdir%A%a\*.msg}
{EXEC-N RD %msgsdir%A%a}
{CALL get_minfo}
{COMP a,%high} {IFCO-L EM2}
{CALL read_data)
{SETV mhigh,%high} {SETV login_name,%l_caller} {SETV userno,%luserno}
{CALL write_data)
{GOTO EM2}
{:msgdspl}
{CALL blank_box}
{SETV temp,0}
{COMP himsgno,0} {IFCO MD1}
{SETV temp,%himsgno} {DECR temp,%lomsgno} {INCR temp}
{:MD1} {DISP 6 ,38,0E, Message Area #%a %an3%%temp}
{COMP fido,y} {IFCO ,MD2}
{SEND %an3 Fido msg(s) } {GOTO MD3}
{:MD2} {SEND %an3 MBBS msg(s) }
{:MD3} {DISP 8 ,38,07,Name ..: %an7%%bname}
{DISP 9 ,38,07,AL ....: %an7%%bal}
{DISP 10,38,07,MAXmsgs: %an7%%maxmsg}
{RETURN}
{:spacebar}
{DISP 15,45,0E,SPACEBAR=next %an0%ENTER=quit ^H}
{:SB2} {GETS-H ch,1,SB1}
{COMP ch, } {IFCO ,spacebar}
{:SB1} {RETURN}
{:ECA}
{SEND %an0}
{DISP 15,3,,%an7%%an9 Scanning...}
{CALL get_cinfo)
{CALL EO2}
{:EC1} {SEND %an0}
{SETV dline,Caller Records}
{CALL AE1}
{COMP ch,e} {IFCO EC5}
{COMP ch,r} {IFCO EC20}
{COMP ch,d} {IFCO EC13,EC2}
{:get_cinfo}
{SETV high,0} {SETV total,0} {SETV na,0} {SETV temp,0}
{:EC} {INCR temp} {COMP temp,%uhigh} {IFCO-G EC0}
{IFEX %userdir%%temp.USR,,EC}
{SETV high,%temp}
{INCR total} {GOTO EC}
{:EC0} {INCR na} {IFEX %userdir%%na.USR,EC0}
{RETURN}
{:EC20}
{CALL blank_box}
{DISP 7 ,46,0E,Review Caller Records}
{:EC18} {DISP 9 ,38,0F,Begin at which record? %an0(1-%uhigh) : ^H^H}
{GETS userno,2,EC1}
{IFEX %userdir%%userno.USR,,EC18}
{:EC19} {CALL blank_box}
{SETV rname} {SETV from} {SETV l_call}
{CALL read_user}
{DISP 7 ,38,07,Handle..: %an7%%login_name}
{DISP 8 ,38,07,ID # ...: %an7%%userno}
{DISP 9 ,38,07,AL .....: %an7%%al} {SETV al}
{DISP 10,38,07,Password: %an7%%password} {SETV password}
{DISP 11,38,07,Name ...: %an7%%rname} {SETV rname}
{DISP 12,38,07,From ...: %an7%%from} {SETV from}
{DISP 13,38,07,LastCall: %an7%%l_call} {SETV l_call}
{CALL spacebar}
{COMP ch, } {IFCO ,EC1}
{:EC21} {INCR userno}
{COMP userno,%uhigh} {IFCO-G EC1}
{IFEX %userdir%%userno.USR,EC19,EC21}
{:EC2} {CALL blank_box}
{DISP 7 ,46,0E,Add a Caller Record}
{DISP 9 ,38,07,Handle? %an7%%an12 } {DISP 9,46,,} {SEND %an7%%an12}
{GETS temp,30,EC1}
{DISP 10,38,,%an3%Checking...}
{LENG %temp} {COMP %_len,3} {IFCO-L EC2}
{COMP temp,new} {IFCO EC2}
{COMP temp,1} {IFCO-GE EC2}
{SETV to,%temp}
{CALL match_name_userno}
{COMP t,1} {SETV t} {IFCO EC2}
{SEND %an0} {DISP 10,38,07,Password? }
{DISP 10,38,07,Password? }
{:EC11} {GETS password,15,EC11}
{DISP 11,38,07,Access Level? }
{SETV protocol,z}
{:EC16} {GETS al,3,EC16}
{:EC3} {DISP 13,38,0C,Ok to save? (%an0%Y%an1,n) :%an0 ^H}
{GETS-H ch,1,EC4}
{COMP ch,y} {IFCO EC4}
{COMP ch,n} {IFCO EC2,EC3}
{:EC4} {DISP 14,38,07,Saving #%na...}
{SETV login_name,%temp} {SETV userno,%na}
{COMP userno,%uhigh} {IFCO-LE EC17}
{CALL read_data}
{SETV uhigh,%na} {SETV login_name,%l_caller} {SETV userno,%luserno}
{CALL write_data}
{SETV login_name,%temp} {SETV userno,%na}
{WOPE-A %datadir%TIMEUSED.LOG} {WRIT %tlc} {WCLO}
{:EC17} {CALL write_user}
{WOPE-A %datadir%CALLERS.LST}
{WRIT %userno}
{WRIT %login_name}
{WRIT %password}
{WCLO}
{GOTO ECA}
{:EC5} {CALL blank_box}
{DISP 7 ,46,0E,Edit a Caller Record}
{DISP 9 ,38,0F,Enter a Handle or ID#.}
{DISP 10,38,07,: } {SEND %an3}
{GETS ch,30,EC1}
{DISP 11,38,,}
{SETV to,%ch}
{CALL match_name_userno}
{COMP t,1} {IFCO ,EC5} {SETV t}
{:EC6} {DISP 12,38,07,Edit%an4 %to%%an0?}
{DISP 13,43,0C,(%an0%Y%an1,n) : ^H}
{GETS-H ch,1,EC7}
{COMP ch,y} {IFCO EC7}
{COMP ch,n} {IFCO EC5,EC6}
{:EC7} {CALL blank_box}
{SETV userno,%tono}
{CALL read_user}
{DISP 7 ,50,07,Account #%userno}
{DISP 8 ,38,07,Handle: %an7%%login_name}
{DISP 9 ,38,07,Pword : %an7%%password}
{DISP 10,38,07,AL : %an7%%al}
{DISP 11,38,0D,(Press ENTER to keep the same)}
{DISP 12,38,07,Handle? %an7%%an12 } {DISP 12,46,,} {SEND %an7%%an12}
{GETS ch,30,EC8}
{DISP 13,38,07,}
{SETV login_name,%ch} {SEND %an0} {DISP 13,38,0C,Wait...}
{CALL update_clist}
{:EC8} {SEND %an0}
{DISP 13,38,07,Password: }
{GETS ch,15,EC9}
{SETV password,%ch} {DISP 14,38,0C,Wait...}
{CALL update_clist}
{:EC9} {DISP 14,38,07,Access Level? }
{GETS ch,3,EC10}
{SETV al,%ch}
{:EC10} {DISP 15,38,0C,Saving...}
{CALL write_user}
{GOTO EC5}
{:EC13} {CALL blank_box}
{DISP 7 ,46,0F,%an7%%an9%DELETE%an3 a Caller Record}
{DISP 9 ,38,0F,Enter a Handle or ID#.}
{DISP 10,38,07,: } {SEND %an1}
{GETS ch,30,EC1}
{SETV to,%ch}
{DISP 7 ,46,0F,%an7%DELETE%an3 a Caller Record}
{DISP 11,38,,}
{CALL match_name_userno}
{COMP t,1} {SETV t} {IFCO ,EC13}
{:EC14} {DISP 12,38,,%an7%DELETE%an1 %to%%an7?}
{DISP 13,45,07,(y/%an7%N%an0) : ^H}
{GETS ch,1,EC13}
{COMP ch,n} {IFCO EC13}
{COMP ch,y} {IFCO ,EC14}
{DISP 15,38,,%an7%%an9%DELETING}
{SETV userno,%tono}
{EXEC-N DEL %userdir%%userno.USR}
{EXEC-N DEL %userdir%INDEX\%userno.DAT}
{EXEC-N DEL %userdir%DATA\%userno.DAT}
{EXEC-N DEL %msgsdir%E%userno-*.*}
{EXEC-N DEL %userdir%REGS\%userno.REG}
{EXEC-N DEL %msgsdir%INDEX\%userno.IDX}
{EXEC-N DEL %msgsdir%TAGS\%userno.TAG}
{EXEC-N DEL %readdir%TAGS\%userno.OLR}
{SETV s,1} {CALL update_clist} {SETV s}
{CALL get_cinfo}
{COMP userno,%high} {IFCO-L EC1}
{CALL read_data)
{SETV uhigh,%high} {SETV login_name,%l_caller} {SETV userno,%luserno}
{CALL write_data)
{GOTO EC1}
{:EFA}
{SEND %an0}
{DISP 15,3,,%an7%%an9 Scanning...}
{CALL get_finfo}
{CALL EO2}
{:EF1} {SEND %an0}
{SETV dline,File Area(s)}
{CALL AE1}
{COMP ch,e} {IFCO EF5}
{COMP ch,r} {IFCO EF15}
{COMP ch,d} {IFCO EF13,EF2}
{:get_finfo}
{SETV high,0} {SETV total,0} {SETV na,0} {SETV temp,0}
{:EF} {INCR temp} {COMP temp,%fhigh} {IFCO-G EF0}
{IFEX %filedir%F%temp.BAS,,EF}
{SETV high,%temp}
{INCR total} {GOTO EF}
{:EF0} {INCR na} {IFEX %filedir%F%na.BAS,EF0}
{RETURN}
{:EF15}
{CALL blank_box}
{DISP 7 ,46,0E,Review File Area(s)}
{:EF17} {DISP 9 ,38,0F,Begin at which area? %an0(1-%fhigh) : ^H^H}
{GETS a,2,EF1}
{IFEX %filedir%F%a.BAS,,EF17}
{:EF18} {ROPE %filedir%F%a.BAS,EF5} {READ bname} {READ bal} {RCLO}
{CALL blank_box}
{DISP 8 ,50,0E,File Area %a}
{DISP 10,38,07,Name: %an7%%bname}
{DISP 11,38,07,AL : %an7%%bal}
{CALL spacebar}
{COMP ch, } {IFCO ,EF1}
{:EF19} {INCR a}
{COMP a,%fhigh} {IFCO-G EF1}
{IFEX %filedir%F%a.BAS,EF18,EF19}
{:EF2} {CALL blank_box}
{DISP 7 ,49,0E,Add a File Area}
{DISP 9 ,38,07,Name? %an7%%an12 } {DISP 9 ,44,,} {SEND %an7%%an12}
{GETS bname,30,EF1}
{SEND %an0} {DISP 10,38,07,Access Level? }
{:EF11} {GETS bal,3,EF11}
{:EF3} {DISP 12,38,0C,Ok to save? (%an0%Y%an1,n) :%an0 ^H}
{GETS-H ch,1,EF12}
{COMP ch,y} {IFCO EF12}
{COMP ch,n} {IFCO EF2,EF3}
{:EF12} {SETV fa,%na}
{DISP 14,38,07,Saving area #%fa...}
{COMP fa,%fhigh} {IFCO-LE EF16}
{CALL read_data}
{SETV fhigh,%fa} {SETV login_name,%l_caller} {SETV userno,%luserno}
{CALL write_data}
{:EF16} {WOPE %filedir%F%fa.BAS} {WRIT %bname} {WRIT %bal} {WCLO}
{WOPE %filedir%F%fa.LST}
{WRIT - unvalidated}
{WRIT Filename Size Description}
{WRIT ------------------------------------------------------------------------------}
{WCLO}
{EXEC-N MD %filedir%F%fa}
{GOTO EFA}
{:EF5} {CALL blank_box}
{DISP 7 ,49,0E,Edit a File Area}
{DISP 9 ,38,0F,Edit which? (1 - %fhigh) : }
{GETS fa,2,EF1}
{COMP fa,1} {IFCO-L EF5}
{COMP fa,%fhigh} {IFCO-G EF5}
{IFEX %filedir%F%fa.BAS,,EF5}
{ROPE %filedir%F%fa.BAS,EF5} {READ bname} {READ bal} {RCLO}
{:EF7} {CALL blank_box}
{DISP 7 ,50,0F,File Area #%fa}
{DISP 9 ,38,07,Name: %an7%%bname}
{DISP 10,38,07,AL : %an7%%bal}
{DISP 11,38,0D,(Press ENTER to keep same info)}
{DISP 12,38,07,Name? %an7%%an12 } {DISP 12,44,,} {SEND %an12}
{GETS ch,30,EF9}
{SETV bname,%ch}
{:EF9} {SEND %an0} {DISP 13,38,07,AL : }
{GETS ch,3,EF10}
{SETV bal,%ch}
{:EF10} {DISP 15,38,0C, Saving...}
{WOPE %filedir%F%fa.BAS} {WRIT %bname} {WRIT %bal} {WCLO}
{GOTO EF5}
{:EF13} {CALL blank_box}
{DISP 7 ,49,0F,%an7%%an9%DELETE%an3 a File Area}
{DISP 9 ,38,0F,DELETE which? (1 - %fhigh) : }
{GETS fa,2,EF1}
{COMP fa,1} {IFCO-L EF13}
{COMP fa,%fhigh} {IFCO-G EF13}
{IFEX %filedir%F%fa.BAS,,EF13}
{DISP 7 ,49,0F,%an7%DELETE%an3 a File Area}
{ROPE %filedir%F%fa.BAS,EF13} {READ bname} {READ bal} {RCLO}
{CALL blank_box}
{DISP 7 ,38,0E, File Area #%fa}
{DISP 9 ,38,07,Name: %an0%%bname}
{DISP 10,38,07,AL : %an0%%bal}
{:EF14} {DISP 12,38,,%an7%DELETE? %an0(y,%an7%N%an0) : ^H}
{GETS ch,1,EF13}
{COMP ch,n} {IFCO EF13}
{COMP ch,y} {IFCO ,EF14}
{EXEC-N DEL %filedir%F%fa\*.*}
{DISP 14,38,,%an7%%an9%DELETING}
{EXEC-N DEL %filedir%F%fa.*}
{EXEC-N RD %filedir%F%fa}
{CALL get_finfo}
{COMP fa,%high} {IFCO-L EF1}
{CALL read_data)
{SETV fhigh,%high} {SETV login_name,%l_caller} {SETV userno,%luserno}
{CALL write_data)
{GOTO EF1}
{:AE1}
{CALL blank_box}
{DISP 7 ,38,0E,%dline:}
{DISP 10,38,07,High # . . . . . . .%an7 %high}
{DISP 9 ,38,07,In use . . . . . . .%an7 %total}
{DISP 11,38,07,Next available . . .%an7 %na}
{:AE2} {DISP 15,42,07,Press ENTER for Master SysMenu}
{DISP 13,38,07,(%an7%A%an0)dd, (%an7%D%an0)elete, (%an7%E%an0)dit or (%an7%R%an0)eview? ^H}
{GETS-H ch,1,menu}
{SETV dline,ader}
{INST dline,%ch} {IFCO ,AE2}
{RETURN}
{:list_ed}
{CALL blank_box}
{DISP 15,3,0E, Which? %an0(1 - %fhigh) : ^H^H^H}
{GETS ch,2,LE}
{COMP ch,1} {IFCO-L list_ed}
{COMP ch,%fhigh} {IFCO-G list_ed}
{EDIT %filedir%F%ch.LST}
{:LE} {CALL EO2}
{GOTO menu}
///////////////////////////////////////////////////////////////////////////
{:blank_box}
{SETV mic,6}
{DISP 6 ,36,07,╔═════════════════════════════════════════╗
{DISP 7 ,36,07,║ ║}
{DISP 8 ,36,07,║ ║}
{DISP 9 ,36,07,║ ║}
{DISP 10,36,07,║ ║}
{DISP 11,36,07,║ ║}
{DISP 12,36,07,║ ║}
{DISP 13,36,07,║ ║}
{DISP 14,36,07,║ ║}
{DISP 15,36,07,║ ║}
{DISP 16,36,07,╚═════════════════════════════════════════╝}
{SETV mic}
{RETURN}
{:WF5}
{DISP 6 ,36,17,╔═════════════════════════════════════════╗
{DISP 7 ,36,17,║ Embryo ____ by Shad Muegge ║}
{DISP 8 ,36,17,║ ---------^|\/ o \------------------ ║}
{DISP 9 ,36,17,║ ____^| ,__^| Association of ║}
{DISP 10,36,17,║ / o \/^|____/ Babble Fish ║}
{DISP 11,36,17,║ ^|__, ^|____ Programmers ║}
{DISP 12,36,17,║ \____^|\/ o \ ║}
{DISP 13,36,17,║ ^| ,__^| MEMBER ║}
{DISP 14,36,17,║ ---------^|/\____/------------------ ║}
{DISP 15,36,17,║ ║}
{DISP 16,36,17,╚═════════════════════════════════════════╝}
{RETURN}