home *** CD-ROM | disk | FTP | other *** search
/ Monster Media 1993 #2 / Image.iso / clipper / nfpat8.zip / ISPRINT.ASM < prev    next >
Assembly Source File  |  1993-07-16  |  9KB  |  226 lines
  1. ; File......: ISPRINT.ASM
  2. ; Author....: Ted Means
  3. ; Date......: $Date:   16 Jul 1993 00:00:18  $
  4. ; Revision..: $Revision:   1.3  $
  5. ; Log file..: $Logfile:   C:/nanfor/src/isprint.asv  $
  6. ; 
  7. ; This function is an original work by Ted Means and is placed in the
  8. ; public domain.  I got the idea from Norm Mongeau, but the code is
  9. ; all mine.
  10. ;
  11. ; Modification history:
  12. ; ---------------------
  13. ;
  14. ; $Log:   C:/nanfor/src/isprint.asv  $
  15. ;  
  16. ;     Rev 1.3   16 Jul 1993 00:00:18   GLENN
  17. ;  Modified for compatibility in protected mode under ExoSpace.  Should
  18. ;  work in real mode as well.
  19. ;  
  20. ;  
  21. ;     Rev 1.2   15 Aug 1991 23:07:56   GLENN
  22. ;  Forest Belt proofread/edited/cleaned up doc
  23. ;  
  24. ;     Rev 1.1   14 Jun 1991 19:54:38   GLENN
  25. ;  Minor edit to file header
  26. ;  
  27. ;     Rev 1.0   01 Apr 1991 01:03:26   GLENN
  28. ;  Nanforum Toolkit
  29. ;  
  30. ;
  31.  
  32.  
  33. ;  $DOC$
  34. ;  $FUNCNAME$
  35. ;     FT_ISPRINT()
  36. ;  $CATEGORY$
  37. ;     DOS/BIOS
  38. ;  $ONELINER$
  39. ;     Check printer status
  40. ;  $SYNTAX$
  41. ;     FT_ISPRINT( [ <cDevice> ] ) -> lResult
  42. ;  $ARGUMENTS$
  43. ;     <cDevice> is optional and is the device to test (LPT2, COM1, etc.).
  44. ;     If omitted, the function will default to the PRN device.
  45. ;  $RETURNS$
  46. ;     .T.  if device is ready for output.
  47. ;     .F.  if one of the following conditions occurs:
  48. ;          1)  The device is not ready.
  49. ;          2)  The device does not exist.
  50. ;          3)  DOS couldn't open the device for some reason
  51. ;              (such as no file handles available).
  52. ;  $DESCRIPTION$
  53. ;     The Clipper IsPrinter() function is somewhat limited because it only
  54. ;     works with LPT1.  Furthermore, it talks directly to the hardware, so
  55. ;     if you have redirected LPT1 via the DOS MODE command, the IsPrinter()
  56. ;     function will return erroneous results.
  57. ;
  58. ;     This function offers a better alternative.  Instead of talking to the
  59. ;     hardware, it issues a DOS call that checks to see if the device is
  60. ;     ready or not.  That gives DOS an opportunity to deal with any
  61. ;     redirections, and since you pass the device name as a parameter, you
  62. ;     can test any device, not just LPT1 (note that the function defaults
  63. ;     to PRN if you fail to pass a valid parameter).
  64. ;
  65. ;     The function also temporarily traps the DOS critical error handler so
  66. ;     you don't get any nasty error messages if the device isn't ready.  It
  67. ;     restores the old critical error handler before exiting.
  68. ;
  69. ;     Note that although this function is mainly designed for testing
  70. ;     printers, you can also check to see if a drive is ready.  Since DOS
  71. ;     thinks the NUL device exists on every drive, you can pass a drive
  72. ;     letter followed by NUL as a parameter.  If DOS is able to open the
  73. ;     NUL device, then the drive is ready, otherwise the door is open or
  74. ;     something else is wrong.
  75. ;
  76. ;     The source code is written to adhere to Turbo Assembler's IDEAL mode.
  77. ;     To use another assembler, you will need to rearrange the PROC and
  78. ;     SEGMENT directives, and also the ENDP and ENDS directives (a very
  79. ;     minor task).
  80. ;  $EXAMPLES$
  81. ;     IF ! FT_ISPRINT()
  82. ;        Qout( "PRN is not ready!" )
  83. ;     ENDIF
  84. ;
  85. ;     IF ! FT_ISPRINT( "COM2" )
  86. ;        Qout( "Check the device on COM2.  Something is wrong." )
  87. ;     ENDIF
  88. ;
  89. ;     IF ! FT_ISPRINT( "A:\NUL" )
  90. ;        Qout( "Oops, better check drive A!" )
  91. ;     ENDIF
  92. ;  $END$
  93. ;
  94.  
  95.          IDEAL
  96.  
  97. Public   FT_ISPRINT
  98.  
  99. Old24Vec EQU       DWord Ptr BP - 4
  100. Old24Ofs EQU       Word Ptr BP - 4
  101. Old24Seg EQU       Word Ptr BP - 2
  102. Handle   EQU       Word Ptr BP - 6
  103. OpenFlag EQU       Byte Ptr BP - 8
  104.  
  105. Extrn    __ParInfo:Far
  106. Extrn    __ParC:Far
  107. Extrn    __RetL:Far
  108.  
  109. Group    DGROUP    _ftData
  110.  
  111. Segment  _ftData   Word      Public    "DATA"
  112. IsReady  DB        ?
  113. Ends     _ftData
  114.  
  115. Segment  _NanFor   Word      Public    "CODE"
  116.          Assume    CS:_NanFor,DS:DGROUP
  117.  
  118. Proc     FT_ISPRINT          Far
  119.  
  120.          Push      BP                        ; Save BP
  121.          Mov       BP,SP                     ; Set up stack reference
  122.          Sub       SP,8                      ; Allocate room for locals
  123.          Mov       [Handle],4                ; Default to PRN
  124.          Mov       [OpenFlag],0              ; Initialize flag
  125.  
  126.          Xor       AX,AX                     ; Request param count
  127.          Push      AX                        ; Put request on stack
  128.          Call      __ParInfo                 ; Count params
  129.          Or        AX,AX                     ; Zero params?
  130.          JZ        PrtTest                   ; Yes, so use default
  131.  
  132. ParType: Mov       AX,1                      ; Specify first param
  133.          Push      AX                        ; Put param # on stack
  134.          Call      __ParInfo                 ; Get type
  135.          Test      AX,1                      ; Character?
  136.          JZ        PrtTest                   ; No, so use default
  137.  
  138. GetParam:Mov       AX,1                      ; Specify first param
  139.          Push      AX                        ; Put param # on stack
  140.          Call      __ParC                    ; Retrieve parameter
  141.  
  142.          Push      DS                        ; Save DS
  143.          Mov       DS,DX                     ; Get segment of device name
  144.          Mov       DX,AX                     ; Get offset of device name
  145.          Mov       AX,3D01h                  ; DOS service--open file or device
  146.          Int       21h                       ; Call DOS
  147.          Pop       DS                        ; Restore DS
  148.          JNC       DHandle                   ; No error, so device was opened
  149.          Xor       AX,AX                     ; Set return value to false
  150.          Jmp       Short RetVal              ; We're outta here
  151.  
  152. DHandle: Mov       [Handle],AX               ; Supply device's handle
  153.          Inc       [OpenFlag]                ; Set flag so close can occur
  154.          
  155. PrtTest: Call      Near _FTHook24            ; Install local INT 24h handler
  156.          Mov       [IsReady],1               ; Assume printer ready
  157.          Mov       AX,4407h                  ; DOS service--get output status
  158.          Mov       BX,[Handle]               ; Choose standard print device
  159.          Int       21h                       ; Call DOS
  160.          And       AL,[IsReady]              ; Combine error reports
  161.          CBW                                 ; Clear high byte
  162.          Call      Near _FTUnHook24          ; Restore old INT 24h vector
  163.  
  164. RetVal:  Push      AX                        ; Put return value on stack
  165.          Call      __RetL                    ; Return status to Clipper app
  166.  
  167.          Cmp       [OpenFlag],1              ; Need to close device?
  168.          JNE       Exit                      ; No, so go ahead and exit
  169.          Mov       AH,3Eh                    ; DOS service--close handle
  170.          Mov       BX,[Handle]               ; Supply file handle
  171.          Int       21h                       ; Call DOS
  172.  
  173. Exit:    Mov       SP,BP                     ; Realign stack
  174.          Pop       BP                        ; Restore BP
  175.          Ret                                 ; Far return to Clipper app
  176. Endp     FT_ISPRINT
  177.  
  178.  
  179.  
  180. Proc     _FTHook24 Near
  181.  
  182.          Push      DS                        ; Save DS
  183.  
  184.          Mov       AX,3524h                  ; DOS service--get INT 24h vector
  185.          Int       21h                       ; Call DOS
  186.          Mov       [Old24Ofs],BX             ; Save offset
  187.          Mov       [Old24Seg],ES             ; Save segment value
  188.  
  189.          Push      CS
  190.          Pop       DS                        ; Set DS to local segment
  191.          Mov       DX,Offset _NanFor:Int_24  ; Offset of local handler
  192.          Mov       AX,2524h                  ; DOS service--set INT 24h vector
  193.          Int       21h                       ; Call DOS  
  194.  
  195.          Pop       DS
  196.          Ret                                 ; Near return
  197. Endp     _FTHook24
  198.  
  199.  
  200.  
  201. Proc     _FTUnHook24         Near
  202.  
  203.          Push      DS                        ; Save DS
  204.          Push      AX                        ; Save AX
  205.          Mov       AX,2524h                  ; DOS service--set INT 24h vector
  206.          LDS       DX,[Old24Vec]             ; Get address of original handler
  207.          Int       21h                       ; Call DOS
  208.          Pop       AX
  209.          Pop       DS
  210.          Ret                                 ; Near return
  211. Endp     _FTUnHook24
  212.  
  213.  
  214.  
  215. Proc     Int_24    Far
  216.  
  217.          Push      DS
  218.          Mov       AX,DGROUP
  219.          Mov       DS,AX
  220.          Mov       [IsReady],0               ; Indicate not ready
  221.          Pop       DS
  222.          Xor       AX,AX                     ; Tell DOS to ignore error
  223.          IRet
  224. Endp     Int_24
  225. Ends     _NanFor
  226. End