home *** CD-ROM | disk | FTP | other *** search
/ Monster Media 1993 #2 / Image.iso / clipper / nettos11.zip / MISC / FNCBALL.ASM < prev    next >
Encoding:
Assembly Source File  |  1992-10-18  |  5.4 KB  |  120 lines
  1. ; File......: FNCBALL.ASM
  2. ; Author....: Ted Means
  3. ; CIS ID....: 73067,3332
  4. ; Date......: $Date$
  5. ; Revision..: $Revision$
  6. ; Log file..: $Logfile$
  7. ; 
  8. ; This is an original work by Ted Means and is placed in the
  9. ; public domain.
  10. ;
  11. ; Modification history:
  12. ; ---------------------
  13. ;
  14. ; $Log$
  15. ;
  16.  
  17. IDEAL
  18.  
  19. PUBLIC   __FNCBALL
  20.  
  21. EXTRN    __PARINFO:FAR
  22. EXTRN    __PARCLEN:FAR
  23. EXTRN    __PARC:FAR
  24. EXTRN    __PARNI:FAR
  25. EXTRN    __RETCLEN:FAR
  26. EXTRN    __RETNI:FAR
  27.  
  28. SEGMENT  _FNNET  WORD      PUBLIC    "CODE"
  29.          ASSUME    CS:_FNNET
  30.  
  31. PROC     __FNCBALL   FAR
  32.  
  33.          PUSH      BP                        ; Save BP
  34.          MOV       BP,SP                     ; Set up stack reference
  35.          SUB       SP,12                     ; Create local vars on stack
  36.          MOV       [WORD PTR BP - 2],DX      ; Load instruction sequence into
  37.          MOV       [WORD PTR BP - 4],AX      ; local variable
  38.          MOV       [WORD PTR BP - 6],0       ; Initialize return value
  39.          LEA       AX,[BP - 4]               ; Get IP of bit operation code
  40.          MOV       [WORD PTR BP - 12],AX     ; Store in local var
  41.          MOV       [WORD PTR BP - 10],SS     ; Store CS of bit op code
  42.  
  43.          XOR       AX,AX                     ; Prepare to count params
  44.          PUSH      AX                        ; Save on stack
  45.          CALL      __PARINFO                 ; Call parameter info routine
  46.          ADD       SP,2                      ; Realign stack
  47.          MOV       BX,2                      ; Param count should be 2
  48.          CMP       [BYTE PTR BP - 4],0F7h    ; Unless NOT or NEG requested
  49.          JNE       HOWMANY                   ; If not, don't worry
  50.          DEC       BX                        ; NOT and NEG use only one param
  51. HOWMANY: CMP       AX,BX                     ; See if two parameters passed
  52.          JNE       DONE_N                    ; If not, return zero
  53.  
  54.          CMP       [BYTE PTR BP - 4],0F7h    ; See if NOT or NEG requested
  55.          JE        TEST1                     ; If so, no second param
  56.  
  57. TEST2:   MOV       AX,2                      ; Prepare to test second param
  58.          PUSH      AX                        ; Save on stack
  59.          CALL      __PARINFO                 ; Call parameter info routine
  60.          ADD       SP,2                      ; Realign stack
  61.          TEST      AX,2                      ; See if parameter is numeric
  62.          JZ        DONE_N                    ; If not, return zero
  63.  
  64. TEST1:   MOV       AX,1                      ; Prepare to test first param
  65.          PUSH      AX                        ; Save on stack
  66.          CALL      __PARINFO                 ; Call parameter info routine
  67.          ADD       SP,2                      ; Realign stack
  68.          TEST      AX,3                      ; See if character or numeric
  69.          JZ        DONE_N                    ; If not, return zero
  70.  
  71. WHICH:   TEST      AX,1                      ; See if character
  72.          MOV       AX,1                      ; Specify first parameter
  73.          PUSH      AX                        ; Save on stack
  74.          JNZ       GET_C                     ; If not, use __PARC
  75.          
  76. GET_N:   CALL      __PARNI                   ; Get param as integer
  77.          MOV       [WORD PTR BP - 8],OFFSET _FNNET:DONE_N
  78.                                              ; Store offset of return handler
  79.          JMP       SHORT GET_2               ; Skip over __PARC call
  80.  
  81. GET_C:   CALL      __PARC                    ; Get param as character
  82.          MOV       ES,DX                     ; Put segment portion into ES
  83.          MOV       BX,AX                     ; Put offset portion into BX
  84.          MOV       AX,[WORD PTR ES:BX]       ; Load value into AX
  85.          MOV       [WORD PTR BP - 8],OFFSET _FNNET:DONE_C
  86.                                              ; Store offset of return handler
  87.  
  88.          CMP       [BYTE PTR BP - 4],0F7h    ; See if NOT or NEG requested
  89.          JE        MANIP                     ; If so, no second param
  90.  
  91. GET_2:   ADD       SP,2                      ; Realign stack
  92.          MOV       [WORD PTR BP - 6],AX      ; Put param into local var
  93.          MOV       AX,2                      ; Specify second param
  94.          PUSH      AX                        ; Save on stack
  95.          CALL      __PARNI                   ; Retrieve second parameter
  96.          ADD       SP,2                      ; Realign stack
  97.          MOV       CX,AX                     ; In case of shift or rotate
  98.  
  99. MANIP:   CALL      [DWORD PTR BP - 12]       ; Execute bit instruction
  100.          JMP       [WORD PTR BP - 8]         ; Jump to return handler
  101.  
  102. DONE_N:  PUSH      [WORD PTR BP - 6]         ; Put return value on stack
  103.          CALL      __RETNI                   ; Return value to Clipper app
  104.          JMP       SHORT EXIT                ; Go to exit handler
  105.  
  106. DONE_C:  MOV       AX,2                      ; Length of string
  107.          PUSH      AX                        ; Save on stack
  108.          LEA       AX,[WORD PTR BP - 6]      ; Get address of return value
  109.          PUSH      SS                        ; Segment of return value
  110.          PUSH      AX                        ; Offset of return value
  111.          CALL      __RETCLEN                 ; Return value to Clipper app
  112.  
  113. EXIT:    MOV       SP,BP                     ; Reset stack pointer
  114.          POP       BP                        ; Restore BP
  115.          RETF                                ; Return to application
  116.  
  117. ENDP     __FNCBALL
  118. ENDS     _FNNET
  119. END
  120.