home *** CD-ROM | disk | FTP | other *** search
/ Monster Media 1993 #2 / Image.iso / clipper / isprin.zip / ISPRINT.ASM next >
Assembly Source File  |  1993-07-14  |  9KB  |  224 lines
  1. ; File......: ISPRINT.ASM
  2. ; Author....: Ted Means
  3. ; Date......: $Date:   15 Aug 1991 23:07:56  $
  4. ; Revision..: $Revision:   1.2  $
  5. ; Log file..: $Logfile:   E:/nanfor/src/isprint.asv  $
  6. ; 
  7. ; This function is an original work by Ted Means and is placed in the
  8. ; public domain.  I got the idea from Norm Mongeau, but the code is
  9. ; all mine.
  10. ;
  11. ; Modification history:
  12. ; ---------------------
  13. ;
  14. ; $Log:   E:/nanfor/src/isprint.asv  $
  15. ;  
  16. ;     Rev 1.2   15 Aug 1991 23:07:56   GLENN
  17. ;  Forest Belt proofread/edited/cleaned up doc
  18. ;  
  19. ;     Rev 1.1   14 Jun 1991 19:54:38   GLENN
  20. ;  Minor edit to file header
  21. ;  
  22. ;     Rev 1.0   01 Apr 1991 01:03:26   GLENN
  23. ;  Nanforum Toolkit
  24. ;  
  25. ;
  26.  
  27.  
  28. ;  $DOC$
  29. ;  $FUNCNAME$
  30. ;     FT_ISPRINT()
  31. ;  $CATEGORY$
  32. ;     DOS/BIOS
  33. ;  $ONELINER$
  34. ;     Check printer status
  35. ;  $SYNTAX$
  36. ;     FT_ISPRINT( [ <cDevice> ] ) -> lResult
  37. ;  $ARGUMENTS$
  38. ;     <cDevice> is optional and is the device to test (LPT2, COM1, etc.).
  39. ;     If omitted, the function will default to the PRN device.
  40. ;  $RETURNS$
  41. ;     .T.  if device is ready for output.
  42. ;     .F.  if one of the following conditions occurs:
  43. ;          1)  The device is not ready.
  44. ;          2)  The device does not exist.
  45. ;          3)  DOS couldn't open the device for some reason
  46. ;              (such as no file handles available).
  47. ;  $DESCRIPTION$
  48. ;     The Clipper IsPrinter() function is somewhat limited because it only
  49. ;     works with LPT1.  Furthermore, it talks directly to the hardware, so
  50. ;     if you have redirected LPT1 via the DOS MODE command, the IsPrinter()
  51. ;     function will return erroneous results.
  52. ;
  53. ;     This function offers a better alternative.  Instead of talking to the
  54. ;     hardware, it issues a DOS call that checks to see if the device is
  55. ;     ready or not.  That gives DOS an opportunity to deal with any
  56. ;     redirections, and since you pass the device name as a parameter, you
  57. ;     can test any device, not just LPT1 (note that the function defaults
  58. ;     to PRN if you fail to pass a valid parameter).
  59. ;
  60. ;     The function also temporarily traps the DOS critical error handler so
  61. ;     you don't get any nasty error messages if the device isn't ready.  It
  62. ;     restores the old critical error handler before exiting.
  63. ;
  64. ;     Note that although this function is mainly designed for testing
  65. ;     printers, you can also check to see if a drive is ready.  Since DOS
  66. ;     thinks the NUL device exists on every drive, you can pass a drive
  67. ;     letter followed by NUL as a parameter.  If DOS is able to open the
  68. ;     NUL device, then the drive is ready, otherwise the door is open or
  69. ;     something else is wrong.
  70. ;
  71. ;     The source code is written to adhere to Turbo Assembler's IDEAL mode.
  72. ;     To use another assembler, you will need to rearrange the PROC and
  73. ;     SEGMENT directives, and also the ENDP and ENDS directives (a very
  74. ;     minor task).
  75. ;  $EXAMPLES$
  76. ;     IF ! FT_ISPRINT()
  77. ;        Qout( "PRN is not ready!" )
  78. ;     ENDIF
  79. ;
  80. ;     IF ! FT_ISPRINT( "COM2" )
  81. ;        Qout( "Check the device on COM2.  Something is wrong." )
  82. ;     ENDIF
  83. ;
  84. ;     IF ! FT_ISPRINT( "A:\NUL" )
  85. ;        Qout( "Oops, better check drive A!" )
  86. ;     ENDIF
  87. ;  $END$
  88. ;
  89.  
  90.  
  91.          IDEAL
  92.  
  93. Public   FT_ISPRINT
  94.  
  95. Old24Vec EQU       DWord Ptr BP - 4
  96. Old24Ofs EQU       Word Ptr BP - 4
  97. Old24Seg EQU       Word Ptr BP - 2
  98. Handle   EQU       Word Ptr BP - 6
  99. OpenFlag EQU       Byte Ptr BP - 8
  100.  
  101. Extrn    __ParInfo:Far
  102. Extrn    __ParC:Far
  103. Extrn    __RetL:Far
  104.  
  105. Group    DGROUP    _ftData
  106.  
  107. Segment  _ftData   Word      Public    "DATA"
  108. IsReady  DB        ?
  109. Ends     _ftData
  110.  
  111. Segment  _NanFor   Word      Public    "CODE"
  112.          Assume    CS:_NanFor,DS:DGROUP
  113.  
  114. Proc     FT_ISPRINT          Far
  115.  
  116.          Push      BP                        ; Save BP
  117.          Mov       BP,SP                     ; Set up stack reference
  118.          Sub       SP,8                      ; Allocate room for locals
  119.          Mov       [Handle],4                ; Default to PRN
  120.          Mov       [OpenFlag],0              ; Initialize flag
  121.  
  122.          Xor       AX,AX                     ; Request param count
  123.          Push      AX                        ; Put request on stack
  124.          Call      __ParInfo                 ; Count params
  125.          Or        AX,AX                     ; Zero params?
  126.          JZ        PrtTest                   ; Yes, so use default
  127.  
  128. ParType: Mov       AX,1                      ; Specify first param
  129.          Push      AX                        ; Put param # on stack
  130.          Call      __ParInfo                 ; Get type
  131.          Test      AX,1                      ; Character?
  132.          JZ        PrtTest                   ; No, so use default
  133.  
  134. GetParam:Mov       AX,1                      ; Specify first param
  135.          Push      AX                        ; Put param # on stack
  136.          Call      __ParC                    ; Retrieve parameter
  137.  
  138.          Push      DS                        ; Save DS
  139.          Mov       DS,DX                     ; Get segment of device name
  140.          Mov       DX,AX                     ; Get offset of device name
  141.          Mov       AX,3D01h                  ; DOS service--open file or device
  142.          Int       21h                       ; Call DOS
  143.          Pop       DS                        ; Restore DS
  144.          JNC       DHandle                   ; No error, so device was opened
  145.          Xor       AX,AX                     ; Set return value to false
  146.          Jmp       Short RetVal              ; We're outta here
  147.  
  148. DHandle: Mov       [Handle],AX               ; Supply device's handle
  149.          Inc       [OpenFlag]                ; Set flag so close can occur
  150.          
  151. PrtTest: Call      Near _FTHook24            ; Install local INT 24h handler
  152.          Mov       [IsReady],1               ; Assume printer ready
  153.          Mov       AX,4407h                  ; DOS service--get output status
  154.          Mov       BX,[Handle]               ; Choose standard print device
  155.          Int       21h                       ; Call DOS
  156.          And       AL,[IsReady]              ; Combine error reports
  157.          CBW                                 ; Clear high byte
  158.          Call      Near _FTUnHook24          ; Restore old INT 24h vector
  159.  
  160. RetVal:  Push      AX                        ; Put return value on stack
  161.          Call      __RetL                    ; Return status to Clipper app
  162.  
  163.          Cmp       [OpenFlag],1              ; Need to close device?
  164.          JNE       Exit                      ; No, so go ahead and exit
  165.          Mov       AH,3Eh                    ; DOS service--close handle
  166.          Mov       BX,[Handle]               ; Supply file handle
  167.          Int       21h                       ; Call DOS
  168.  
  169. Exit:    Mov       SP,BP                     ; Realign stack
  170.          Pop       BP                        ; Restore BP
  171.          Ret                                 ; Far return to Clipper app
  172. Endp     FT_ISPRINT
  173.  
  174.  
  175.  
  176. Proc     _FTHook24 Near
  177.  
  178.          Push      DS                        ; Save DS
  179.  
  180.          Mov       AX,3524h                  ; DOS service--get INT 24h vector
  181.          Int       21h                       ; Call DOS
  182.          Mov       [Old24Ofs],BX             ; Save offset
  183.          Mov       [Old24Seg],ES             ; Save segment value
  184.  
  185.          Push      CS
  186.          Pop       DS                        ; Set DS to local segment
  187.          Mov       DX,Offset _NanFor:Int_24  ; Offset of local handler
  188.          Mov       AX,2524h                  ; DOS service--set INT 24h vector
  189.          Int       21h                       ; Call DOS  
  190.  
  191.          Pop       DS
  192.          Ret                                 ; Near return
  193. Endp     _FTHook24
  194.  
  195.  
  196.  
  197. Proc     _FTUnHook24         Near
  198.  
  199.          Push      DS                        ; Save DS
  200.          Push      AX                        ; Save AX
  201.          Mov       AX,2524h                  ; DOS service--set INT 24h vector
  202.          LDS       DX,[Old24Vec]             ; Get address of original handler
  203.          Int       21h                       ; Call DOS
  204.          Pop       AX
  205.          Pop       DS
  206.          Ret                                 ; Near return
  207. Endp     _FTUnHook24
  208.  
  209.  
  210.  
  211. Proc     Int_24    Far
  212.  
  213.          Push      DS
  214.          Mov       AX,DGROUP
  215.          Mov       DS,AX
  216.          Mov       [IsReady],0               ; Indicate not ready
  217.          Pop       DS
  218.          Xor       AX,AX                     ; Tell DOS to ignore error
  219.          IRet
  220. Endp     Int_24
  221. Ends     _NanFor
  222. End
  223. 
  224.