home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Monster Media 1993 #2
/
Image.iso
/
business
/
mailman.zip
/
INSTALL.BAT
< prev
next >
Wrap
DOS Batch File
|
1993-06-05
|
8KB
|
204 lines
@echo off
cls
rem -------------------------------------------
rem install batch file for demo version
rem of the St. Dragon Mailing List Manager.
rem
rem Usage:
rem INSTALL [source] [destination]
rem
rem Copyright (c) 1993 by
rem St. Dragon Enterprises, Sausalito, CA
rem All rights reserved.
rem -------------------------------------------
rem set default installation
set source=a:
set dest=c:\dragon
rem check for help request
if !%1 == !? goto usage
if !%1 == !/? goto usage
if !%1 == !-? goto usage
if !%1 == !HELP goto usage
if !%1 == !help goto usage
if !%1 == !Help goto usage
echo I--N--S--T--A--L--L I--N--S--T--A--L--L I--N--S--T--A--L--L
echo ----------------------------------------------------------------------
echo . This is the St. Dragon Mailing List manager, version 0.81
echo .
echo . Included in this package are the following files:
echo .
echo . INSTALL.BAT -- The installation batch file for this system.
echo . DRAGON.ZIP -- The Mailing List Manager system.
echo . DOX.TXT -- Reference Manual.
echo . REG.TXT -- Registration information.
echo .
echo . For detailed instructions about installation type in "INSTALL /?",
echo . or see "INSTALLATION" in the reference manual.
echo .
echo . NOTE - this file was archived using PKZIP version 2.04g. Older
echo . versions of PKUNZIP might not be able to handle it correctly.
echo ----------------------------------------------------------------------
pause
if !%1 == ! goto msg
rem if the user specified a source, then use it.
set source=%1
if not exist %1\*.* goto error1
rem if the user specified a destination, then use it.
if not !%2 == ! set dest=%2
rem
rem check that destination is there, make it if it isn't and
rem verify that it can be written to.
rem
rem if directory already exists with files in it, then just go on to msg.
if exist %dest%\*.* goto msg
rem create destination directory if it doesn't already exist
rem (pipe to nul on "md" doesn't work. Do a CLS right after the
rem "md" to clear the "can't create directory" message which will
rem displayed if the directory already exists.
md %dest%
cls
rem verify that the directory exists and can be written to
if not exist %dest%\*.* echo "test" > %dest%\test
if not exist %dest%\*.* goto error2
if exist %dest%\test del %dest%\test
:msg
rem installation advisory message
cls
echo I--N--S--T--A--L--L I--N--S--T--A--L--L I--N--S--T--A--L--L
echo .
echo . -----------------------------------------------------------
echo . The St. Dragon Mailing List Manager
echo . --- Version 0.81 ---
echo .
echo . Install from drive %source% to %dest%
if not exist %dest%\*.* goto msgpart2
echo .
echo . !WARNING! "%dest%" already exists and contains files.
echo . This installation may destroy existing files.
:msgpart2
echo .
echo . -----------------------------------------------------------
echo . Press any key to continue or Ctrl-C to abort now
echo . -----------------------------------------------------------
echo .
echo .
pause
cls
pkunzip -d -o %source%\dragon.zip %dest%
rem
rem create a startup batch file and leave it in c:\
rem will only work if mailman was installed on drive c:
rem
echo @echo off > c:\dragon.bat
echo cls >> c:\dragon.bat
echo echo ...Starting St. Dragon Mailing List Manager >> c:\dragon.bat
echo rem Start up Batch File for St. Dragon Mailing List Manager >> c:\dragon.bat
echo rem Copyright (c) 1993 >> c:\dragon.bat
echo rem by St. Dragon Enterprises, Sausalito, CA >> c:\dragon.bat
echo rem All Rights Reserved >> c:\dragon.bat
echo rem >> c:\dragon.bat
echo rem If MailMan is not installed on drive C, then remove the >> c:\dragon.bat
echo rem 'rem' in front of the correct drive letter listed here. >> c:\dragon.bat
echo rem >> c:\dragon.bat
echo C: >> c:\dragon.bat
echo rem D: >> c:\dragon.bat
echo rem E: >> c:\dragon.bat
echo rem F: >> c:\dragon.bat
echo rem G: >> c:\dragon.bat
echo rem other: (supply your own) >> c:\dragon.bat
echo rem >> c:\dragon.bat
echo cd %dest% >> c:\dragon.bat
echo if not exist mailman.exe goto error >> c:\dragon.bat
echo mailman >> c:\dragon.bat
echo goto end >> c:\dragon.bat
echo :error >> c:\dragon.bat
echo echo ---------------------------------------- >> c:\dragon.bat
echo echo The MailMan system could not be located. >> c:\dragon.bat
echo echo Please see the file for more >> c:\dragon.bat
echo echo for more information on this problem. >> c:\dragon.bat
echo echo ---------------------------------------- >> c:\dragon.bat
echo :end >> c:\dragon.bat
echo c: >> c:\dragon.bat
echo cd c:\ >> c:\dragon.bat
:complete
rem normal completion
cls
echo ---------------------------------------------------------
echo . -----------------------------------------------------
echo . The St. Dragon Mailing List Manager Version 0.81
echo . has been successfully installed. To run it, go to
echo . %dest%, and type in MAILMAN.
echo .
echo . -----------------------------------------------------
echo . For information on how to register the product and
echo . to receive the latest version, along with a printed
echo . manual, press Shift-F1 after starting the MailMan
echo . and look at the "REGISTRATION" entry.
echo . -----------------------------------------------------
echo ---------------------------------------------------------
goto end
:usage
rem no or incorrect parameters given
echo
echo -------------------------------------------------
echo . Correct usage of this batch file is:
echo . INSTALL [source] [destination]
echo .
echo . Example: (to install from a: to C:\DRAGON)
echo . INSTALL
echo .
echo . Example: (to install to another directory)
echo . INSTALL a: c:\mailman
echo . INSTALL c:\download c:\realcool
echo -------------------------------------------------
goto end
:error1
rem couldn't find source
echo ----------------------------------------
echo Specified source "%source%" could
echo not be located or drive was not ready.
echo
echo Please check and try again.
echo ----------------------------------------
goto usage
:error2
rem couldn't find or create destination
echo --------------------------------------
echo Specified destination "%dest%"
echo could not be located or created.
echo
echo Please check that drive exists, that
echo there is space on it and that it can
echo be written to.
echo --------------------------------------
goto usage
:end
set source=
set dest=