home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Monster Media 1994 #1
/
monster.zip
/
monster
/
WILDCAT
/
GFRWCCFG.ZIP
/
RUN.BAT
< prev
Wrap
DOS Batch File
|
1993-08-26
|
3KB
|
129 lines
@echo off
goto startfd
rem Name : Run.Bat
rem Procedure : Runs FrontDoor 2.02nc
rem Last Rev. : Aug. 26, 1993
:startfd
cls
set wcnodeid=1
set wcportid=1
set wcirqid=4
set wcbaseid=$3f8
cd\wc30\data
nodeup 1
cd\fd
fd -NOUNPACK
if errorlevel 100 goto maint
if errorlevel 90 goto board
if errorlevel 80 goto local
if errorlevel 60 goto mail
if errorlevel 10 goto break
if errorlevel 1 goto done
if errorlevel 0 goto done
goto startfd
:board
arq2mnp
call dobbs.bat
goto startfd
:local
cd\wc30
wildcat /B LOCAL
cd\fd
goto startfd
:maint
REM create a filelist for the BBS and another one for Gofer distribution
REM in the format <net>-<node>.LST archived with .ZIP or .ARJ
cd\wc30
wcpro files.pro
cd\filelist
copy files.lst 107-102.lst
pkzip -m! files.zip files.lst
P:\pkz110r\pkzip -m! 107-102.zip 107-102.lst
mv files.zip F:\001
mv 107-102.zip F:\file\gofer_nj
cd\wc30
wcpro update.pro
fstat
ustat
cd\
FOR %%1 IN (C D E F G H I J K L M N O P Q) DO DS EN %%1:\ /s
wait!
boot
:mail
cd\tick
tick >> C:\bbslog\tick.log
REM We want to run Gofer Burrow and ArcMail3 so that when Gofer processes
REM the incoming files, ArcMail3 will create a mail packet containing the
REM Gofer generated user message. These should always be run together.
cd\gofer
REM Run Gofer in burrow mode to process incoming files, move them to the
REM proper file area, and create the messages.
gofer burrow
REM Run ArcMail3 to create a mail packet to your system containing the
REM newly generated Gofer user message that WildMail can toss into the
REM BBS's Netmail message area.
arcmail3 to 107/102
REM Here we must do any file processing that can change file sizes BEFORE
REM WCFile adds the file to Wildcat's database. For simplicity I listed
REM the commands to strip the comments from .ARJ and .ZIP files. If you
REM want to run a file scanner (Catscan,Transcan, etc.) you should run it
REM after WCFile has added the files to the database.
F:
cd\078
arj c *.arj -zNUL
for %%f in (*.ZIP) do pkzip %%f -z < NUL
REM Here we run WCFile in batch mode to read the Gofer created filelist
REM and add those files to the Wildcat database.
C:
cd\wc30
WCFILE /A:78 /U:GOFER /P:1,12,15,75 /N /D:C:\GOFER\FLIST\FILE1.BBS
REM ^ ^ ^ ^ ^
REM | | | | |
REM | | | | Add Files W/ The Description
REM | | | | In FILE1.BBS
REM | | | |
REM | | | Do Not Insert Keywords
REM | | |
REM | | Set Positions Of Start And End Of Filename And
REM | | Description (Must Follow The Format In Gofer.Cfg)
REM | |
REM | Set Uploader
REM |
REM Set File Area
REM This runs Wildmail to scan, toss, and process Netmail. You have to
REM process Netmail so the ArcMail3 generated packet will get processed.
REM You don't have to run Scan or Toss at this time.
cd\wm30
wm scan toss netmail
cd\fd
goto startfd
:break
cls
echo.
echo.
echo Session is ended
:done