home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Der Mediaplex Sampler - Die 6 von Plex
/
6_v_plex.zip
/
6_v_plex
/
DISK5
/
DOS_38
/
SPPRO406.ZIP
/
CUS-INS.BAT
< prev
next >
Wrap
DOS Batch File
|
1991-10-07
|
3KB
|
87 lines
echo off
echo About to install Sequencer Plus Pro with the following parameters:
echo Drive %1
echo Directory %2
if "%3==" goto DEF_ADD
echo Address %3
goto SH_PORT
:DEF_ADD
echo Address /addr:220
:SH_PORT
if "%4==" goto DEF_PT1
echo FM Port %4
goto VF_PARAM
:DEF_PT1
echo FM Port /port:2
:VF_PARAM
rem make sure logged onto disk:
if exist CUS-INS.BAT goto OK_START
echo
echo You must log onto the drive with the Sequencer Plus Pro disk in it before
echo Installing (e.g. if the disk is in drive A:, type A: [Enter]
echo then run the installation program.
goto END
:OK_START
echo
echo Are these options correct? (type Y or N)
YorN
if errorlevel 1 goto NO
echo Are you using a Casio keyboard for your master keyboard? (type Y or N)
YorN
rem none of the commands between here and the next errorlevel check set the
rem errorlevel, so it is ok to ask the question here & look at errorlevel later.
rem make sure drive letter is valid:
if "%2==" goto BAD_CMD
for %%d in (A: B: C: D: E: F: G: H: I: J: K: L: M:) do if "%%d"=="%1" goto OK_DRIVE
for %%d in (N: O: P: Q: R: S: T: U: V: W: X: Y: Z:) do if "%%d"=="%1" goto OK_DRIVE
for %%d in (a: b: c: d: e: f: g: h: i: j: k: l: m:) do if "%%d"=="%1" goto OK_DRIVE
for %%d in (n: o: p: q: r: s: t: u: v: w: x: y: z:) do if "%%d"=="%1" goto OK_DRIVE
goto BAD_CMD
:OK_DRIVE
rem make directories
echo If the target directories exist, Ignore the
echo "Unable to create directory" messages.
md %1%2
md %1%2.\SONGS
echo Copying files...
for %%f in (SPPRO.EXE BASHELP.SP0 TAPISB.COM ) do copy /v %%f %1%2
for %%f in (*.SNG) do copy /v %%f %1%2.\SONGS
for %%f in (*.MID) do copy /v %%f %1%2.\SONGS
echo Making SP.BAT batch file...
echo tapisb %3 %4> %1%2.\SP.BAT
echo if "%%1" == "/rem" goto REMOVE> %1%2.\DRIVER.BAT
echo if "%%1" == "/REM" goto REMOVE>> %1%2.\DRIVER.BAT
echo tapisb %3 %4>> %1%2.\DRIVER.BAT
if errorlevel 1 goto NOCASIO
echo sppro /CASIO %%1 %%2 %%3 %%4 %%5 %%6 %%7 %%8 %%9 >> %1%2.\SP.BAT
goto FINISH
:NOCASIO
echo sppro %%1 %%2 %%3 %%4 %%5 %%6 %%7 %%8 %%9 >> %1%2.\SP.BAT
:FINISH
echo tapisb /rem >> %1%2.\SP.BAT
echo goto OUT>> %1%2.\DRIVER.BAT
echo :REMOVE>> %1%2.\DRIVER.BAT
echo tapisb /rem>> %1%2.\DRIVER.BAT
echo :OUT>> %1%2.\DRIVER.BAT
echo
echo Sequencer Plus Pro is now installed. To run Sequencer Plus Pro, log onto
echo %1%2 and type SP [Enter].
goto END
:BAD_CMD
echo You did not run the CUS-INS command with the correct command line parameters.
echo Run INSTALL on the Sequencer Plus Pro disk to find out how to run CUS-INS.
goto END
:NO
echo Run the install program again with the correct options.
echo Run INSTALL on the Sequencer Plus Pro disk to find out how to run CUS-INS.
:END