home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Der Mediaplex Sampler - Die 6 von Plex
/
6_v_plex.zip
/
6_v_plex
/
DISK5
/
DOS_01
/
4DVC31.ZIP
/
4DVCDLET.BTM
< prev
next >
Wrap
Text File
|
1991-01-04
|
4KB
|
124 lines
@echo off
rem
rem This is the entry .BTM file for killing files to an archive. It accepts 1 to
rem n parameters from the 4DVC.BTM entry screen, each of which should be a
rem filename (wildcards accepted).
rem
rem Variables are "cleaned-up" when they are no longer needed. This helps to
rem keep the Environment Space in use to a minimum.
rem
rem Processing goes like this:
rem
rem Establish an empty subdirectory within which to work
rem For each parameter passed,
rem If the parameter is an extension only
rem Find all files in each 4DVC archive
rem If the parameter is a filename.extension
rem Find only desired files in each 4DVC archive
rem Acquire their Descriptions
rem If no files found, show "no files" message and process next parameter
rem Present list in the SELECT
rem Call 4DVCDLT2.BAT for each file the user selects
rem Erase the work-subdirectory
rem
set VCSPEC=
set VCRESP=
set VCFMT=
set VCOK=
cls
md 4DVCDLET >&! NUL
@del /qy 4DVCDLET\*.* >&! NUL
:TESTPARMS
if "%1" EQ "" goto WRAPUP
set VCFMT=EXT
iff not exist 4DVC%1.ZIP then
set VCFMT=FIL
iff not exist 4DVC%@ext[%1].ZIP then
shift
goto TESTPARMS
endiff
endiff
if "%VCFMT" EQ "FIL" for %%Z in (4DVC%@ext[%1].zip) do gosub LOOP
if "%VCFMT" EQ "EXT" for %%Z in (4DVC%1.zip) do gosub LOOP
shift
set VCFMT=
goto TESTPARMS
:WRAPUP
iff "%VCOK" EQ "" then
cls
echo 4DVCDLET: No archive files found with extensions provided.
pause
endiff
set VCOK=
@del /qy 4DVCDLET\*.* >&! NUL
rd 4DVCDLET >&! NUL
cls
quit
rem *******************************************************************
rem
rem Loop to obtain all entries in the .ZIP file and their descriptions
rem
rem At end of loop, the SELECT command is processed against the files.
rem
rem *******************************************************************
:LOOP
cls
set VCOK=X
echo Processing archive file %@upper[%Z]. Please wait a moment.
iff "%VCFMT" EQ "FIL" then
PKZIP -q-vcbrd %Z %@name[%1].* >&! 4DVCDLET\4DVCDLET.0
else
PKZIP -q-vcbrd %Z >&! 4DVCDLET\4DVCDLET.0
endiff
set VCRCD=8
gosub LOOPTOP
return
:LOOPTOP
if %@len[%@line[4DVCDLET\4DVCDLET.0,%VCRCD]] EQ 0 goto LOOPEND
if "%@substr[%@line[4DVCDLET\4DVCDLET.0,%VCRCD],1,6]" EQ "------" goto LOOPIN
:LOOPOUT
set VCRCD=%@eval[%VCRCD + 1]
goto LOOPTOP
:LOOPIN
set VCRCD=%@eval[%VCRCD + 1]
if "%@substr[%@line[4DVCDLET\4DVCDLET.0,%VCRCD],1,6]" EQ "------" goto LOOPOUT
set VCNAM=%@substr[%@line[4DVCDLET\4DVCDLET.0,%VCRCD],46,12]
set VCRCD=%@eval[%VCRCD + 1]
set VCCOM=%@substr["%@line[4DVCDLET\4DVCDLET.0,%VCRCD] ",10,41]
echo %Z >&! 4DVCDLET\%VCNAM
describe 4DVCDLET\%VCNAM "%VCCOM"
set VCCOM=
set VCNAM=
goto LOOPIN
:LOOPEND
set VCRCD=
@del /q 4DVCDLET\4DVCDLET.0 >&! NUL
iff exist 4DVCDLET\DESCRIPT.ION then
keystack !
select /Or call 4DVCDLT2 (4DVCDLET\*.*)
keystack 00
else
drawbox 1 0 13 79 2 whi on yel fill yel
iff "%VCFMT" EQ "FIL" then
scrput 3 12 whi on yel No files found in archive %@upper[%Z] which match your request:
scrput 4 20 bri whi on yel %@upper[%@name[%1]].000 thru %@upper[%@name[%1]].999
scrput 5 12 whi on yel If you think this is an error, try running
scrput 6 20 bri whi on yel PKZIP -q-vcbrd %@upper[%Z] %@upper[%@name[%1]].*
scrput 7 12 whi on yel manually from the command line.
else
scrput 4 12 whi on yel No files at all found in archive %@upper[%Z].
scrput 5 12 whi on yel If you think this is an error, try running
scrput 6 20 bri whi on yel PKZIP -q-vcbrd %@upper[%Z]
scrput 7 12 whi on yel manually from the command line.
endiff
scrput 9 5 whi on yel If there are files present, then there is some problem writing to your
scrput 10 5 whi on yel disk (password/write protection, not enough space, etc.). Resolve the
scrput 11 5 whi on yel problem and try again. Press a key to continue.
screen 11 52
inkey /W180 %%VCRESP
set VCRESP=
cls
endiff
@del /qy 4DVCDLET\*.* >&! NUL
return