home *** CD-ROM | disk | FTP | other *** search
/ Various Unprotection Examples / unprotect.zip / unprotect / STBP / STBP.ASM < prev    next >
Assembly Source File  |  1987-03-14  |  3KB  |  113 lines
  1. PAGE 64,132
  2. title    (Faking Out Star Trek's Copy Protection - Version #01)
  3. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  4. ;
  5. ;    This program was specifically designed to thwart a copy 
  6. ;    protection scheme that formatted one track with 16 sectors.  
  7. ; 
  8. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  9. envrnmt_seg    equ    2Ch    ; pointer to program's environment segment
  10. int03loc    equ    03*04    ; vector location for int03
  11. int13loc    equ    13h*04    ; vector location for int13h
  12. ;
  13. cseg    segment 
  14.     org 100h
  15. ;
  16. bypass    proc far
  17.         assume cs:cseg,ds:cseg
  18. ;
  19.     jmp    install
  20. ;
  21.         dw    'BP'    ; flag that this program was already installed 
  22. oldint13    dd    00    ; save area for old int13 vector
  23. ;
  24. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  25. newint13    equ    $
  26.     sti            ; first reenable interrupts 
  27.     pushf            ; this will get altered 
  28. ;
  29.     or    dx,dx        ; side zero on drive A: ???
  30.     jnz    intcall        ; if not don't bother 
  31.     cmp    ch,09        ; track #09 ???
  32.     jnz    intcall        ; if not don't bother 
  33.     cmp    ax,0401h    ; only verify one sector ???
  34.     jnz    intcall
  35. ;                ; looks like we have it men 
  36. ;;;    call    cs:oldint13    ; this is no longer needed 
  37.     popf
  38.     mov    ah,00        ; fake out verify operation with OK status 
  39.     clc            ; clear carry flag 
  40.     ret    02
  41. ;
  42. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  43. intcall    equ    $
  44.     popf
  45.     jmp    cs:oldint13    ; branch to normal int 13h routine 
  46. ;
  47. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  48. inst_msg    db    'Star Trek Bypass is now installed.......'
  49.         db    0Dh,0Ah,'$'
  50. deinst_msg    db    'Star Trek Bypass is now deinstalled.......'
  51.         db    0Dh,0Ah,'$'
  52. ;
  53. install    label    near        ; install and make routine resident 
  54.     xor    ax,ax        ; first get old interrupt 13h vector
  55.     mov    es,ax
  56.     mov    bx,es:word ptr int13loc
  57.     mov    ax,es:word ptr int13loc+02
  58. ;
  59.     mov    ds,ax        ; see if this program was already installed 
  60.     cmp    ds:[bx-06],'BP'
  61.     jnz    install02    ; no 
  62. ;
  63.     cli
  64.     mov    ax,ds:[bx-04]    ; restore old vector offset 
  65.     mov    es:word ptr int13loc,ax
  66.     mov    ax,ds:[bx-02]    ; restore old vector segment 
  67.     mov    es:word ptr int13loc+02,ax
  68.     sti
  69. ;
  70.     mov    ax,ds
  71.     mov    es,ax
  72.     mov    ah,49h
  73.     int    21h        ; deallocate old bypass program segment 
  74. ;
  75.     mov    ax,cs        ; bring ds back to reality 
  76.     mov    ds,ax
  77. ;
  78.     mov    dx,offset deinst_msg
  79.     mov    ah,09        ; message offset already in dx 
  80.     int    21h        ; print string 
  81. ;
  82.     mov    ah,4Ch        ; exit to DOS 
  83.     int    21h
  84. ;
  85. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  86. install02    equ    $
  87.     push    cs
  88.     pop    ds        ; restore ds
  89. ;
  90.     mov    ds:word ptr oldint13,bx
  91.     mov    ds:word ptr oldint13+02,ax
  92.     cli            ; disable interrupts 
  93.     mov    es:word ptr int13loc,offset newint13
  94.     mov    es:word ptr int13loc+02,cs
  95. ;                ; write in our new interrupt 13h vector 
  96.     sti            ; reenable interrupts 
  97. ;
  98.     mov    es,ds:word ptr envrnmt_seg
  99.     mov    ah,49h
  100.     int    21h        ; deallocate old bypass environment segment
  101. ;
  102.     mov    dx,offset inst_msg
  103.     mov    ah,09        ; Print string function
  104.     int    21h        ; Print "install" message
  105. ;                ; get rid of code after label inst_msg 
  106.     mov    dx,offset inst_msg
  107.     int    27h        ; Terminate and stay resident
  108. ;
  109. bypass    endp
  110. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  111. cseg    ends
  112.     end    bypass
  113.