home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Compute! Gazette 1994 January
/
1994-01a.d64
/
net
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2022-09-20
|
6KB
|
188 lines
4000 rem copyright 1994 - compute publications intl ltd - all rights reserved
4001 open 15,8,15
4002 forh=685to709:reada:pokeh,a:next
4004 data32,158,173,32,247,183,32,19,166,165,95,56
4006 data233,1,176,2,198,96,133,65,165,96,133,66,96
4007 d=200:dim n(d),nc$(d),c$(d),n1$(d),n2$(d),yl$(d),ad$(d),p$(d),f$(d)
4008 a=0:y$=",":print"[147] ham net ":print
4016 print" 1=add new member"
4020 print" 2=search data for change or info"
4024 print" 3=save"
4026 print" 4=end"
4027 print" 5=start net"
4028 print" 6=list check-ins"
4029 print" 7=save ck-in list"
4030 print" 8=read ck-in list from disk"
4031 print" 9=view directory"
4032 print" 10=print ck-in list to printer"
4033 print" 11=net count"
4036 input"nr.";b:onbgoto4038,4152,4262,4269,4184,4212,4270,4288,4600,4604,4446
4038 y$=",":d$="data":rem-item 1 add new member - - - - - - - - - - -
4040 print"[147]first name. ('menu'=menu)":inputn1$:ifn1$="menu"then4008
4042 input"last name (u=unknown)";n2$:ifn2$="u"thenn2$="------"
4044 input"xyl-name/n/?";yl$:yl$="("+yl$+")":input"call";c$
4046 input"phone no./none";p$:ifp$="none"thenp$="--------"
4048 print"street & 1st 3 ltrs of city u=unk":inputa$:ifa$="u"thena$="-------unk"
4050 c=asc(mid$(c$,2,1)):ifc>46andc<58thenc1$=mid$(c$,3):c2$=left$(c1$,1):goto4054
4052 c=asc(mid$(c$,3,1)):ifc>46andc<58thenc1$=mid$(c$,4):c2$=left$(c1$,1):goto4054
4054 s$=n1$+y$+n2$+y$+c$+y$+yl$+y$+p$+y$+a$
4056 x=asc(c2$)*100:ifh$="+4"thenrestorex:goto4060
4058 sys(685)x
4060 readn1$,n2$,c$,yl$,p$,a$:x=x+1:ifn1$="!"thendl=x:goto4064
4062 goto4060
4064 printchr$(147);dl;d$;s$
4066 print"run4002"
4070 poke631,19:poke632,13:poke633,13:poke198,3:end
4152 y=6500:dl=y:ifh$="+4"thenrestore6500:goto4156
4153 rem search data statements
4154 sys(685)6500
4155 print"[147] enter item to search for in following categories:"
4156 input"first/last name/yl name/call/3 ltr city";z$:print"[160]"
4158 print"is this a: (use number)":print"1 first name":print"2 last name"
4160 print"3 call":print"4 yl name":print"5 city"
4162 inputn:
4164 readn1$,n2$,c$,yl$,p$,a$:ifn1$="!"theny=y+100:dl=y:goto4164
4166 ifn1$="."thenprint" search completed. change if necessary.":goto 4016
4168 ifn=1andn1$=z$thengoto4180
4170 ifn=2andn2$=z$thengoto4180
4172 ifn=3andc$=z$thengoto4180
4174 ifn=4andyl$="("+z$+")"thengoto4180
4176 ifn=5andright$(a$,3)=z$thengoto4180
4178 dl=dl+1:goto4164
4180 s$=n1$+y$+n2$+y$+c$+y$+yl$+y$+p$+y$+a$
4182 printdl;"data"+s$:print"":dl=dl+1:goto4164
4184 print
4186 n=0:print"enter call suffix+*for no cmt,enter \ to return to menu";
4188 inputz$:n=n+1:x=len(z$):ifright$(z$,1)="*"thenz$=left$(z$,x-1):nc$="**"
4190 ifz$="\"then4008:n=n-1
4192 z1$=left$(z$,1):z1= asc(z1$)*100:ifz1>9100orz1<6500then4188
4196 sys(685)z1
4198 readn1$,n2$,c$,yl$,p$,a$
4200 ifn1$="!"thenprintn;z$;" not listed-get call & name" :gosub11000:goto4188
4202 c=asc(mid$(c$,2,1)):ifc>46andc<58thenc1$=mid$(c$,3):goto4206
4204 d=asc(mid$(c$,3,1)):ifd>46andd<58thenc1$=mid$(c$,4):goto4206
4206 ifz$=c1$then4210
4208 goto4198
4210 n(n)=n:nc$(n)=nc$:c$(n)=c$:n1$(n)=n1$:n2$(n)=n2$:p$(n)=p$
4211 printn;nc$;c$;" ";n1$;" ";n2$;" ";p$;:nc$="":goto 4188
4212 print"[147]":ln=1:pn=22:for i=ln to pn
4213 printi" ";nc$(i)" ";c$(i)" ";n1$(i)" ";n2$(i)" ";p$(i)
4214 next i
4218 print "press + for next page,- for previous page,up arrow to resume listing"
4220 get a$:if a$=""then 4220
4221 if a$="^"then n=n-1:goto4188
4222 if a$="+"then ln=ln+22:if ln>nthen ln=1
4224 if a$="-"then ln=ln-22:if ln<1then ln=1
4225 if a$="\"then print chr$(147):goto4016
4226 print"[147]":for i=ln to ln+22
4227 if i>n then i=ln+22:goto 4230
4228 printi " ";nc$(i)" ";c$(i)" ";n1$(i)" ";n2$(i)" ";p$(i)
4230 next i
4240 goto 4220
4246 rem n=n-1:goto4220
4262 rem-item 3 - save---saves program to include any change to data statements
4263 print "save net program"
4264 input"are you sure yes/no y[157][157][157]";yn$:if yn$="n"then 4008:rem resaving
4266 print"[147]scratching":close15:open15,8,15,"s:net":close15
4267 print"[147]saving":save"net",8:goto4016
4269 end
4270 input"date ie 1-19-94";w$:if w$=""then 4016
4272 open 1,8,3,"0:net "+w$+"s,w"
4273 gosub 10000:rem dos error?
4275 print#1,n
4276 for i = 1 to n-1
4278 print#1,i","nc$(i)","c$(i)","n1$(i)","n2$(i)","p$(i)
4282 next i
4284 print#1:close1
4286 goto 4016
4287 rem read ck-in file from disk
4288 print"use date ie 1-19-94 for filename"
4290 input" date";r$:if r$=""then 4016
4292 open 1,8,3,"0:net "+r$+"s,r"
4293 gosub 10000
4294 input#1,n
4295 for i=1 to n-1
4296 input#1,i,nc$(i),c$(i),n1$(i),n2$(i),p$(i)
4297 print i;" "nc$(i);" "c$(i);" "n1$(i);" "n2$(i);" "p$(i)
4300 next i
4302 print#1:close1
4304 n=n-1:goto4188
4432 print"":print"":print"":print" press any key"
4434 getb$:ifb$=""then4434
4446 rem*****summing the weekly count
4448 input"see or add to count s/a";c$:ifc$="s"then4452
4450 list4452-4476:end
4452 print"----------------1994--------"
4454 print"jan";:print15+11+16+11+4+9+7 ;:print"qsts";:print1+1+2
4456 print"feb";:print
4458 print"mar";:print
4460 print"apr";:print
4462 print"may";:print
4464 print"jun";:print
4466 print"jul";:print
4468 print"aug";:print
4470 print"sep";:print
4472 print"oct";:print
4474 print"nov";:print
4476 print"dec";:print
4484 goto 4016
4504 print"any key"
4506 getd$:ifd$=""then4506
4508 goto4008
4600 sys49152
4601 get a$:if a$=""then 4601
4602 print "[147]":goto4016
4603 rem list ck ins to printer
4604 open 4,4
4606 for i=1 to n-1
4608 print#4,n(i)" ";nc$(i)" ";c$(i)" ";n1$(i)" ";n2$(i)" ";p$(i)
4610 next i
4612 print#4:close4
4614 goto 4016
6499 rem-********* net check ins ******************************************
6500 dataroy,frazor,ws5a,(n),622-6410,1220 no. main ros
6599 data!,!,!,!,!,!
6699 data!,!,!,!,!,!
6799 data!,!,!,!,!,!
6899 data!,!,!,!,!,!
6999 data!,!,!,!,!,!
7099 data!,!,!,!,!,!
7199 data!,!,!,!,!,!
7299 data!,!,!,!,!,!
7399 data!,!,!,!,!,!
7499 data!,!,!,!,!,!
7599 data!,!,!,!,!,!
7699 data!,!,!,!,!,!
7799 data!,!,!,!,!,!
7899 data!,!,!,!,!,!
7999 data!,!,!,!,!,!
8099 data!,!,!,!,!,!
8100 dataralph,knight,ng5q,(fran),622-9250,1619 n. kansas ros
8102 datatom,coates,w8qd,((marge)),625-0987,1001 debremmond ros
8199 data!,!,!,!,!,!
8299 data!,!,!,!,!,!
8399 data!,!,!,!,!,!
8401 datatom,jones,k5tom,(sue),555-4758,-------unk
8499 data!,!,!,!,!,!
8599 data!,!,!,!,!,!
8699 data!,!,!,!,!,!
8799 data!,!,!,!,!,!
8899 data!,!,!,!,!,!
8999 data!,!,!,!,!,!
9098 data!,!,!,!,!,!
9099 data.,.,.,.,.,.
10000 close15:open15,8,15
10010 input#15,en,em$,et,es
10020 if en=0 then return
10030 print "error on disk"
10040 print en;em$;et;es
10050 close1:close15
10060 goto4016
11000 print
11010 print "enter call,first name,last name, phone"
11020 input"call";c$(n)
11022 input"first name";n1$(n)
11024 input"last name";n2$(n)
11026 input"phone";p$(n)
11040 return