home *** CD-ROM | disk | FTP | other *** search
/ Compute! Gazette 1989 May / 1989-05.d64 / show.create (.txt) < prev    next >
Commodore BASIC  |  2022-09-20  |  3KB  |  84 lines
  1. 10 rem copyright 1989 compute! publications, inc. - all rights reserved
  2. 20 dimfo$(13),f$(50),t(50),m$(50)
  3. 30 fori=1to13:readfo$(i):next:poke53280,.:poke53281,.:goto170
  4. 40 input"[147]how many pictures";p
  5. 50 ifp<1then170
  6. 60 z=.:input"display time (1-59 seconds)";tl:iftl<1ortl>59thentl=10
  7. 70 fori=1top:print"[147]#[159]"i"picture name";:inputf$(i)
  8. 80 iff$(i)=""orlen(f$(i))>16then70
  9. 90 print""tab(13)"[153]picture format?"
  10. 100 print"[150]":forj=1to13:printchr$(64+j)". "fo$(j):next
  11. 110 geta$:ifa$=""then110
  12. 120 k=asc(a$):ifk<65ork>77then110
  13. 130 t(i)=k-64:print"[154] message to be displayed before viewing"
  14. 140 inputm$(i)
  15. 150 ifm$(i)=""thenm$(i)="now loading..."
  16. 160 z=z+1:next
  17. 170 print"[147]"chr$(142)tab(14)"[158][213][192][192][157][157][157][221]  uper[157][157][157][157][157][157][157][158][202][192][201][157]";
  18. 180 print"[221]lideshow[157][157][157][157][157][157][157][157][157][157][157][158][192][192][203]"
  19. 190 printtab(10)"1. create slideshow":printtab(10)"2. edit slideshow"
  20. 200 printtab(10)"3. save slideshow":printtab(10)"4. load slideshow"
  21. 210 printtab(10)"5. quit":printtab(10)"you have"z"pictures"
  22. 220 print""tab(10)"[159]make selection (1-5)"
  23. 230 print""tab(3)"copyright 1989 compute! publ., inc."
  24. 240 printtab(11)"all rights reserved[159]"
  25. 250 geta$:ifa$=""then250
  26. 260 ifa$<"1"ora$>"5"then250
  27. 270 onval(a$)goto40,360,280,460,510
  28. 280 rem save
  29. 290 h$="":input"[147]save as (filename)";h$:ifh$=""then170
  30. 300 iflen(h$)>16then290
  31. 310 open15,8,15,"s0:"+h$:print#15,"i0"
  32. 320 open1,8,2,"0:"+h$+",s,w":gosub750
  33. 330 print#1,p:print#1,tl
  34. 340 fori=1top:print#1,f$(i):print#1,t(i):print#1,m$(i):nexti
  35. 350 gosub750:close1:close15:goto170
  36. 355 rem edit
  37. 360 ifz=0then170
  38. 370 fori=1top
  39. 380 print"[147]#"i:print"picture name: "f$(i):print"pic format: "fo$(t(i))
  40. 390 print"message":printm$(i)
  41. 400 print"[158]1. change picture name":print"2. change picture format"
  42. 410 print"3. change message":print"4. next":print"5. quit"
  43. 420 geta$:ifa$=""then420
  44. 430 ifval(a$)<1orval(a$)>5then420
  45. 440 onval(a$)goto560,600,620,650,730
  46. 450 rem load
  47. 460 h$="":input"[147]load (filename)";h$:ifh$=""then170
  48. 470 iflen(h$)>16then460
  49. 480 open15,8,15:open1,8,2,"0:"+h$+",s,r":gosub750:input#1,p:input#1,tl
  50. 490 fori=1top:input#1,f$(i):input#1,t(i):input#1,m$(i):nexti
  51. 500 gosub750:close1:close15:z=p:goto170
  52. 510 rem quit
  53. 520 print"[147]"tab(7)"quit, are you sure?  (y/n)"
  54. 530 geta$:ifa$="n"then170
  55. 540 ifa$="y"thenprint"[147]":end
  56. 550 goto530
  57. 560 print"picture name";:inputu$
  58. 570 ifu$=""then380
  59. 580 iflen(u$)>16thenprint"[145][145][145][145]":goto560
  60. 590 f$(i)=u$:goto380
  61. 600 t(i)=t(i)+1:ift(i)=14thent(i)=1
  62. 610 goto380
  63. 620 print"new message":inputv$:ifv$=""then380
  64. 630 iflen(v$)>40thenprint"[145][145][145][145][145][145]":goto620
  65. 640 m$(i)=v$:goto380
  66. 650 next
  67. 660 print"[147]"tab(7)"current display time is"tl
  68. 670 print""tab(7)"change time limit?   (y/n)"
  69. 680 geta$:ifa$="n"then730
  70. 690 ifa$<>"y"then680
  71. 700 print"[147]time limit  (1-59)";:inputlt:iflt=.then730
  72. 710 iflt>59then730
  73. 720 tl=lt
  74. 730 goto170
  75. 740 rem read error channel
  76. 750 input#15,en,em$,et,es:ifen=0thenreturn
  77. 760 print"disk error: "str$(en)" "em$str$(et)" "str$(es)" "
  78. 770 printtab(14)"press any key"
  79. 780 getk$:ifk$=""then780
  80. 790 close1:close15:goto170
  81. 800 datakoala,create with garfield,doodle,print shop screen magic,paint now!
  82. 810 dataart studio,advanced art studio,rainbow painter,paintbrush,vidcom
  83. 820 dataartist 64,blazing paddles,lores
  84.