home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Run Magazine ReRun: Productivity Pak 2
/
rerun-productivity-pak-ii.d64
/
rs64
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2022-09-20
|
2KB
|
70 lines
10 rem ********************************
20 rem boot program *
30 rem for *
40 rem commodore 64 runscript 2.40 *
50 rem june 16, 1986 *
60 rem by robert rockefeller *
70 rem ********************************
80 :
90 dev=8 : rem set dev equal to load device number
100 hlp$="": rem make hlp$ equal filename of help file
110 :
120 a=780: x=781: y=782: rem register saves for sys
130 dim ps$(6): rem holds filenames of print sets
140 :
150 ps$(1)="": rem name of print set 1
160 ps$(2)="": rem name of print set 2
170 ps$(3)="": rem name of print set 3
180 ps$(4)="": rem name of print set 4
190 ps$(5)="": rem name of print set 5
200 ps$(6)="": rem name of print set 6
210 :
220 if hlp$="" then 260
230 for j=1 to len(hlp$)
240 poke 743+j,asc(mid$(hlp$,j,1))
250 next j
260 poke 743,len(hlp$)
270 :
280 adr=57344: rem load address of print set 1
290 rem load print sets, if any
300 for j=1 to 6
310 if ps$(j)<>"" then prog$=ps$(j): gosub 420
320 adr=adr+1024
330 next j
340 :
350 prog$="ob.rs64 2.40": gosub 480
360 gosub 640: sys900: rem start
370 end
380 :
390 :
400 :
410 rem load program file
420 gosub 480: rem setup name & logical file
430 poke a,0 : poke x,(adr/256-int(adr/256))*256 : poke y,adr/256
440 sys 65493 : rem load
450 return
460 :
470 :
480 rem use the kernal setlfs
490 poke a,0 : poke x,dev : poke y,0
500 sys 65466
510 :
520 rem setup filename
530 for loop=1 to len(prog$)
540 poke 849+loop,asc(mid$(prog$,loop,1))
550 next loop
560 :
570 rem use kernal setnam
580 poke a,len(prog$) : poke x,850and255 : poke y,850/256
590 sys 65469
600 :
610 return
620 :
630 :
640 for loop=900 to 910
650 read byte : poke loop,byte
660 next loop
670 return
680 :
690 data 169,0,170,160,8,32,213,255,76,0,16