home *** CD-ROM | disk | FTP | other *** search
/ CBM Funet Archive / cbm-funet-archive-2003.iso / cbm / crossplatform / converters / uudecode.bas < prev   
Encoding:
Internet Message Format  |  1993-10-31  |  1.7 KB
  1. fROM: AC387@YFN.YSU.EDU (RANDALL WILLIAMS)
  2. nEWSGROUPS: COMP.BINARIES.CBM
  3. sUBJECT: basic UUDECODE
  4. fOLLOWUP-tO: COMP.SYS.CBM
  5. dATE: 31 oCT 1993 02:20:19 -0700
  6. oRGANIZATION: uNIVERSITY OF aRIZONA cs dEPARTMENT, tUCSON az
  7. nntp-pOSTING-hOST: CASLON.CS.ARIZONA.EDU
  8.  
  9. lAST CHANGED - 10/31/93
  10.  
  11. tHIS IS A basic UUDECODE PROGRAM. iT WOULD BE GOOD FOR UUDECODING
  12. FILES UNTIL SOMETHING FASTER COULD BE OBTAINED. iT IGNORES EVERYTHING
  13. UNTIL IT FINDS THE "BEGIN" STATEMENT AT THE START OF A UUENCODED FILE.
  14. tHE FILE MUST BE A SEQUENTIAL
  15. petascii FILE AND CONVERTS IT TO A PROGRAM FILE. sINCE IT IS IN basic IT IS EASY TO CHANGE.
  16.  
  17. 10 INPUT"ENTER INPUT FILE NAME";FI$
  18. 20 INPUT"ENTER INPUT DEVICE #";DI
  19. 30 INPUT"ENTER OUTPUT FILE NAME";FO$
  20. 40 INPUT"ENTER OUTPUT DEVICE #";DO
  21. 50 PRINT"SEARCHING FOR FILE START"
  22. 60 OPEN2,DI,2,FI$+",S,R"
  23. 70 GOSUB400
  24. 80 IFLEFT$(W$,5)="BEGIN"THEN190
  25. 90 PRINT"FILE START NOT FOUND"
  26. 100 PRINTW$:GOTO70
  27. 190 PRINT"BEGINNING FILE CONVERSION"
  28. 200 OPEN3,DO,3,"@0:"+FO$+",P,W":LC=1
  29. 210 GOSUB400:PRINT"LINE ";LC;"  "
  30. 220 IFLEFT$(W$,3)="END"THEN360
  31. 230 X=2:LL=(ASC(LEFT$(W$,1))-32)AND63
  32. 240 IFLL=0THEN210
  33. 250 LL=LL/3*4
  34. 260 FORZ=0TO3
  35. 270 IFX+Z-1>LLTHENB(Z)=32:GOTO290
  36. 280 B(Z)=(ASC(MID$(W$,X+Z,1))-32)AND63
  37. 290 NEXT:X=X+4
  38. 300 C1=B(0)*4+INT(B(1)/16)
  39. 310 C2=((B(1)*16)AND240)+INT(B(2)/4)
  40. 320 C3=((B(2)*64)AND192)+B(3)
  41. 330 PRINT#3,CHR$(C1);CHR$(C2);CHR$(C3);
  42. 340 IFX-1=>LLTHENLC=LC+1:GOTO210
  43. 350 GOTO260
  44. 360 PRINT"FILE CONVERSION DONE"
  45. 370 PRINT#3,"":CLOSE2:CLOSE3:END
  46. 400 W$=""
  47. 405 GET#2,X$:IFX$=""THENX$=CHR$(0)
  48. 410 IFX$=CHR$(13)ORX$=CHR$(10)THENRETURN
  49. 420 IFST<>0THENPRINT"ERROR":GOTO370
  50. 430 W$=W$+X$
  51. 440 IFLEN(W$)=254THENRETURN
  52. 450 GOTO405
  53.  
  54.  
  55. -- 
  56. sLAY THE DRAGONS OF YOUR OWN MIND BEFORE YOU CALL ME INSANE.
  57. AC387@YFN.YSU.EDU
  58. AM789@CLEVELAND.FREENET.EDU
  59. -=*> gANDALF <*=-
  60.  
  61.