home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / sigm / vols200 / vol235 / bcread.asm < prev    next >
Encoding:
Assembly Source File  |  1994-07-13  |  11.1 KB  |  566 lines
  1. ;**************************************************
  2. ;
  3. ;                 BASICODE READ
  4. ;
  5. ;  DIT OPENBAAR PROGRAMMA MAG GECOPIEERD EN GEDISTRIBEERD
  6. ;  WORDEN,  MITS INHOUDENDE DE VOLGENDE COPYRIGHT NOTICE
  7. ;
  8. ;   "         DIT PROGRAMMA
  9. ;     BETREFFENDE EEN IMPLEMENTATIE VAN DE
  10. ;        NOS BASICODE
  11. ;
  12. ;   IS TER BESCHIKKING GESTELD DOOR DE
  13. ;    HOBBY COMPUTER CLUB (HOLLAND)      "
  14. ;
  15. ;
  16. ;  NOS     P.O. 1200     1200BE HILVERSUM    (HOBBYSCOOP)
  17. ;  HCC  P.O. 149    2250AC VOORSCHOTEN    (CP/M gg)
  18. ;
  19. ;   Implementatie:
  20. ;        Albert van der Horst
  21. ;    t.b.v.  FORTH gebruikersgroep (HCC)
  22. ;
  23. ;*************************************************
  24.  
  25.     ORG    100H
  26.     CALL    PRINT
  27.  DB CTRLZ,LF,LF,' ** CP/M BASICODE LEES '
  28.  DB '**  RELEASE 1.0',CR,LF,LF,0
  29. ;
  30. ;
  31. ;*************************************************
  32. ;
  33. ;    Algemene opmerking:
  34. ;    Daar ook CP/M de registers van de Z80 niet
  35. ;    intact laat bij aanroepen naar het systeem,
  36. ;    is hier de regel aanhouden dat registers altijd
  37. ;    verpest worden door subroutines, tenzij anders
  38. ;    vermeld.
  39. ;
  40. ;------------- VERANDERLIJKE EQUATES ---------------
  41. ;
  42. ;     In het algemeen zal men voor ieder type computer
  43. ;       een verantwoorde keus moeten maken uit de volgende
  44. ;    opties, alsmede hardware adressen in moeten vullen.
  45. ;
  46. ; ASSEMBLER SWITCH      ALS HIJ 1 IS, BETEKENT HET DAT 
  47. MEMMAP    EQU 1    ; De Centronics poort is 'memory mapped'
  48. DEBUG    EQU 0    ; Debug instrukties meegeassembleerd
  49.         ;  Een langzame processor kan hier niet tegen!
  50. FIG    EQU 0    ; Een FIGFORTH blokken file wordt ingelezen,
  51.         ;  d.w.z. alle CR en LF's weg, alle regels
  52.         ;  worden aangevuld tot 64 characters.
  53. OSBRN    EQU 1    ; Speciaal voor OSBORNE: bank switching    
  54.  
  55. ; HARDWARE EQUATES
  56. CRIT    EQU    55    ; Grens tussen lengte O of 1 bit
  57. PAPORT    EQU    2902H    ; Parallel port (memory mapped)
  58.             ; Hier moet het Centronics 'PRINTER READY'
  59.             ;  signaal op binnen komen.
  60. SCREEN    EQU    0F000H    ; Memory mapped video screen
  61. ;
  62. ;------------- VASTE EQUATES --------------------------------
  63.  
  64. BDOS    EQU    5H
  65. DMA    EQU    80H
  66. STX    EQU    02H
  67. ETX    EQU    03H
  68. LF    EQU    0AH
  69. CR    EQU    0DH
  70. CTRLZ    EQU    1AH    ; CONTROL-Z
  71. FCB    EQU    5CH    ; Standaard file control block
  72.  
  73. ;-------------------------------------------------
  74.  
  75.     JMP    STACK    
  76.  
  77. ;
  78. ; ================================================
  79. ;
  80.  
  81.     IF    NOT OSBRN    ; Normale situatie
  82.     DS    20H        ; Reserveer stack ruimte
  83.     ENDIF
  84.  
  85.     IF    OSBRN    ; Programma moet boven 4000H draaien
  86.     ORG    4020H    ; wegens of Osborne bankswitching
  87.     ENDIF
  88.  
  89. STACK:    
  90.     LXI    H,STACK
  91.     SPHL
  92.  
  93. ; - - - - - WACHT OP KEYBOARD - - - - - - - - - - - 
  94.  
  95.     CALL    PRINT
  96.     DB    'START CASSETTE EN GEEF RETURN',CR,LF,0 
  97.     MVI    C,1
  98.     CALL    BDOS
  99.  
  100. ;----------- LEZEN VAN CASSETTE --------------------
  101.  
  102. ; - - - - - DISABLE INTERRUPTS - - - - - - - - - - 
  103. ;
  104. ;     DIT IS MISSCHIEN NIET VOOR ELK SYSTEEM VAN BELANG
  105.  
  106.     DI
  107.  
  108. ; - - - - - INITIALISEREN  - - - - - - - - - - - - -  
  109.  
  110.     IF    OSBRN
  111.     CALL    BANK2
  112.     ENDIF
  113.  
  114.     LXI    H,BUFFER-1
  115.     SHLD    LASTCH
  116. ;
  117. ;------- HAAL DE BYTES EEN VOOR EEN BINNEN ----------------
  118. ;
  119. ;     Op elk punt waar gelezen wordt kan de gebruiker
  120. ;      laten afbreken. Men komt dan in de error afhandeling
  121. ;      aan het eind van dit gedeelte (LABEL ERROR2)
  122.  
  123.  
  124.  
  125. REP1:    CALL    SYNCH        ; Zoek volgende startbit
  126.     CALL    BYTOBF           ; Haal byte van cassette
  127.                 ;  en plaats in buffer
  128.     CALL    CALCHK         ; Checksum bijwerken
  129.     MOV    A,C        ; Naar video ter controle
  130.     STA    SCREEN
  131.  
  132.     CPI    ETX+80H        ; ETX ->voorlaatste char
  133.     JNZ    REP1        ; Anders volgende byte
  134.  
  135. ; - - - - CHECKSUM - - - - - - - - - - - - - - - 
  136.  
  137.     CALL    SYNCH
  138.     CALL    BYTOBF    ; Haal checksum van cassette
  139.     LDA    CHKSUM    ; Haal berekende checksum    
  140.     CMP    C    ; Moet gelijk zijn 
  141.     JNZ    ELSE1    
  142.     MVI    A,0FFH
  143.     JMP    END2
  144.  
  145. ELSE1:    MVI    A,0
  146. END2:    STA    OKAY
  147.     JMP    END1
  148.  
  149. ; - - - - -  ON ERROR GEDEELTE - - - - - - - - - - - 
  150.  
  151. ERROR2:    MVI    A,0    ; Natuurlijk niet okay
  152.     STA    OKAY    ; want het inlezen werd onderbroken
  153.             ; door de gebruiker
  154.     LHLD    LASTCH  ; Verzekerd van ETX
  155.     INX    H    
  156.     MVI    M,ETX     
  157.     SHLD    LASTCH
  158.  
  159. ; - - - - - AFSLUITEN - - - - - - - - - - - - - - 
  160.  
  161. END1:    NOP
  162.  
  163.     IF    OSBRN    
  164.     CALL    BANK1    ; Bank terugschakelen
  165.     ENDIF
  166.  
  167.     EI
  168.  
  169.     CALL    MESSGE  ; Hoe afgelopen?
  170.  
  171. ;
  172. ;------- VERPLAATS VAN BUFFER NAAR SCHIJF --------------
  173. ;
  174. ;    In dit hele gedeelte wijst HL naar het te
  175. ;    verwerken byte in de buffer.
  176. ;
  177. ;- - - - - - INITIALISEREN - - - - - - - - 
  178. ;
  179.     CALL     OPEN
  180.     LHLD    FRSTCH        ; Skip rommel voor STX
  181.     INX    H        ; Skip ook nog over STX
  182.  
  183. ; - - - - - LOOP OVER DMA BUFFERS - - - - - - - -
  184.  
  185. REP6:
  186.     LXI    D,DMA
  187.     MVI    B,80H    ; Bytes per record
  188.  
  189. REP7:    CALL    COPCHR    ; Byte naar DMA buffer
  190.     JZ    OUT3    ; Z: d.w.z. ETX gevonden
  191.     DCR    B
  192.     JNZ    REP7
  193.     
  194.     PUSH    H
  195.     CALL    WRITE    ; BUFFER VOL : SCHRIJVEN
  196.     POP    H
  197.     JMP    REP6
  198.  
  199. ; - - - - - LAATSTE RECORD - - - - - - - - - - - 
  200. ;
  201. ;  Vul de laatste buffer met CTRLZ's op
  202.  
  203. OUT3:    DCX    D    ; Overschrijf ETX
  204. REP2:    MVI    A,CTRLZ
  205.     STAX    D
  206.     INX    D
  207.     DCR    B
  208.     JNZ    REP2
  209.  
  210.     CALL WRITE
  211.  
  212.  
  213. ;- - - - - - EINDE - - - - - - - - - - - - - - 
  214.  
  215.     CALL    CLOSE
  216.     JMP    0    ; Terug naar CP/M
  217.     
  218. ;**************************************************
  219. ;
  220. ;     SUBROUTINE GEBIED
  221. ;
  222. ;**************************************************
  223.  
  224. ; --------- BYTE NAAR DMA BUFFER -------------
  225. ; 
  226. ;    Verplaats een byte van input buffer naar DMA buffer.
  227. ;    Als Z, dan zijn we ETX tegengekomen.
  228. ;    Stelt HL ( 'van'-pointer) en DE ('naar'-pointer bij)
  229. ;    Behoudt het BC register (teller), tenzij bij FIG
  230. ;     opvulakties.
  231.  
  232. COPCHR    MOV    A,M    ; Copieer buffer naar DMA 
  233.     INX    H
  234.     ANI    7FH    ; 7e BIT ERAF
  235.     STAX    D
  236.     INX    D
  237. ;    CPI    ' '    ; Controle char?
  238. ;    JNC    NORMAL
  239.     CPI    LF
  240.     JZ    NORMAL
  241.     CPI    CR    ; Enige toegestane controle character
  242.  
  243.     IF    FIG    ; Bij FIGFORTH speciale opvul actie
  244.     CZ    OPVUL
  245.     ENDIF
  246.  
  247.     IF    NOT FIG
  248.     JZ    CRLF
  249.     JMP    NORMAL
  250. CRLF:    DCX    H    ; Frommel er een LF bij
  251.     MVI    M,LF    ; Wordt straks pas opgepikt!
  252.     ENDIF
  253.  
  254. NORMAL:    CPI    ETX    ; Z vlag betekent einde
  255.     RET
  256.  
  257. ;---------- OPVULLEN MET SPATIES -----------------
  258. ;
  259. ;    Alleen voor FIG FORTH files
  260. ;    Stelt HL,DE en BC bij (zie COPCHR)
  261.  
  262.     IF    FIG
  263. OPVUL    MVI    A,020H    ; Spatie
  264.     DCX    D
  265.     STAX    D    ; Overschrijf CR,
  266.     INX    D    ;   die er al was.
  267.  
  268. REP9    MVI    A,20H    ; Schrijf spaties
  269.     STAX    D
  270.     INX    D
  271.     DCR    B
  272.     MOV    B,A
  273.     CPI    41H    ; Tot 1e regel vol
  274.     RZ
  275.     CPI    01H    ; Of 2e regel vol
  276.     RZ
  277.     JMP    REP9
  278.     ENDIF
  279.  
  280. ;---------- SYNCHRONISEREN ---------------------
  281. ; 
  282. ;    Wacht op 0-bit
  283.  
  284. SYNCH:    LXI    H,PAPORT
  285.     CALL    BITPS
  286.     MVI    A,CRIT/2    ; HET GAAT HIER OM HALVE PERIODE
  287.         CMP    E
  288.     JNC    SYNCH
  289.     CALL    BITPS        ; OOK TWEEDE KEER LANG?
  290.     MVI    A,CRIT/2
  291.         CMP    E
  292.  
  293.     IF    DEBUG 
  294.     MOV    A,E
  295.     STA    SCREEN+3
  296.     ENDIF
  297.  
  298.     JNC    SYNCH
  299.     RET
  300.  
  301. ; --------- VERWIJDER CHARACTERS -------------------- 
  302. ;
  303. ;    Verwijder alle char's, gelijk aan register C
  304.  
  305. REMOVE    LXI    D,FRSTCH
  306.     LXI    H,FRSTCH
  307.  
  308. REP8:    LDAX    D        ; COPIEER VAN D
  309.     MOV    M,A        ;   NAAR H
  310.  
  311.     CMP    C        
  312.     JZ    END4        ; INDIEN HET EEN FOUT CHAR IS
  313.     INX    H        ;  INCREMENTEER DAN H NIET
  314.  
  315. END4:    INX    D
  316.     CPI    ETX
  317.     JNZ    REP8
  318.  
  319.     DCX    H
  320.     SHLD    LASTCH        ; NIEUW EINDPUNT
  321.     RET
  322.  
  323.  
  324. ; ------- HAAL BYTE OP -----------------------------
  325. ;
  326. ;    Haalt een byte op en plaats het in de buffer.
  327. ;    Uitvoer: C bevat het gelezen byte.
  328. ;    
  329. BYTOBF:    MVI    C,80H        ; Als dit bit weer tevoorschijn
  330.                 ; komt zijn we klaar
  331. DO1:    CALL    BITIN        ; lees bit
  332.     MOV    A,C        ; Schuif bit in C erbij
  333.     RAR
  334.     MOV    C,A
  335.     JNC    DO1    
  336.  
  337.     LHLD    LASTCH        ; Plaats c in buffer
  338.     INX    H
  339.     MOV    M,C
  340.     SHLD    LASTCH
  341.     RET
  342.  
  343. ; --------- HOUDT CHECKSUM BIJ ------------------- 
  344. ;
  345. ;    Invoer: C
  346. ;
  347. CALCHK:    MOV    A,C    ; In C zit het zojuist gelezen byte    
  348.     CPI    STX+80H
  349.     LDA    CHKSUM
  350.      JNZ    END3    ; Als STX gelezen was 
  351.     XRA    A    ; initialisieer dan checksum opnieuw
  352.     SHLD    FRSTCH    ; en onthoud dit adres
  353. END3:    XRA    C
  354.     STA    CHKSUM
  355.     RET
  356.  
  357. ; ------------- SWITCH NAAR BANK 1 -------------  
  358. ;
  359. ;  Zie OSBORNE USER GUIDE 262 ( REV.12/15/82)
  360.  
  361.  
  362.     IF    OSBRN
  363. BANK1:    OUT    1
  364.     MVI    A,1
  365.     STA    0EF08H    
  366.     RET
  367.  
  368. ; ------------- SWITCH NAAR BANK 2 ------------------
  369. ;
  370. ;  Zie OSBORNE USER GUIDE 262 ( REV.12/15/82)
  371.  
  372. BANK2:    OUT    0
  373.     MVI    A,0
  374.     STA    0EF08H    
  375.     RET
  376.     ENDIF
  377.  
  378.  
  379. ; ------------- HAAL EEN BIT BINNEN -------------
  380. ;
  381. ; Bepaal de lengte van de positieve en negatieve 
  382. ;  fase.
  383. ; 1/1200 sec = 833.25 usec 
  384. ; Op de Osborne (4 Mhz) is dat 3333 cycles
  385. ; Bij overschrijding hiervan een sprong naar
  386. ; de foutafhandeling.
  387. ; BC blijft behouden door deze routine heen, C bevat
  388. ; immers het te lezen byte in opbouw
  389.  
  390. BITIN:    PUSH    B
  391.     MVI    B,2    ; 2 fasen voor '1-bit'
  392.     
  393. REP4:    CALL    BITPS    ; Wacht 1e periode
  394.     MOV    D,E    ; Bewaar lengte eerste helft
  395.     CALL    BITPS    ; Wacht 2e periode
  396.     MOV    A,E
  397.     ADD    D    ; Totale lengte
  398.  
  399.     IF    DEBUG
  400.     STA    SCREEN+3
  401.     ENDIF
  402.  
  403.     CPI    CRIT    ;  0 of 1 bit?
  404.     JNC    OUT2    ; Uit de loop bij 1200 periode
  405.     DCR    B
  406.     JNZ    REP4
  407.             ; Anders: skip 2e golf
  408. OUT2:    POP    B
  409.     RET
  410.  
  411. ; ----------- MEET LENGTE PERIODE -----------------
  412. ;
  413. ; HL wijst al naar de poort (bij memory mapped)
  414. ; Bij time-out wordt gekeken of er een toets ingedrukt is.
  415. ; Zo ja, dan breekt het inlezen af. 
  416.  
  417.  
  418.     IF    MEMMAP
  419. BITPS:    MOV    A,M    ; Lees poort
  420.     MVI    E,0    ; Init teller
  421.  
  422. REP5:    INR    E    ; Meet lengte
  423.     JZ    OUT1    ; Timeout
  424.     CMP    M    ; Veranderd?
  425.     JZ    REP5    ; Zo niet herhaal
  426.     RET
  427.     ENDIF
  428.  
  429. ; - - - - HET VOLGENDE NIET GETEST - - - - - - - 
  430.  
  431.     IF    NOT MEMMAP 
  432. BITPS:    IN    PAPORT    ; Lees poort
  433.     MOV    L,A    ; Bewaar in L
  434.     MVI    E,0    ; Init teller
  435.  
  436. REP5:    INR    E    ; Meet lengte
  437.     JZ    OUT1    ; Timeout
  438.     IN    PAPORT
  439.     CMP    L    ; Veranderd?
  440.     JZ    REP5    ; Zo niet herhaal
  441.     RET
  442.     ENDIF
  443.  
  444. ; - - - - - TIME OUT - - - - - - - - - -
  445.  
  446. OUT1:    
  447.     IF    OSBRN
  448.     CALL    BANK1
  449.     ENDIF
  450.  
  451.     CALL    KBD    ; Wil men afbreken?
  452.     PUSH    PSW
  453.  
  454.     IF    OSBRN
  455.     CALL    BANK2
  456.     ENDIF
  457.  
  458.     POP    PSW
  459.     JNZ    REP5     ; Zoniet toch doorgaan
  460.     JMP    ERROR2
  461.  
  462.  
  463. ; ---------- PRINT DE TEKST VOLGENDE OP DE CALL ---------------
  464.  
  465. PRINT    POP    H    ; Haal return address op
  466.     MOV    A,M    ; Haal een letter op
  467.     INX    H
  468.     ORA    A
  469.     JZ    END5
  470.     PUSH    H
  471.     CALL    CRT
  472.     JMP    PRINT
  473. END5    PCHL        ; RETURN
  474.  
  475. ; ----------- HOE AFGELOPEN -----------------------
  476.  
  477. MESSGE:    CALL    PRINT
  478.     DB    CR,LF,' DE CHECKSUM KLOPT ',0
  479.     LDA    OKAY
  480.     ANA    A
  481.     RNZ
  482.     CALL    PRINT
  483.     DB    'NIET',0
  484.     RET
  485.  
  486. ;=================================================
  487. ;
  488. ;            INTERFACE MET CP/M
  489. ;            ------------------
  490. ;
  491. ;=================================================
  492.  
  493. ; ---------------  FUNKTIE SCAN FOR CHAR -----------
  494. ;
  495. ;  Uitvoer : Z-vlag betekent toets ingedrukt
  496.  
  497. KBD    PUSH    H
  498.     PUSH    D
  499.     PUSH    B
  500.     EI
  501.     MVI    C,0BH    
  502.     CALL    BDOS
  503.     ANI    1    ; TEST L.S. BIT
  504.     CPI    1
  505.     DI
  506.     POP    B
  507.     POP    D
  508.     POP    H
  509.     RET    
  510.  
  511. ; ----------  FUNKTIE PRINT A CHAR ------------
  512.    
  513. CRT    MOV    E,A    ; OUTPUTS 'A' IN ASCII
  514.     MVI    C,2    
  515.     CALL    BDOS    
  516.     RET
  517.  
  518.                
  519.  
  520. ; --------  FUNKTIE MAAK FILE ------------------- 
  521. ;
  522. ;    OPENT DE FILE MET NAAM OP FCB VOOR SCHRIJVEN
  523. ;
  524. OPEN:    MVI    C,22
  525.     LXI    D,FCB
  526.     CALL    BDOS
  527.     RET
  528.  
  529. ; ------  FUNKTIE SCHRIJF RECORD  ---------------
  530.  
  531. ;
  532. ;    SCHRIJF HET volgende RECORD 
  533. ;
  534. WRITE:    MVI    C,21
  535.     LXI    D,FCB
  536.     CALL    BDOS
  537.     RET
  538.  
  539. ; --------  FUNKTIE SLUIT FILE  --------------
  540. ;
  541. ;    SLUIT HET SCHRIJVEN AF
  542. ;
  543. CLOSE:    MVI    C,16
  544.     LXI    D,FCB
  545.     CALL    BDOS
  546.     RET
  547.  
  548. ;=================================================
  549. ;
  550. ;            START VAN BUFFER GEBIED
  551. ;            -----------------------
  552. ;
  553. ;=================================================
  554.  
  555. ;
  556. OKAY    DB    0    ; BOOLEAN: BETEKENT
  557. ;               - ER WAS STX
  558. ;               - ER WAS ETX
  559. ;               - DE CHECKSUM KLOPTE
  560. FRSTCH    DW    0    ; ADRES VAN EERSTE CHAR : STX
  561. ;              ALS OKAY DUS STX
  562. LASTCH    DW    0    ; ADRES VAN LAATSTE CHAR : ETX
  563. ;              ALS OKAY DUS ETX
  564. CHKSUM    DB    0    ; LOPENDE CHECKSUM
  565. BUFFER:    DS    5000H
  566.