home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / sigm / vols200 / vol220 / mxo-vp10.asm < prev    next >
Encoding:
Assembly Source File  |  1994-07-13  |  6.3 KB  |  222 lines
  1.     TITLE    'MEX VENTEL MD212 PLUS MODEM OVERLAY V1.0'
  2. ;
  3. ; (DELETE ABOVE TITLE LINE IF ASSEMBLING WITH ASM)
  4. ;
  5. ; used smartmodem overlay for MEX: revision 1.2
  6. ; Written 04/16/84 by Ronald G. Fowler (V1.2) as an outline.
  7. ;
  8. ;            Written by:
  9. ;        Bruce Childers & Jon Albers
  10. ;        Data - 202-633-0804, 0805, 0806
  11. ;               703-281-7907
  12. ;
  13. ; This overlay will allow you to use a Ven-Tel Plus modem with Mex.
  14. ; It will allow auto-dial.  Note -- You can only disconnect using
  15. ; DTR, so set the DISC equatte to false.
  16. ;
  17. ; This overlay will work with any modem overlay that terminates
  18. ; prior to 0B00H
  19. ;
  20. FALSE    EQU    0
  21. TRUE    EQU    NOT FALSE
  22. ;
  23. ;
  24. DISC    EQU    FALSE        ;<<== CHANGE TO FALSE IF YOU DISC. WITH DTR
  25. PENRIL    EQU    FALSE        ;Set true if you have a Penril
  26. ;
  27. ; SYSTEM CONSTANTS
  28. ;
  29. DIALV    EQU    0162H        ;LOCATION OF DIAL VECTOR IN OVERLAY
  30. DISCV    EQU    0165H        ;LOCATION OF DISCONNECT VECTOR IN OVERLAY
  31. DIALOC    EQU    0B00H        ;DIALING CODE GOES HERE
  32. MEX    EQU    0D00H        ;"CALL MEX"
  33. ;
  34. ; FOLLOWING ARE FUNCTION CODES FOR THE MEX SERVICE CALL PROCESSOR
  35. ;
  36. INMDM    EQU    255        ;RETURN CHAR FROM MDM IN A, CY=NO CHR IN 100MS
  37. TIMER    EQU    254
  38. TMDINP    EQU    253        ;B=# SECS TO WAIT FOR CHAR, CY=NO CHAR
  39. CHEKCC    EQU    252        ;CHECK FOR ^C FROM KBD, Z=PRESENT
  40. SNDRDY    EQU    251        ;TEST FOR MODEM-SEND READY
  41. RCVRDY    EQU    250        ;TEST FOR MODEM-RECEIVE READY
  42. SNDCHR    EQU    249        ;SEND A CHARACTER TO THE MODEM (AFTER SNDRDY)
  43. RCVCHR    EQU    248        ;RECV A CHAR FROM MODEM (AFTER RCVRDY)
  44. ;
  45. CR    EQU    13
  46. LF    EQU    10
  47. ;
  48. ;
  49. ;
  50.     ORG    DIALV        ;OVERLAY THE DIALING VECTOR
  51.     JMP    DIAL
  52. ;    
  53.     IF    DISC        ;IF PROVIDING DISCONNECT CODE
  54.     ORG    DISCV        ;OVERLAY THE VECTOR
  55.     JMP    DISCON
  56.     ENDIF
  57. ;
  58. ; This is the DIAL routine called by MEX to dial a digit. The digit
  59. ; to be dialed is passed in the A register.  Note that two special
  60. ; codes must be intercepted as non-digits: 254 (start dial sequence)
  61. ; and 255 (end-dial sequence).  Mex will always call DIAL with 254
  62. ; in the accumulator prior to dialing a number.  Mex will also call
  63. ; dial with 255 in A as an indication that dialing is complete. Thus,
  64. ; the overlay may use these values to "block" the number, holding it
  65. ; in a buffer until it is completely assembled.
  66. ; After the 254-start-dial sequence, MEX will call the overlay with
  67. ; digits, one-at-a-time.  MEX will make no assumptions about the dig-
  68. ; its, and will send each to the DIAL routine un-inspected (some modems,
  69. ; like the Smartmodem, allow special non-numeric characters in the
  70. ; phone number, and MEX may make no assumptions about these).
  71. ;
  72. ; After receiving the end-dial sequence (255) the overlay must take
  73. ; whatever end-of-dial actions are necessary *including* waiting for
  74. ; carrier at the distant end.  The overlay should monitor the keyboard
  75. ; during this wait (using the MEX keystat service call), and return
  76. ; an exit code to MEX in the A register, as follows:
  77. ;
  78. ;    0 - Carrier detected, connection established
  79. ;    1 - Far end busy (only for modems that can detect this condition)
  80. ;    2 - No answer (or timed out waiting for modem response)
  81. ;    3 - Keyboard abort (^C only: all others should be ignored)
  82. ;    4 - Error reported by modem
  83. ;
  84. ; <No other codes should be returned after an end-dial sequence>
  85. ;
  86. ; The overlay should not loop forever in the carrier-wait routine, but
  87. ; instead use either the overlay timer vector, or the INMDMV (timed 100
  88. ; ms character wait) service call routine.
  89. ;
  90. ; The DIAL routine is free to use any of the registers, but must return
  91. ; the above code after an end-dial sequence
  92. ;
  93.     ORG    DIALOC
  94. ;
  95. DIAL:    CPI    254        ;START DIAL?
  96.     JZ    STDIAL        ;JUMP IF SO
  97.     CPI    255        ;END DIAL?
  98.     JZ    ENDIAL        ;JUMP IF SO
  99. ;
  100. ; Not start or end sequence, must be a digit to be sent to the modem
  101. ;
  102.     CALL    SEND        ;SEND CHARACTER TO MODEM
  103.     RET            ;ALL DONE
  104. ;
  105. ; Here on a start-dial sequence
  106. ;
  107. STDIAL:    CALL     SETUP        ;WAKE UP THE VENTEL
  108.     RET
  109. ;
  110. ; Here on an end-dial sequence
  111. ;
  112. ENDIAL: MVI    A,CR        ;PUT A CR AT THE END
  113.     CALL    SEND        ;SEND CR TO MODEM
  114.  
  115. WAITVP: MVI    C,INMDM
  116.     CALL    MEX        ;CATCH ANY OUTPUT FROM THE MODEM
  117.     JNC    WAITVP        ;LOOP UNTIL NO MORE CHARACTERS
  118. ;
  119. ; THE FOLLOWING LOOP WAITS FOR A RESULT FROM THE MODEM (UP TO
  120. ; 60 SECONDS: YOU MAY CHANGE THIS VALUE IN THE FOLLOWING LINE).
  121. ;
  122. RESULT:    MVI    C,60        ;<<== MAXIMUM TIME TO WAIT FOR RESULT
  123. VPWLP:    PUSH    B
  124.     MVI    B,1        ;CHECK FOR A CHAR, UP TO 1 SEC WAIT
  125.     MVI    C,TMDINP    ;DO TIMED INPUT
  126.     CALL    MEX
  127.     POP    B
  128.     JNC    VPTEST        ;JUMP IF MODEM HAD A CHAR
  129.     PUSH    B        ;NO, TEST FOR CONTROL-C FROM CONSOLE
  130.     MVI    C,CHEKCC
  131.     CALL    MEX
  132.     POP    B
  133.     JNZ    VPNEXT        ;IF NOT, JUMP
  134.     MVI    B,CR        ;YES, SHUT DOWN THE MODEM
  135.     MVI    C,SNDCHR
  136.     CALL    MEX
  137.     MVI    A,3        ;RETURN ABORT CODE
  138.     RET
  139. VPNEXT:    DCR    C        ;NO
  140.     JNZ    VPWLP        ;CONTINUE
  141. ;
  142. ; ONE MINUTE WITH NO MODEM RESPONSE (OR NO CONNECTION)
  143. ;
  144. VPTIMO:    MVI    A,2        ;RETURN TIMEOUT CODE
  145.     RET
  146. ;
  147. ; MODEM GAVE US A RESULT, CHECK IT
  148. ;
  149. VPTEST:    ANI    7FH        ;IGNORE ANY PARITY
  150.     CALL    VPANAL        ;TEST THE RESULT
  151.     MOV    A,B        ;A=RESULT (CY SIGNIFICANT HERE TOO)
  152.     PUSH    PSW        ;SAVE IT
  153. VPTLP:    MVI    C,INMDM        ;FLUSH ANY REMAINING COMMAND LINE
  154.     CALL    MEX
  155.     JC    VPCHEK        ;JUMP IF NO INPUT
  156.     CPI    LF        ;GOT SOME ... WAITING FOR EOL
  157.     JNZ    VPTLP        ;EAT ANY IN-BETWEEN
  158. VPCHEK:    POP    PSW        ;A HAS MEX RETURN-CODE, CY=1 IF UNKNOWN
  159.     JC    RESULT        ;IF RESULT UNKNOWN, IGNORE IT
  160.     RET
  161. ;
  162. VPANAL:    MVI    B,0        ;PREP CONNECT CODE
  163.     CPI    'O'        ;"CONNECT"?
  164.     RZ
  165.     INR    B        ;PREP BUSY CODE B=1
  166.     CPI    'B'
  167.     RZ
  168.     INR    B        ;PREP NO CONNECT MSG B=2
  169.     CPI    'N'        ;N=NO CONNECT
  170.     RZ
  171.     MVI    B,4        ;PREP MODEM ERROR
  172.     CPI    'E'        ;E=ERROR
  173.     RZ
  174.     STC            ;UNKNOWN...
  175.     RET
  176. ;
  177. ;    SET UP ROUTINE TO WAKE VEN-TEL UP
  178. ;
  179. SETUP:    MVI    C,SNDRDY    ;CHECK TO SEE IF MODEM IS ALIVE
  180.     CALL     MEX
  181.     JNZ    SETUP
  182.     MVI    A,CR        ;send first cr of 3
  183.     CALL    SEND
  184.     CALL    DELAY1        ;Wait to avoid sending CR's too fast for modem
  185. SETUP2:    MVI    C,SNDRDY
  186.     CALL    MEX
  187.     JNZ    SETUP2
  188.     MVI    A,CR        ;send second cr
  189.     CALL    SEND
  190.     CALL    DELAY1
  191. SETUP3:    MVI    C,SNDRDY    
  192.     CALL    MEX
  193.     JNZ    SETUP3
  194.     MVI    A,CR        ;send third cr
  195.     CALL    SEND
  196.     MVI    B,30        ;Wait to get past banner
  197.     MVI    C,TIMER
  198.     CALL    MEX
  199.     CALL    DELAY1
  200. KOUT:    MVI    C,SNDRDY
  201.     CALL    MEX
  202.     JNZ    KOUT
  203.     MVI    B,'K'    ;GET READY TO DIAL
  204.     MVI    C,SNDCHR
  205.     CALL    MEX
  206.     CALL    DELAY1
  207.     RET
  208. ; 
  209. DELAY1:    MVI    B,5        ;Delay routine
  210.     MVI    C,TIMER
  211.     CALL    MEX
  212.     RET
  213.  
  214. ;    SEND A CHARACTER TO THE MODEM
  215. ;
  216. SEND:    MOV    B,A        ;WHEN CALLING HERE, THE CHAR IS IN A
  217.     MVI    C,SNDCHR
  218.     CALL    MEX
  219.     RET
  220. ;                End of  Overlay
  221.     END
  222.