home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / sigm / vols200 / vol219 / mxo-im10.asm < prev    next >
Encoding:
Assembly Source File  |  1994-07-13  |  6.6 KB  |  217 lines
  1.     TITLE    'MEX CERMETEK INFO-MATE 212A OVERLAY V1.0'
  2. ;
  3. ; (DELETE ABOVE TITLE LINE IF ASSEMBLING WITH ASM)
  4. ;
  5. ; Cermetek Info-Mate 212A overlay for MEX: version 1.0
  6. ;
  7. ; Derived from MXO-SM11.AQM by Ronald Mozer (V1.0)
  8. ; Original written by Ronald G. Fowler (V1.0)
  9. ;
  10. ; This modules adapts MEX for the Cermetek Info-Mate 212A modem.
  11. ; The main function of this module is to provide dialing capability;
  12. ; the disconnect vector is ancillary.  You must supply the disconnect
  13. ; routine which drops the DTR line in the standard mdm7 overlay as
  14. ; the info-mate has no other way of hanging up after the 'U 1' code.
  15. ;
  16. ; Use the MXO-SM?? or MXO-PM?? as a model to develop dialing routines
  17. ; for non-standard modems (e.g., the Racal-Vadic) as they will be better
  18. ; supported.
  19. ;
  20. ; This overlay will work with any modem overlay that terminates
  21. ; prior to 0B00H
  22. ;
  23. ;
  24. ; SYSTEM CONSTANTS
  25. ;
  26. DIALV    EQU    0162H        ;LOCATION OF DIAL VECTOR IN OVERLAY
  27. GOODBY    EQU    0168H        ;LOCATION OF GOODBYE VECTOR IN OVERLAY
  28. DIALOC    EQU    0B00H        ;DIALING CODE GOES HERE
  29. MEX    EQU    0D00H        ;"CALL MEX"
  30. ;
  31. ; FOLLOWING ARE FUNCTION CODES FOR THE MEX SERVICE CALL PROCESSOR
  32. ;
  33. INMDM    EQU    255        ;RETURN CHAR FROM MDM IN A, CY=NO CHR IN 100MS
  34. TIMER    EQU    254
  35. TMDINP    EQU    253        ;B=# SECS TO WAIT FOR CHAR, CY=NO CHAR
  36. CHEKCC    EQU    252        ;CHECK FOR ^C FROM KBD, Z=PRESENT
  37. SNDRDY    EQU    251        ;TEST FOR MODEM-SEND READY
  38. RCVRDY    EQU    250        ;TEST FOR MODEM-RECEIVE READY
  39. SNDCHR    EQU    249        ;SEND A CHARACTER TO THE MODEM (AFTER SNDRDY)
  40. RCVCHR    EQU    248        ;RECV A CHAR FROM MODEM (AFTER RCVRDY)
  41. ;
  42. CR    EQU    13
  43. LF    EQU    10
  44. ;
  45. ;
  46.     ORG    DIALV        ;OVERLAY THE DIALING VECTOR
  47.     JMP    DIAL
  48. ;
  49. ; This is the DIAL routine called by MEX to dial a digit. The digit
  50. ; to be dialed is passed in the A register.  Note that two special
  51. ; codes must be intercepted as non-digits: 254 (start dial sequence)
  52. ; and 255 (end-dial sequence).  Mex will always call DIAL with 254
  53. ; in the accumulator prior to dialing a number.  Mex will also call
  54. ; dial with 255 in A as an indication that dialing is complete. Thus,
  55. ; the overlay may use these values to "block" the number, holding it
  56. ; in a buffer until it is completely assembled (in fact, that's the
  57. ; scheme employed here for the Info-Mate).
  58. ;
  59. ; After the 254-start-dial sequence, MEX will call the overlay with
  60. ; digits, one-at-a-time.  MEX will make no assumptions about the dig-
  61. ; its, and will send each to the DIAL routine un-inspected (some modems,
  62. ; like the Smartmodem, allow special non-numeric characters in the
  63. ; phone number, and MEX may make no assumptions about these).
  64. ;
  65. ; After receiving the end-dial sequence (255) the overlay must take
  66. ; whatever end-of-dial actions are necessary *including* waiting for
  67. ; carrier at the distant end.  The overlay should monitor the keyboard
  68. ; during this wait (using the MEX keystat service call), and return
  69. ; an exit code to MEX in the A register, as follows:
  70. ;
  71. ;    0 - Carrier detected, connection established
  72. ;    1 - Far end busy (only for modems that can detect this condition)
  73. ;    2 - No answer (or timed out waiting for modem response)
  74. ;    3 - Keyboard abort (^C only: all others should be ignored)
  75. ;    4 - Error reported by modem
  76. ;
  77. ; <No other codes should be returned after an end-dial sequence>
  78. ;
  79. ; The overlay should not loop forever in the carrier-wait routine, but
  80. ; instead use either the overlay timer vector, or the INMDMV (timed 100
  81. ; ms character wait) service call routine.
  82. ;
  83. ; The DIAL routine is free to use any of the registers, but must return
  84. ; the above code after an end-dial sequence
  85. ;
  86.     ORG    DIALOC
  87. ;
  88. DIAL:    LHLD    DIALPT        ;FETCH POINTER
  89.     CPI    254        ;START DIAL?
  90.     JZ    STDIAL        ;JUMP IF SO
  91.     CPI    255        ;END DIAL?
  92.     JZ    ENDIAL        ;JUMP IF SO
  93. ;
  94. ; Not start or end sequence, must be a digit to be sent to the modem
  95. ;
  96.     MOV    M,A        ;PUT CHAR IN BUFFER
  97.     INX    H        ;ADVANCE POINTER
  98.     SHLD    DIALPT        ;STUFF PNTR
  99.     RET            ;ALL DONE
  100. ;
  101. ; Here on a start-dial sequence
  102. ;
  103. STDIAL:    CALL    GOODBY
  104.     LXI    H,DIALBF    ;SET UP BUFFER POINTER
  105.     SHLD    DIALPT
  106.     RET
  107. ;
  108. ; Here on an end-dial sequence
  109. ;
  110. ENDIAL:    MVI    M,27H        ;CLOSE INFO-MATE QUOTES
  111.     INX    H
  112.     MVI    M,CR        ;STUFF END-OF-LINE INTO BUFFER
  113.     INX    H        ;FOLLOWED BY TERMINATOR
  114.     MVI    M,0
  115.     LXI    H,IMDIAL    ;POINT TO DIALING STRING
  116.     CALL    IMSEND        ;SEND IT
  117. ;
  118. ; THE FOLLOWING LOOP WAITS FOR A RESULT FROM THE MODEM (UP TO
  119. ; 60 SECONDS: YOU MAY CHANGE THIS VALUE IN THE FOLLOWING LINE).
  120. ; NOTE THAT THE SMARTMODEM HAS AN INTERNAL 30 SECOND TIMEOUT WHILE
  121. ; FOR A CARRIER ON THE OTHER END.  YOU CAN CHANGE BY PLAYING WITH THE
  122. ; S7 VARIABLE (I.E. SEND THE SMARTMODEM "AT S7=20" TO LOWER THE 30 SECOND
  123. ; WAIT TO 20 SECONDS).
  124. ;
  125. RESULT:    MVI    C,30        ;<<== MAXIMUM TIME TO WAIT FOR RESULT
  126. SMWLP:    PUSH    B
  127.     MVI    B,1        ;CHECK FOR A CHAR, UP TO 1 SEC WAIT
  128.     MVI    C,TMDINP    ;DO TIMED INPUT
  129.     CALL    MEX
  130.     POP    B
  131.     JNC    IMTEST        ;JUMP IF MODEM HAD A CHAR
  132.     PUSH    B        ;NO, TEST FOR CONTROL-C FROM CONSOLE
  133.     MVI    C,CHEKCC
  134.     CALL    MEX
  135.     POP    B
  136.     JNZ    IMNEXT        ;IF NOT, JUMP
  137.     CALL    GOODBY        ;YES, SHUT DOWN THE MODEM
  138.     MVI    A,3        ;RETURN ABORT CODE
  139.     RET
  140. IMNEXT:    DCR    C        ;NO
  141.     JNZ    SMWLP        ;CONTINUE
  142. ;
  143. ; ONE MINUTE WITH NO MODEM RESPONSE (OR NO CONNECTION)
  144. ;
  145. SMTIMO:    MVI    A,2        ;RETURN TIMEOUT CODE
  146.     RET
  147. ;
  148. ; MODEM GAVE US A RESULT, CHECK IT
  149. ;
  150. IMTEST:    ANI    7FH        ;IGNORE ANY PARITY
  151.     CALL    IMANAL        ;TEST THE RESULT
  152.     JC    RESULT        ;GO TRY AGAIN IF UNKNOWN RESPONSE
  153.     MOV    A,B        ;A=RESULT 
  154.     PUSH    PSW        ;SAVE IT
  155. IMTLP:    MVI    C,INMDM        ;EAT ANY ADDITIONAL CHARS FROM SMARTMODEM
  156.     CALL    MEX
  157.     JNC    IMTLP        ;UNTIL 100MS OF QUIET TIME
  158.     POP    PSW        ;RETURN THE CODE
  159.     ORA    A        ;CONNECT????
  160.     RZ
  161.     PUSH    PSW
  162.     CALL    GOODBY        ;HANGUP THE PHONE IF NOT GOOD CONNECT...
  163.     POP    PSW        ;SAVE RESULT CODE...
  164.     RET
  165. ;
  166. IMANAL:    MVI    B,0        ;PREP CONNECT CODE
  167.     CPI    'A'        ;"CONNECT"?
  168.     RZ
  169.     INR    B        ;PREP BUSY CODE B=1
  170.     CPI    'B'
  171.     RZ
  172.     INR    B        ;PREP NO CONNECT MSG B=2
  173.     CPI    'N'        ;N=NO CONNECT
  174.     RZ
  175.     MVI    B,4        ;PREP MODEM ERROR
  176.     CPI    '?'        ;E=ERROR
  177.     RZ
  178. ;
  179. ; THE FOLLOWING ARE CODES THAT THE INFO-MATE CAN DETECT BUT MEX DOES
  180. ; NOT SUPPORT AN APPROPIATE RESULT CODE... ALL OF THE FOLLOWING INDICATE
  181. ; AN ABORT SITUATION - SO - I AM USING THE CONTROL C ABORT RESULT CODE.
  182. ;
  183.     MVI    B,3        ;ABORT CODE
  184.     CPI    'W'        ;WRONG SPEED.
  185.     RZ
  186.     CPI    'V'        ;HUMAN VOICE DETECTED..
  187.     RZ
  188.     CPI    'X'        ;NO DIAL TONE DETECTED..
  189.     RZ
  190. ;
  191. ; UNKNOWN RESPONSE, RETURN CARRY TO CALLER.
  192. ;
  193.     STC
  194.     RET
  195. ;
  196. ; INFO-MATE UTILITY ROUTINE: SEND STRING TO MODEM
  197. ;
  198. IMSEND:    MVI    C,SNDRDY    ;WAIT FOR MODEM READY
  199.     CALL    MEX
  200.     JNZ    IMSEND
  201.     MOV    A,M        ;FETCH NEXT CHARACTER
  202.     INX    H
  203.     ORA    A        ;END?
  204.     RZ            ;DONE IF SO
  205.     MOV    B,A        ;NO, POSITION FOR SENDING
  206.     MVI    C,SNDCHR    ;NOPE, SEND THE CHARACTER
  207.     CALL    MEX
  208.     JMP    IMSEND
  209. ;
  210. ; DATA AREA
  211. ;
  212. IMDIAL:    DB    'N'-40H,'U 1,D ',27H ;SET MODEM TO QUITE AND DIAL #
  213. DIALBF:    DS    52        ;2* 24 CHAR MAX, + CR + NULL + SLOP
  214. DIALPT:    DS    2        ;DIAL POSITION POINTER
  215. ;
  216.     END
  217.