home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / sigm / vols100 / vol193 / bishow31.asm < prev    next >
Encoding:
Assembly Source File  |  1994-07-13  |  45.9 KB  |  1,867 lines
  1. ;    title    'BISHOW v3.01 - buffered bidirectional file scroll utility'
  2. ;
  3. ; Ver 3.01, 15 Jan 84, Frans van Duinen, Toronto, Ont
  4. ;    - made unsqueeze message optional
  5. ;    - added library capability
  6. ;    - fixed bug in conditional assembly of CLRSCR
  7. ;
  8. ; Ver 2.09, 7 Jan 84, Frans van Duinen, Toronto, Ont
  9. ;    - Modified USQ routines for higher speed (+10%) and
  10. ;     less memory usage.
  11. ;    - made USQ code optional through conditional assembly
  12. ;    - fixed a bug introduced with 2.08 and SHORT=TRUE 
  13. ;      (resulted from ASM's inability to nest IF/ENDIF) 
  14. ;    - fixed a bug  that reset FCBEX after open, whenever
  15. ;      sector 0 was read, (this resulted in BDOS assuming that
  16. ;      the current extent, whose allocation group nos were still
  17. ;      in the FCB, was the correct one. 
  18. ;    - Changed exit to clear screen only on Q or ^C exit,
  19. ;      to leave any messages visible
  20. ;    - Made wait after clear screen a cond assembly option
  21. ;
  22. ; Ver 2.08, 2 Jan 84, Frans van Duinen, Toronto, Ont
  23. ;    - added squeezed file capability
  24. ;    - added sidewise scrolling on ^I, ^L, steps of 8
  25. ;    - Osborne support for cursor keys, clr scr & scr size
  26. ;    - Changed FILBAK rtn to recognize top of file
  27. ;    - Set up flag to avoid unnecessary re-reading of
  28. ;      top of file 
  29. ;
  30. ;    The unsqueeze code was lifted from the USQ base code
  31. ;    by Dave Rand (Edmonton, Alberta) as adapted for LTYPE1
  32. ;    by S.Kluger (El Paso,Texas)
  33. ;    The code was lifted to allow continued use of ASM.COM 
  34. ;
  35. ; Ver 1.07, 1 Aug 83, Ted H. Emigh  ...!unc!tucc!emigh
  36. ;    - added screen width specification
  37. ;    - added screen definition commands (see notes below)
  38. ;
  39. ; Ver 1.06, 2 Jul 83, Chuck Forsberg
  40. ;    - added commands for more, mince, vi familiarity.
  41. ;      Bad cmd gives help
  42. ;
  43. ; Ver 1.051, 26 June 83, Dick Mead
  44. ;    - added "?" for help on commands.
  45. ;
  46. ; Ver 1.05, 31 May 83, Bruce Ratoff
  47. ;    - added 'N' (next line) and 'P' (previous line) cmds
  48. ;    - decreased buffer from 8k to 4k (8k takes too long)
  49. ;
  50. ; Ver 1.04, 15 May 83, Keith Petersen, W8SDZ
  51. ;    - fixed bug which caused display past end-of-file
  52. ;        and added bogus eof in case none at file end
  53. ;    - added strip of high-order bit in line count routine
  54. ;    - added exit clear of any left-over keyboard character
  55. ;
  56. ; Ver 1.03, 11 May 83, Keith Petersen, W8SDZ
  57. ;    - fixed to allow assembly with ASM.COM
  58. ;    - fixed screen clear bug when crossing read boundries
  59. ;    - added strip for high-order bit in character before
  60. ;        printing (needed for WordStar files)
  61. ;    - improved stack routines
  62. ;    - fixed bug in console input routine
  63. ;    - removed Z80 dependant code (now works on 8080 too)
  64. ;
  65. ; Ver 1.02, 06 May 83, Lucien Pan, Toronto, Canada
  66. ;     - fixed some minor bugs
  67. ;     - returns to ccp w/o warm boot
  68. ;     - filters form-feeds (useful in .PRN files)
  69. ;     - scrolls foward/backwards by same number of lines
  70. ;     - disable/enable cursor during scroll for H-19
  71. ;
  72. ; Ver 1.01, 30 Mar 83 - added BDOS function  6.  W.F.Mcgee
  73. ;
  74. ; Ver 1.00, 23 Aug 82 Phil Cary, 748 Kenilworth Parkway, Baton
  75. ; Rouge, LA  70808
  76. ;
  77. ; BISHOW is a  buffered,  bidirectional  version  of  SHOW.ASM
  78. ; which first appeared in Interface Age, November, 1981.  That
  79. ; program  could  only  scroll  forward  in  a  file, and read
  80. ; sectors from disk one at a time as they  were  sent  to  the
  81. ; console.   I  used SHOW frequently to take a quick look at a
  82. ; file without loading a  big  text  editor,  and  to  examine
  83. ; another  file  with the RUN command while in Wordstar.  TYPE
  84. ; does not work since it is not a file that Wordstar can  load
  85. ; and run.
  86. ;
  87. ; It was annoying when I went past the point I was looking for
  88. ; in a file with SHOW, and could not go backwards.  Thus, this
  89. ; bidirectional  version  which  uses  random access reads. In
  90. ; addition, buffering was added so that  the  number  of  disk
  91. ; reads  would  be  reduced,  and  moving  back and forth in a
  92. ; moderate sized file would be speeded up.  There is  a  trade
  93. ; off between the size of the buffer and the length of time it
  94. ; takes to refill the buffer which should be set to the user's
  95. ; preference.
  96. ;
  97. ; There are several customizing items in this program.  One is 
  98. ; the equate "maxsec" which sets the buffer size.   Another is 
  99. ; the  string  in the subroutine "clrscr" just after  the  org 
  100. ; statement.   This should be changed to erase the screen  and 
  101. ; home  the cursor for the user's terminal.   The program,  as 
  102. ; written,  requires a terminal with an erase screen and  home 
  103. ; cursor  function.   Some  terminals  do not allow  the  80th 
  104. ; column  to be filled without going to the  next  line.   For 
  105. ; this reason, the screen width ("maxchr") initially is set to 
  106. ; 79.   The screen sizes can be changed using the "S" (screen) 
  107. ; command.  The parameters that can be changed are the maximum 
  108. ; column  displayed ("maxchr"),  the minimum column  displayed 
  109. ; (allowing  you  to "window" the output),  and the number  of 
  110. ; lines ("scroln").   A zero for the maximum column  displayed 
  111. ; will  give and unlimited screen width.   The maximum  column 
  112. ; displayed  and  the number of lines can be set when  calling 
  113. ; BISHOW,  e.g.,  "BISHOW file.nam 79 24" will give 79 columns 
  114. ; and 24 lines,  and "BISHOW file.nam 79" will give 79 columns 
  115. ; with the default number of lines.  The last customizing item 
  116. ; is the "short" equate.   If this is chosen, the multiplicity 
  117. ; of command forms is not allowed (see the beginning to change 
  118. ; the  commands  used),  and certain messages  are  shortened.  
  119. ; This will allow BISHOW to fit into a 1K area.  If "short" is 
  120. ; false, the program is slightly over 1K.  Finally, direct I/O 
  121. ; to the console is used to avoid echoing the commands to  the 
  122. ; console as the CP/M write console function does.
  123. ;
  124. ; Just  a  small contribution to the public domain software as
  125. ; partial payment for the many fine and  educational  programs
  126. ; the system has given me.  Phil Cary.
  127. ;
  128. ;Define version number for help message
  129. VERS    EQU    3        ;Note current use in DB constrains VERS & 
  130. REVS    EQU    10        ; REVS to be one and two digits respectively
  131. ;
  132. FALSE    EQU    0
  133. TRUE    EQU    NOT FALSE
  134. ;
  135. HEATH    EQU    FALSE        ;assemble for H-19 terminal
  136. OSBORNE    EQU    TRUE        ;assemble for Osborne I
  137. SHORT    EQU    FALSE        ;set to true if you want the short version
  138.                 ;which is less than 1K
  139.                 ;Requires also that SQUEEZE is set false
  140. SQUEEZE    EQU    TRUE        ;Generate code to handle squeezed files 
  141. NOWAIT    EQU    TRUE        ;Do not wait after clear screen
  142. SILENT    EQU    TRUE        ;No "unsqueezing text" msg
  143. LIBRARY    EQU    TRUE        ;Optional handling of library type files
  144. ;
  145. ;    Operational equates
  146. ;
  147. MAXSEC    EQU    32        ;number of sectors in buffer
  148. SQSIGN    EQU    0FF76H        ;Signature for SQ files
  149. LBSIGN    EQU    2000H        ;Signature for library files
  150. DLE    EQU    090H        ;Char flag for run compression (SQ)
  151. ;
  152.     IF    NOT OSBORNE
  153. SCROLN    EQU    24        ;number of lines per scroll
  154. MAXCHR    EQU    79        ;number of characters per line
  155. ARWLFT    EQU    08H        ;Cursor left key (backspace)
  156. ARWRT    EQU    09H        ;Cursor right key (tab)
  157.     ENDIF
  158. ;
  159.     IF    OSBORNE
  160. SCROLN    EQU    24        ;number of lines per scroll
  161. MAXCHR    EQU    51        ;number of characters per line
  162. ARWLFT    EQU    08H        ;Cursor left key (backspace)
  163. ARWUP    EQU    0BH        ;Cursor up key (vert tab)
  164. ARWRT    EQU    0CH        ;Cursor right key (formfeed)
  165.     ENDIF
  166.  
  167. ;
  168. BASE    EQU    0        ;standard zero base CP/M
  169. ;
  170. ;    BDOS functions
  171. ;
  172. CONOUT    EQU    2        ;console write
  173. OPEN    EQU    15        ;open file
  174. CLOSE    EQU    16        ;close file
  175. READR    EQU    33        ;read file random access
  176. STDMA    EQU    26        ;set dma address
  177. ;
  178. ;    Page zero equates
  179. ;
  180. WBOOT    EQU    BASE        ;warm boot entry point
  181. BDOS    EQU    WBOOT+5        ;BDOS entry point
  182. FCB    EQU    WBOOT+5CH    ;default fcb drive number
  183. CMDTAIL    EQU    WBOOT+80H    ;location of command tail
  184. FCBFN    EQU    FCB+1        ;start of filename
  185. FCBFT    EQU    FCB+9        ;start of filetype
  186. FCBEX    EQU    FCB+12        ;current extent number
  187. FCBCRR    EQU    FCB+33        ;current record number, random access
  188. TPA    EQU    WBOOT+100H    ;transient program area
  189. ;
  190. ;    ASCII equates
  191. ;
  192. ENDMSG    EQU    0        ;null
  193. BELL    EQU    7        ;bell
  194. BS    EQU    8        ;Backspace
  195. TAB    EQU    9        ;tab
  196. LF    EQU    0AH        ;line feed
  197. CR    EQU    0DH        ;carriage return
  198. EOF    EQU    1AH        ;end of file
  199. ESC    EQU    1BH        ;escape
  200. SPACE    EQU    20H        ;space
  201. ;
  202. ; Equates for the short version
  203. ;
  204. ; Any invalid command gives help
  205. ; in addition to quit, ^C ends the program
  206. ; Be sure to change the help2 printout
  207. ;
  208. NXTPAG    EQU    SPACE        ;next page
  209. BACK    EQU    'B'        ;scroll backward
  210. NEXT    EQU    CR        ;next line
  211. PREV    EQU    '-'        ;previous line
  212. SCREEN    EQU    'S'        ;set screen parameters
  213. QUIT    EQU    'Q'        ;exit bishow
  214. FIRST    EQU    '1'        ;first page
  215. ;
  216.     ORG    TPA
  217. ;
  218.     JMP    START        ;skip over next subroutine
  219. ;
  220. CLRSCR:
  221.     CALL    CDISP        ;command to erase screen and home cursor
  222. ;
  223.     IF    NOT (HEATH OR OSBORNE)
  224.     DB    ESC,'+',ENDMSG    ;put your screen clear string here
  225.     ENDIF
  226. ;
  227.     IF    HEATH
  228.     DB    ESC,'E',ENDMSG    ;__for H/Z-19 terminal. change as required
  229.     ENDIF
  230. ;
  231.     IF    OSBORNE
  232.     DB    1AH,ENDMSG    ;__for Osborne (& Televideo?)
  233.     ENDIF
  234. ;
  235.     IF    NOT NOWAIT
  236. ;
  237. WAIT:    MVI    B,0        ;waste time (may or may not be necessary)
  238. ;
  239. WAIT1:    XTHL            ;good time gobbeler!
  240.     XTHL
  241.     DCR    B
  242.     JNZ    WAIT1
  243. ;
  244.     ENDIF
  245. ;
  246.     RET            ;return from clrscr
  247. HELP2:
  248.     CALL    CDISP
  249.     DB    CR,LF,'Commands:',CR,LF
  250. ;
  251.     IF    NOT SHORT
  252.     DB    '^F,F,^V,sp=next page, ^B,B=back page, '
  253.     DB    '^H=left, ^L=rite'
  254.     DB    CR,LF
  255.     DB    'CR,+,N=next line, '
  256.     DB    '-,P=back line, 1=1st line, ^C,Q=exit',CR,LF,ENDMSG
  257.     ENDIF
  258. ;
  259.     IF    SHORT
  260.     DB    'sp=next page, B=back page',CR,LF
  261.     DB    'CR=next line, '
  262.     DB    '-=back line, 1=1st line, ^C,Q=exit',CR,LF,ENDMSG
  263.     ENDIF
  264. ;
  265.     JMP    GETCMD
  266. ;
  267. START:    LXI    H,0        ;get ccp's stack
  268.     DAD    SP
  269.     SHLD    STACK        ;save old stack for later
  270.     LXI    SP,STACK    ;set new stack
  271.     LXI    H,CMDTAIL    ;point to command tail
  272.     MOV    B,M        ;get number of char in tail
  273.     INX    H        ;point to first character
  274.     INR    B
  275. ;
  276.     CALL    EATSP        ;Step to next non-bl in input
  277.     JZ    OPENF        ;no more characters
  278. ;
  279.     CALL    FILNAM        ;Skip file name, returns <B>=0 or <A>=20H
  280.     JZ    OPENF        ;only file name in tail
  281. ;
  282. ;            Check if there is a member name
  283. ;
  284.     CALL    EATSP        ;Step to next non-bl in input
  285.     JZ    OPENF        ;no more characters
  286.     CPI    '9'+1        ;Numeric?
  287.     JNC    MEMB        ;No -
  288.     CPI    '0'
  289.     JNC    NUMBER        ;Yes - must be width & heigth
  290. ;            Have member name (at FCB+11H)
  291. MEMB:
  292.     STA    MEMNAM        ;No - have member name
  293.     PUSH    H        ;Posn in command line 
  294.     PUSH    B        ;# of chars remaining
  295.     LXI    H,FCB+11H    ;Source
  296.     LXI    D,MEMFCB+1    ;Destination
  297.     MVI    B,11        ;Move name + type
  298.     CALL    MOVE 
  299. ;                add LBR suffix if required
  300.     LXI    H,FCB+9        ;Is there a suffix
  301.     MOV    A,M
  302.     CPI    SPACE
  303.     JNZ    NUMBR2        ;Yes - leave
  304.     MVI    M,'L'
  305.     INX    H
  306.     MVI    M,'B'
  307.     INX    H
  308.     MVI    M,'R'
  309. NUMBR2:
  310.     POP    B
  311.     POP    H
  312.     CALL    FILNAM        ;Skip member name, returns <B>=0 or <A>=20H
  313.     JZ    OPENF        ;end
  314. ;
  315. ;            Handle screen width & height
  316. NUMBER:
  317.     LXI    D,CHRMAX    ;point to chr/line
  318.     CALL    GETNBR        ;get number of characters/line
  319.     JC    HELP        ;invalid number
  320.     LXI    D,LINMAX    ;point to number of lines
  321.     CNZ    GETNBR        ;call only if characters still in
  322.                 ;__command tail
  323.     JC    HELP        ;invalid number
  324. ;
  325. OPENF:    CALL    OPNFIL        ;open file in default fcb
  326. ;
  327.     IF    SQUEEZE
  328. ;
  329.     CALL    CHKSQ        ;Check for squeezed, init if
  330. ;                ;Returns first word in file in <HL>
  331. ;
  332.     ENDIF
  333. ;
  334.     IF    LIBRARY
  335. ;
  336.     CALL    CLRSCR        ;erase the screen
  337.     CALL    FILBF0        ;fill the disk buffer with start of file
  338.     CALL    CHKLB        ;Check for library file
  339.     JMP    WRTFW0        ;Buffer contains top sectors
  340. ;
  341.     ENDIF    
  342. ;
  343. WRTFWD:
  344.     CALL    CLRSCR        ;erase the screen
  345.     CALL    FILBF0        ;fill the disk buffer with start of file
  346. WRTFW0:
  347.     LXI    H,DSKBUF    ;point to beginning of buffer
  348. ;
  349. WRTFW1:
  350.     MOV    A,M        ;get a character
  351.     CPI    EOF        ;see if eof
  352.     JZ    GETCMD        ;yes, wait for command
  353.     INX    H        ;bump pointer
  354.     ANI    7FH        ;strip high bit
  355.     CPI    'L'-40H        ;filter form-feeds
  356.     JZ    FILTER        ;__commonly found in .PRN files
  357.     CALL    CO1        ;put it on console
  358.     CPI    CR        ;see if end of line
  359.     JZ    FWDCNT        ;yes, adjust line count
  360. ;
  361. WRTFW2:    LXI    D,ENDBUF    ;get end of buffer address
  362.     CALL    cmphlde        ;Is HL> gt DE> (end of buff)
  363. ;                ; Note test is LT now, not NE (v1.81)
  364.     JC    WRTFW1        ;continue with next character
  365.     CALL    FILBUF        ;fill the disk buffer with next sectors
  366.     JMP    WRTFW0        ;start over
  367. ;
  368. HELP:    CALL    CDISP
  369.     DB    'BISHOW version '
  370.     DB    (VERS MOD 10)+'0','.'
  371.     DB    REVS/10+'0',(REVS MOD 10)+'0',CR,LF
  372.     DB    'Usage: d:bishow d:fn.ft '
  373. ;
  374.     IF    LIBRARY
  375. ;
  376.     DB    '[member] '
  377. ;
  378.     ENDIF
  379. ; 
  380.     DB    '[cols [lines]]',CR,LF
  381.     DB    ENDMSG
  382.     JMP    EXIT1
  383. ;
  384. FILTER:    PUSH    PSW        ;save status
  385.     MVI    A,'^'        ;print '^' in front
  386.     CALL    CO1        ;__of control character
  387.     POP    PSW        ;restore status
  388.     ADI    40H        ;mask into displayable char
  389.     CALL    CO1        ;display filtered control char
  390. ;
  391. FWDCNT:    LDA    LINCNT        ;get number of lines displayed
  392.     INR    A        ;bump it
  393.     STA    LINCNT        ;__and store it
  394.     MOV    D,A        ;save lincnt
  395.     LDA    LINMAX        ;get max number of line
  396.     CMP    D        ;compare with line count
  397.     JNZ    WRTFW2        ;if not there, continue, else get command
  398.     XRA    A        ;zero the
  399.     STA    LINCNT        ;__line count
  400. ;
  401. GETCMD:    PUSH    H
  402.     PUSH    D
  403.     PUSH    B
  404. ;
  405.     IF    HEATH
  406.     CALL    CDISP
  407.     DB    ESC,'x5',ENDMSG    ;disable cursor
  408.     ENDIF
  409. ;
  410. GETCM1:    CALL    GETIN        ;Get input char if any
  411.     ORA    A        ;loop till char avail
  412.     JZ    GETCM1
  413.     POP    B
  414.     POP    D
  415.     POP    H
  416.     CPI    'a'        ;change command to
  417.     JC    GETCM2        ;__upper case
  418.     CPI    'z'+1
  419.     JNC    GETCM2
  420.     XRI    20H        ;is lower case, make upper case
  421. ;
  422. GETCM2:
  423.     IF    NOT SHORT
  424.     CPI    '1'        ; 1 means goto 1st line
  425.     JZ    WRTTOP        ;Test if top in buffer
  426.     CPI    '?'        ;help request
  427.     JZ    HELP2
  428.     CPI    ' '        ;more use space
  429.     JZ    WRTFW1
  430.     CPI    'F'        ;scroll forward?
  431.     JZ    WRTFW1        ;br if yes
  432.     CPI    'F'-40H        ;vi uses ^F
  433.     JZ    WRTFW1
  434.     CPI    'V'-40H        ;mince uses ^V
  435.     JZ    WRTFW1
  436.     CPI    'B'        ;scroll backward?
  437.     JZ    WRTBAK
  438.     CPI    'B'-40H        ;vi uses ^B
  439.     JZ    WRTBAK
  440.     CPI    'N'        ;scroll next line?
  441.     JZ    WRTNXT
  442.     CPI    '+'
  443.     JZ    WRTNXT
  444.     CPI    CR        ;scroll next line?
  445.     JZ    WRTNXT
  446.     CPI    LF
  447.     JZ    WRTNXT
  448.     CPI    'P'        ;scroll prev line?
  449.     JZ    WRTPRV
  450. ;
  451.     ENDIF
  452.     IF    OSBORNE AND NOT SHORT
  453. ;
  454.     CPI    ARWUP        ;Cursor up?
  455.     JZ    WRTPRV
  456. ;
  457.     ENDIF
  458.     IF    NOT SHORT
  459. ;
  460.     CPI    '-'
  461.     JZ    WRTPRV
  462.     CPI    'C'-40H        ;must be exit
  463.     JZ    EXITCL        ;return control to CCP if yes or
  464.     CPI    'Q'        ;more use q for quit
  465.     JZ    EXITCL
  466.     CPI    'S'        ;set screen parameters
  467.     JZ    SETSCR
  468.     CPI    ARWLFT        ;Cursor left?
  469.     JZ    ADJMM
  470.     CPI    ARWRT        ;Cursor right?
  471.     JZ    ADJMM
  472.     JMP    HELP2        ;else give a hint
  473.     ENDIF
  474. ;
  475.     IF    SHORT
  476.     CPI    FIRST        ; 1 means goto 1st line
  477.     JZ    WRTTOP
  478.     CPI    NXTPAG        ;scroll forward?
  479.     JZ    WRTFW1        ;br if yes
  480.     CPI    BACK        ;scroll backward?
  481.     JZ    WRTBAK
  482.     CPI    NEXT        ;scroll next line?
  483.     JZ    WRTNXT
  484.     CPI    PREV        ;scroll prev line?
  485.     JZ    WRTPRV
  486.     CPI    'C'-40H        ;must be exit
  487.     JZ    EXITCL        ;return control to CCP if yes or
  488.     CPI    QUIT        ;alternative quit
  489.     JZ    EXITCL
  490.     CPI    SCREEN        ;set screen parameters
  491.     JZ    SETSCR
  492.     JMP    HELP2        ;else give a hint
  493.     ENDIF
  494. ;
  495. ;            Go to top of file
  496. WRTTOP:
  497.     LDA    TOPBUF        ;Get top in buffer flag
  498.     ORA    A
  499.     JNZ    WRTFWD        ;No - the hard way
  500.     CALL    CLRSCR        ;erase the screen
  501. WRTTO1:
  502.     XRA    A
  503.     STA    LINCNT        ;Clear lines put so far
  504.     JMP    WRTFW0        ;Buffer contains top sectors
  505. ;
  506. ;            Write one more line
  507. WRTNXT:    LDA    LINMAX
  508.     DCR    A        ;fool wrtfw1 to only write one line
  509.     STA    LINCNT
  510.     JMP    WRTFW1
  511. ;            Back up one line
  512. WRTPRV:    LDA    LINMAX        ;back up one screen + 1 line
  513.     INR    A
  514.     JMP    WRTBK0
  515. ;            Back up full screen
  516. WRTBAK:    LDA    LINMAX        ;get screen line count
  517.     ADD    A        ;__multiply by 2
  518. ;
  519. WRTBK0:    INR    A        ;__and add 1
  520.     STA    LINCNT        ;__to backup to previous page
  521.     CALL    CLRSCR        ;clear the screen
  522. ;
  523. WRTBK1:    LXI    D,DSKBUF    ;get address of start of buffer start
  524.     CALL    cmphlde        ;Is HL> LT DE> (start of buff)
  525. ;                ; Note test is LT now, not NE (v1.81)
  526.     JC    FILBAK        ;Go refill buffer
  527. ;
  528. WRTBK2:    MOV    A,M        ;get a character
  529.     ANI    7FH        ;strip high bit
  530.     DCX    H        ;decrement buffer
  531.     CPI    CR        ;see if end of line
  532.     JZ    BAKCNT        ;__or form-feed
  533.     CPI    'L'-40H        ;__and adjust line count if so
  534.     JNZ    WRTBK1        ;else, loop if not
  535. ;
  536. BAKCNT:    LDA    LINCNT        ;else, get number of lines to move back
  537.     DCR    A        ;__and decrement it
  538.     STA    LINCNT        ;__store it
  539.     JNZ    WRTBK1        ;__and loop if not there
  540.     INX    H        ;else bump pointer
  541.     INX    H        ;__to account for dcx
  542.     JMP    WRTFW1        ;and go write a screen
  543. ;
  544. FILBAK:
  545. ;            Test for top of file
  546.     LDA    TOPBUF        ;Get top in buffer flag
  547.     ORA    A
  548.     JZ    WRTTO1        ;Yes - start of file in buffer
  549. ;            Start of file not in buffer, step back
  550.     LHLD    SECCNT        ;Get no of sectors last read
  551.     LXI    D,MAXSEC    ;get the buffer size
  552.     DAD    D        ;add them
  553.     XCHG            ;__and put them in DE
  554.     LDA    FCBCRR        ;subtract low order byte 
  555.     SUB    E        ;__from current record count
  556.     STA    FCBCRR        ;__and store in current record count
  557.     LDA    FCBCRR+1    ;same with high order byte
  558.     SBB    D        ;__but with borrow
  559.     JM    WRTFWD        ;if beyond beginning of file, start over
  560.     STA    FCBCRR+1    ;else, store high order byte
  561.     CALL    FILBUF        ;fill the buffer
  562.     LXI    H,ENDBUF    ;__and point to end of buffer
  563.     CALL    CLRSCR        ;clear the screen
  564.     JMP    WRTBK2        ;continue moving back in file
  565. ;
  566. ;            Fill buffer with top of file 
  567. FILBF0:
  568.     XRA    A        ;get a 0
  569.     STA    LINCNT        ;store in line count
  570.     STA    CHRCNT        ;store in character count
  571. ;                Do not reset the current extent!!!
  572. ;                BDOS will switch extents only if the no
  573. ;                specified ( <FCBEX> ) does NOT agree with
  574. ;                the wanted no <FCBCRR>. 
  575.     STA    FCBCRR        ;Reset to sector zero
  576. ;
  577.     IF    NOT LIBRARY
  578. ;
  579.     STA    FCBCRR+1    ;
  580.     STA    FCBCRR+2    ;__and clear the overflow
  581. ;
  582.     ENDIF
  583. ;
  584.     IF    LIBRARY
  585. ;
  586.     LHLD    SCZERO        ;Set to sector zero for file/member
  587.     SHLD    FCBCRR
  588. ;
  589.     ENDIF
  590. ;
  591. ;            ;Fill buffer from spec'd sector
  592. FILBUF:
  593.     MVI    B,MAXSEC    ;number of sectors to resd
  594. FILB1S:
  595. ;
  596.     IF    LIBRARY
  597. ;
  598.     LHLD    SCZERO        ;Get top sector for member
  599.     XCHG 
  600.     LHLD    FCBCRR        ;Is this top of file?
  601.     CALL    cmphlde        ;This it? (<A>=0 if equal)
  602. ;
  603.     ENDIF
  604.     IF    NOT LIBRARY    
  605.     LHLD    FCBCRR        ;Is this top of file?
  606.     MOV    A,H
  607.     ORA    L
  608. ;
  609.     ENDIF
  610. ;
  611.     STA    TOPBUF        ;Set top of file in buffer flag
  612.     LXI    D,DSKBUF    ;load start of disk buffer
  613.     LXI    H,0        ;zero out the
  614.     SHLD    SECCNT        ;__number of sectors in buffer
  615. ;                ; Z - top, NZ - not top 
  616.     IF    SQUEEZE
  617.     LDA    SQFLG        ;Is this a squeezed file
  618.     ORA    A
  619.     JNZ    FILSQ        ;Yes -
  620.     ENDIF
  621. ;
  622. FILBU1:
  623.     PUSH    H        ;save all
  624.     PUSH    D        ;__registers from
  625.     PUSH    B        ;__BDOS clobber
  626.     MVI     C,STDMA        ;set dma to
  627.     CALL    BDOS        ;__disk buffer
  628. ;
  629.     LXI    D,FCB        ;set up to read
  630.     MVI    C,READR        ;__a record
  631.     CALL    BDOS        ;do it
  632.     ORA    A        ;read OK?
  633.     LHLD    FCBCRR        ;get current record number
  634.     INX    H        ;__bump it
  635.     SHLD    FCBCRR        ;__and save it
  636.     LHLD    SECCNT        ;get sectors in buffer
  637.     INX    H        ;bump it
  638.     SHLD    SECCNT        ;store it
  639.     POP    B
  640.     POP    D
  641.     POP    H
  642.     JNZ    RDERR        ;no, last sector read
  643. ;
  644.     IF    LIBRARY
  645. ;
  646.     PUSH    D        ;Save sector buffer pointer
  647.     LHLD    FCBCRR        ;get current record number
  648.     XCHG
  649.     LHLD    SCLAST        ;& get last sector for member (or FFFF)
  650.     CALL    cmphlde        ;Are we within member 
  651.     POP    D
  652.     JC    RDERR        ;no, last sector read
  653. ;
  654.     ENDIF
  655. ;
  656.     DCR    B        ;decrement it
  657.     RZ            ;if done return
  658.     LXI    H,128        ;else, add 128 to
  659.     DAD    D        ;__dma address
  660.     XCHG            ;put it in de
  661.     JMP    FILBU1        ;read another sector
  662. ;
  663.     IF    SQUEEZE
  664. ;
  665. ;            Fill buffer from squeezed file
  666. ;            This rtn handles mapping from unsq sector #
  667. ;            to sector, byte & bit in sq stream
  668. ;            on input FCBCRR contains wanted sector no,
  669. ;            ( no allowance made for sectors # over 65535)
  670. ;            <B> contains no of sectors wanted
  671. ;            DE> buffer where sectors wanted,
  672. ;             ignored in this version, always full DSKBUF
  673. FILSQ:
  674.     LHLD    FCBCRR        ;Get # for 1st sector wanted
  675.     XCHG
  676.     PUSH    D        ;Save to restore after unsq
  677.     LHLD    NXTSEC        ; & 1st sector after buffered ones  
  678.     CALL    cmphlde        ;Consecutive?
  679.     JZ    USQNXT        ;Yes - fine
  680.     JNC    USQBAK        ;No - lower
  681. ;            ;Next sect after latest but not consec
  682.     CALL    CDISP
  683.     DB    CR,LF,'Program failure, non-contiguous sectors requested'
  684.     DB    CR,LF,'from unsqueeze rtn',CR,LF,0
  685.     JMP    EXIT        ;Should never happen
  686. USQBAK:            ;Going backward
  687. ;
  688.     ENDIF
  689.     IF    SQUEEZE AND LIBRARY
  690. ;
  691.     LHLD    SCZERO        ;Get 1st sector for member
  692.     CALL    cmphlde        ;All the way back to start?
  693. ;
  694.     ENDIF
  695.     IF    SQUEEZE AND NOT LIBRARY
  696. ;
  697.     MOV    A,D        ;All the way?
  698.     ORA    E
  699. ;
  700.     ENDIF
  701.     IF    SQUEEZE
  702. ;
  703.     JNZ    USQNO1        ;No - MUST be prev!!!
  704.     LXI    H,SQMAP+2+8    ;Yes - reset SQMAP index to #3
  705.     SHLD    SQMAP
  706. USQNO1:
  707.     LHLD    SQMAP        ;Get index into mapping table
  708.     LXI    D,-8        ;Step back from next, past current to prev
  709.     DAD    D
  710.     SHLD    SQMAP        ; & save updated index for next
  711.     MOV    E,M        ;Get SQ sector no
  712.     INX    H
  713.     MOV    D,M
  714.     INX    H
  715.     MOV    C,M        ;Get byte offset
  716.     INX    H
  717.     MOV    A,M        ; & bit offset
  718.     STA    bitlft
  719.     XRA    A
  720.     STA    rcnt        ;No runs in progress
  721. ;                (assumption)
  722.     STA    SQBYT+1        ;Set offset 1st data byte
  723.     MOV    A,C
  724.     STA    SQBYT        ;For now offset within sector only
  725.     LHLD    SQBSC1        ;Get no of first SQ sector now in buffer
  726.     XCHG            ;<HL> wanted 1st sector, <DE> actual 1st
  727.     CALL    cmphlde        ;Is 1st buffer sector low/equal 1st data sect?
  728.     JNC    USQ1OK        ;Yes - first wanted sector SQ in buffer
  729. ;                 Max header 1035 bytes + file name)
  730. ;            Force reload of SQ buffer
  731.     SHLD    NXTSQS        ;No - 1st data sector b/4 1st buffer sect
  732. ;                 (note is probab not sector 0
  733. ;                 because of header, eg decoding tree)
  734.     MVI    A,1        ;Set rewind with I/O
  735.     STA    SQREWD        ;Set rewind flag
  736. ;                 SQBYT contains offset of 1st data byte
  737.     XRA    A
  738.     STA    SQEOF        ;Reset end of file on SQ
  739. ;                Leave current extent alone. This is how
  740. ;                BDOS knows how to switch extents. It checks
  741. ;                if the current extent no agrees with
  742. ;                the wanted record.
  743.     STA    FCBCRR+2    ; & count overflow, should not be necessary
  744.     MOV    D,A
  745.     JMP    USQNX1        ;Go adj buffer pointer
  746. ;                (NOP since <DE>=0
  747. ;            ;SQ text still in buffer
  748. USQ1OK:
  749. ;                <DE> # of 1st sector in SQ buf
  750. ;                <HL> # of wanted SQ sector 
  751. ;                (Max 100H SQ sectors in buffer)
  752.     MOV    A,L
  753.     SUB    E
  754.     RAR            ;Convert to pages (100H)
  755. ;                 Know Cy=0 in
  756. ;                 leaves Cy if odd no of sects
  757.     MOV    D,A
  758.     MVI    A,0        ;Do not disturb Cy
  759.     RAR            ;Pu carry (now 80H or 00H) 
  760. USQNX1:
  761.     MOV    E,A
  762.     LHLD    SQBYT        ;Get offset of 1st data byte in wanted sect
  763.     DAD    D        ; --> offset in buffer
  764.     LXI    D,SQBUF
  765.     DAD    D        ;Convert to absolute addr
  766.     SHLD    inbufs        ;& set as next byte to unsqueeze
  767. ;
  768. USQNXT:            ;Next sector consecutive
  769.     LHLD    NXTSQS        ;Get no of next SQ sector 
  770. ;                (in case read reqd)
  771.     SHLD    FCBCRR
  772. ;            Build mapping table entry
  773.     LHLD    inbufs        ;Calc offset in buffer
  774.     LXI    D,-SQBUF
  775.     DAD    D
  776.     MOV    C,L        ;Keep offset within sector
  777.     LDA    bitlft        ;Get bit offset
  778.     MOV    B,A
  779.     ORA    A        ;On byte boundary?
  780.     MOV    A,C
  781.     JNZ    NOTBBY        ;No -
  782.     INR    A        ;Yes - no adj reqd
  783. NOTBBY:
  784.     ANI    7FH        ;Ensure sector relative
  785.     DAD    H        ;Convert to sector no
  786.     ORA    A        ;Is next byte at start of sect?
  787.     JNZ    SECTOK
  788.     DCR    H        ;Yes - step back one sector
  789. SECTOK:
  790.     DCR    A
  791.     ANI    7FH        ;& adj byte index
  792.     MOV    E,H
  793.     MVI    D,0
  794.     LHLD    SQBSC1        ;# of 1st sector in buffer
  795.     DAD    D
  796.     XCHG            ;<D> absolute SQ sector no
  797.     LHLD    SQMAP        ;Get index
  798.     MOV    M,E        ;Save abs SQ sector no
  799.     INX    H
  800.     MOV    M,D
  801.     INX    H
  802.     MOV    M,A        ;Save sector relative byte offset
  803.     INX    H
  804.     MOV    M,B        ;Save bitlft
  805.     INX    H
  806.     SHLD    SQMAP        ;Save new index
  807. ;
  808.     ENDIF
  809.     IF    SQUEEZE AND NOT SILENT
  810. ;
  811.     CALL    CDISP        ;Show msg where is
  812.     DB    '>>> Unsqueezing text <<<',ENDMSG
  813. ;                Corrupts display if aft CR but b/4 LF
  814. ;
  815.     ENDIF
  816. ;
  817. ;
  818.     CALL    filusq        ;Fill unsq buffer
  819. ;                returns NZ on EOF
  820. ;                SQEOF set as well then
  821. ;
  822.     IF    SQUEEZE AND NOT SILENT
  823. ;
  824.     CALL    CDISP        ;Remove msg just displayed, assumes
  825. ;                 BS works across start of line if reqd
  826.     DB    BS,BS,BS,BS,BS,BS,BS,BS,BS,BS,BS,BS
  827.     DB    BS,BS,BS,BS,BS,BS,BS,BS,BS,BS,BS,BS
  828.     DB    '                        '
  829.     DB    BS,BS,BS,BS,BS,BS,BS,BS,BS,BS,BS,BS
  830.     DB    BS,BS,BS,BS,BS,BS,BS,BS,BS,BS,BS,BS,0
  831. ;
  832.     ENDIF
  833.     IF    SQUEEZE
  834. ;
  835.     LHLD    FCBCRR        ;Get no of next SQ sector
  836.     SHLD    NXTSQS
  837.     LHLD    nxtadr        ;Calc # of unsq sectors in buf
  838.     LXI    D,-DSKBUF    ;(as neg no)
  839.     DAD    D        ;Calc length
  840.     DAD    H        ; & convert to sectors in <H>
  841.     MOV    L,H
  842.     MVI    H,0
  843.     SHLD    SECCNT        ;Save # of sectors in DSKBUF
  844.     POP    D        ;Get FCBCRR as passed by calling rtn
  845.     DAD    D        ; & calc new one
  846.     SHLD    FCBCRR
  847.     SHLD    NXTSEC
  848.     RET
  849. ;
  850.     ENDIF
  851. ;
  852. ;
  853. ;We only get here if end of file
  854. ;
  855. RDERR:    MVI    A,EOF        ;get bogus eof
  856.     STAX    D        ;save at buffer end in case no eof in file
  857.     XRA    A        ;get a zero to direct to start of buffer
  858.     RET            ;__on ret
  859. ;
  860. OPNFIL:    LDA    FCBFN        ;point to first letter of filename
  861.     CPI    ' '        ;anything there?
  862.     JZ    HELP        ;no, give help message
  863.     XRA    A        ;get a 0
  864.     STA    FCBEX        ;zero current extent
  865. ;                MUST open file on extent zero
  866.     LXI    D,FCB        ;file name in default fcb
  867.     MVI    C,OPEN        ;set up to open
  868.     CALL    BDOS        ;do it
  869.     INR    A        ;open OK?
  870.     RNZ            ;yes
  871.     CALL    CDISP        ;else, give error msg and quit
  872.     DB    'file not found ',ENDMSG
  873.     JMP    EXIT1        ;leave msg on screen on exit
  874. ;
  875. GETNBR:    MOV    A,M        ;get first digit
  876.     INX    H
  877.     DCR    B        ;b=number of characters left in buffer
  878.     RZ            ;no digit
  879.     CPI    SPACE
  880.     JZ    GETNBR        ;wait until next non-space
  881.     PUSH    D        ;save location to save number
  882.     MVI    D,0        ;initialize number
  883. ;
  884. GNUM1:    SUI    30H        ;change ASCII to number
  885.     JC    INVNUM        ;not a number
  886.     CPI    10
  887.     CMC
  888.     JC    INVNUM        ;not a number
  889.     PUSH    PSW        ;save number
  890.     MOV    A,D        ;multiply old number by 10
  891.     ADD    A        ;*2
  892.     ADD    A        ;*4
  893.     ADD    A        ;*8
  894.     ADD    D        ;*9
  895.     ADD    D        ;*10
  896.     MOV    D,A
  897.     POP    PSW        ;restore new digit
  898.     ADD    D
  899.     MOV    D,A
  900.     MOV    A,M        ;get next digit
  901.     INX    H
  902.     DCR    B
  903.     JZ    ENDNUM        ;end of number
  904.     CPI    SPACE
  905.     JNZ    GNUM1
  906. ;
  907. ENDNUM:    MOV    A,D        ;save number
  908.     DCR    A        ;correct number for co routines
  909.     XCHG            ;set to restore save location
  910.     POP    H        ;restore save location
  911.     MOV    M,A        ;save digit
  912.     XCHG            ;put buffer location where it belongs
  913.     MOV    A,B        ;see if any characters left in buffer
  914.     ORA    A        ;zero if no characters in buffer
  915.     RET
  916. ;
  917. INVNUM:    POP    D        ;correct stack
  918.     RET
  919. ;
  920. ASCIIN:    MVI    B,100        ;divide by 100, then change
  921.     CALL    DIVIDE        ;__digit to ASCII and store at hl
  922.     MVI    B,10        ;divide by 10, then change
  923.     CALL    DIVIDE        ;__digit to ASCII and store at hl+1
  924.     MVI    B,30H        ;change ones place number
  925.     ADD    B        ;__to ASCII and store at hl+2
  926.     MOV    M,A
  927. ;
  928.     IF    NOT (SHORT AND HEATH)
  929.     DCX    H        ;delete leading zeroes
  930.     DCX    H        ;__in the number
  931.     MVI    C,SPACE        ;__and replace with spaces
  932.     MOV    A,B
  933.     CMP    M        ;check first digit for '0'
  934.     JNZ    CDISP        ;not zero
  935.     MOV    M,C        ;replace with space
  936.     INX    H
  937.     CMP    M        ;check second digit for '0'
  938.     JNZ    CDISP        ;not zero
  939.     MOV    M,C        ;replace with space
  940.     ENDIF
  941. ;
  942. CDISP:    XTHL            ;exchange top of stack and HL
  943. ;
  944. CDIS1:    MOV    A,M        ;HL now pointing to db message
  945.     ORA    A        ;see if 0 at end of message
  946.     INX    H
  947.     JZ    CDIS2        ;yes, restore stack and return
  948.     CALL    CO        ;no, print the character
  949.     JMP    CDIS1        ;__and loop
  950. ;
  951. CDIS2:    XTHL            ;get return address on top of stack
  952.     RET            ;__and return
  953. ;
  954. CO:    PUSH    B        ;Save the registers
  955.     PUSH    D        ;__from bdos
  956.     PUSH    H        ;__clobber
  957. CO2:    PUSH    PSW
  958.     MOV    E,A        ;set up character
  959.     MVI    C,CONOUT    ;__to send to console
  960.     CALL    BDOS        ;do it
  961.     POP    PSW
  962. CO5:    POP    H        ;restore
  963.     POP    D        ;__the registers
  964.     POP    B
  965.     RET
  966. ;
  967. CO1:    PUSH    B        ;Save the registers
  968.     PUSH    D
  969.     PUSH    H
  970.     MOV    E,A
  971.     LXI    H,CHRCNT    ;Get address of character count
  972.     CPI    CR        ;see if end of line
  973.     JZ    ENDLIN        ;update line information
  974.     CPI    LF        ;ignore linefeed
  975.     JZ    CO2
  976.     LDA    CHRMAX        ;get maximum characters per line
  977.     CMP    M        ;see if too many char
  978.     JC    CO5        ;don't print character
  979.     MOV    A,E        ;restore and print character
  980.     CPI    TAB        ;fix chrcnt for tabs
  981.     JZ    TABFIX
  982.     INR    M        ;increment character count
  983.     LDA    CHRMIN        ;see if up to minimum display yet
  984.     CMP    M
  985.     MOV    A,E        ;restore character
  986.     JNC    CO5        ;do not display character
  987.     JMP    CO2        ;finally, display character
  988. ;
  989. ENDLIN:    MVI    M,0        ;reset character count
  990.     JMP    CO2        ;print cr
  991. ;
  992. TABFIX:    MVI    A,08H        ;fix chrcnt for tabs
  993.     ADD    M        ;increment to next 8-count
  994.     ANI    0F8H        ;make into multiple of 8
  995. ;
  996. TAB2:    SUB    M        ;get number of space to go
  997.     MOV    B,A
  998. ;
  999. TAB1:    MVI    A,SPACE        ;expand tab
  1000.     CALL    CO1
  1001.     DCR    B
  1002.     JNZ    TAB1        ;still more spaces
  1003.     JMP    CO5        ;exit routine
  1004. ;
  1005. SETSCR:    PUSH    H
  1006.     PUSH    D
  1007.     PUSH    B
  1008. ;
  1009. GETMAX:    LDA    CHRMAX        ;get maximum number of characters
  1010.     INR    A
  1011.     LXI    H,HUNS
  1012.     CALL    ASCIIN        ;put ASCII number in message        
  1013. ;
  1014.     IF    NOT SHORT
  1015.     DB    CR,LF,'Maximum Column: '
  1016.     ENDIF
  1017. ;
  1018.     IF    SHORT
  1019.     DB    CR,LF,'Max Column: '
  1020.     ENDIF
  1021. ;
  1022. HUNS:    DB    30H
  1023.     DB    30H
  1024.     DB    30H
  1025.     DB    ' New? ',ENDMSG
  1026.     CALL    GETINP        ;read input from console
  1027.     LXI    D,CHRMAX    ;set new chrmax in memory
  1028.     CALL    GETNBR
  1029.     JC    GETMAX        ;if error, repeat last message
  1030. ;
  1031. GETMIN:    LDA    CHRMIN        ;get minimum character display
  1032.     INR    A
  1033.     LXI    H,HUN
  1034.     CALL    ASCIIN        ;put ASCII number in message        
  1035. ;
  1036.     IF    NOT SHORT
  1037.     DB    LF,'Minimum Column: '
  1038.     ENDIF
  1039. ;
  1040.     IF    SHORT
  1041.     DB    LF,'Min Column: '
  1042.     ENDIF
  1043. ;
  1044. HUN:    DB    30H
  1045.     DB    30H
  1046.     DB    30H
  1047.     DB    ' New? ',ENDMSG
  1048.     CALL    GETINP        ;read input from console
  1049.     LXI    D,CHRMIN    ;set new chrmax in memory
  1050.     CALL    GETNBR
  1051.     JC    GETMIN        ;if error, repeat last message
  1052. ;
  1053. GETLIN:    LDA    LINMAX        ;get number of lines per display
  1054.     LXI    H,HUND
  1055.     CALL    ASCIIN        ;put ASCII number in message        
  1056.     DB    LF,'Lines Displayed: '
  1057. ;
  1058. HUND:    DB    30H
  1059.     DB    30H
  1060.     DB    30H
  1061.     DB    ' New? ',ENDMSG
  1062.     CALL    GETINP        ;read input from console
  1063.     LXI    D,LINMAX    ;set new chrmax in memory
  1064.     CALL    GETNBR
  1065.     JC    GETLIN        ;if error, repeat last message
  1066.      POP    B
  1067.     POP    D
  1068.     POP    H
  1069. ;
  1070. WRTSAM:    LDA    LINMAX        ;write the same screen
  1071.     JMP    WRTBK0
  1072. ;
  1073. ;
  1074. GETINP:    MVI    A,5        ;get set to read new maximum column
  1075.     STA    CMDTAIL
  1076.     MVI    C,0AH
  1077.     LXI    D,CMDTAIL
  1078.     CALL    BDOS        ;get maximum column
  1079.     LXI    H,CMDTAIL+1    ;now, change to ASCII
  1080.     MOV    B,M
  1081.     INX    H
  1082.     INR    B
  1083.     RET            ;return with input in buffer
  1084. ;
  1085.     IF    NOT SHORT
  1086. ;            Adjust char min/max on cursor left/rt
  1087. ADJMM:
  1088.     PUSH    H
  1089.     CPI    ARWLFT        ;Move left (decrease)?
  1090.                 ; set flag
  1091.     LDA    CHRMAX        ;What is last char on line t/b displ
  1092.     MOV    H,A
  1093.     LDA    CHRMIN        ; & 1st char to display
  1094.     MVI    L,8        ;Scroll by 8
  1095.     JZ    ADJMMD        ;Yes - adjust down
  1096.     ADD    L        ;No - increase min, no limit
  1097.     PUSH    PSW
  1098.     MOV    A,L
  1099.     ADD    H        ; & max
  1100.     JMP    ADJMMS
  1101. ADJMMD:
  1102.     SUB    L        ;Display more to the left
  1103.     PUSH    PSW
  1104.     MOV    A,H
  1105.     SUB    L
  1106. ADJMMS:
  1107.     MOV    H,A        ;<H> max
  1108.     POP    PSW        ;<A> min
  1109.     CMP    H        ;Wrap, (max< min)
  1110.     JNC    ADJMMX        ;Yes - leave unchanged
  1111.     STA    CHRMIN
  1112.     MOV    A,H
  1113.     STA    CHRMAX
  1114. ADJMMX:
  1115.     POP    H
  1116.     JMP    WRTSAM        ;Go write same screen
  1117. ;
  1118.     ENDIF
  1119. ; 
  1120. DIVIDE:    MVI    C,'0'-1        ;extract dividend of a div c
  1121. ;
  1122. DIV1:    INR    C        ;__and store in location pointed
  1123.     SUB    B        ;__to by hl
  1124.     JNC    DIV1
  1125.     ADD    B
  1126.     MOV    M,C        ;save ASCII digit
  1127.     INX    H        ;bump pointer to next location
  1128.     RET
  1129. ;
  1130. EXITCL:
  1131. ;            Clear screen only on reg exit
  1132.     CALL    CLRSCR        ;clear the screen
  1133. ;
  1134. EXIT:
  1135.     CALL    GETIN        ;__get any waiting characters
  1136.     CALL    GETIN        ; and any possible second char
  1137. ;
  1138.     IF    HEATH
  1139.     CALL    CDISP        ;re-enable cursor
  1140.     DB    ESC,'y5',ENDMSG
  1141.     ENDIF
  1142. ;
  1143.     LXI    D,FCB        ;close file
  1144.     MVI    C,CLOSE        ;--in case this is MP/M
  1145.     CALL    BDOS
  1146. ;
  1147. EXIT1:
  1148.     LHLD    STACK        ;get old stack
  1149.     SPHL
  1150.     RET            ;return to CCP
  1151. ;
  1152.     IF    LIBRARY
  1153. ;
  1154. ;            Check for Library file
  1155. ;
  1156. CHKLB:
  1157.     xra    a
  1158.     sta    memfcb
  1159.     sta    lbflg        ;Clear library flag
  1160.     LHLD    DSKBUF        ;Get 1st word in file
  1161.     lxi    d,lbsign    ;Get expected value
  1162.     call    cmphlde
  1163.     jz    islb
  1164. ;            Not library
  1165.     lda    memnam        ;Was member specified
  1166.     ora    a
  1167.     rz            ;No - ok
  1168.     call    CDISP
  1169.     db    cr,lf,'File is not a library',cr,lf,0
  1170.     jmp    EXIT        ;Get out to leave msg visible
  1171. ;            Is library
  1172. islb:
  1173.     mvi    a,1
  1174.     sta    LBFLG        ;Yes - set library flag
  1175.     LXI    H,DSKBUF+14    ;Set to dir size (in sectors)
  1176.     mov    a,m        ;Assume <255 entries
  1177.     RAL
  1178.     RAL            ;Convert # sectors to # entries
  1179.     DCR    A        ;Less 1 for file descriptor
  1180.     sta    dirsiz        ;directory size in entries
  1181.     mov    b,a        ;Save no of entries for loop
  1182. ;            If no member specified show directory,
  1183. ;            else find the member
  1184.     LDA    MEMNAM        ;Do we have member name on command line?
  1185.     ORA    A
  1186.     JNZ    NODISP        ;Yes
  1187.     CALL    CDISP        ;Note protects <B>
  1188.     DB    CR,LF,'Library file, containing:',CR,LF,LF,0
  1189. NODISP:
  1190.     LXI    H,DSKBUF+20H    ;Set 1st member entry
  1191. ;            Loop through directory entries
  1192. dirlp:
  1193.     push    b        ;Save no of entries remaining
  1194.     MOV    A,M        ;Get entry status
  1195.     ORA    A        ;Deleted?
  1196.     JNZ    nyet        ;Yes - skp to next
  1197.     LDA    MEMNAM        ;Do we have member name on command line?
  1198.     ORA    A
  1199.     JZ    DISPM        ;No - display all member names
  1200. ;            See if wanted member
  1201.     mvi    b,12        ;Length of names + 00H in front
  1202.     lxi    d,memfcb
  1203.     call    cpstr        ;Compare names
  1204.     jz    found
  1205.     jmp    nyet
  1206. ;            Display rather than look for
  1207. DISPM:
  1208.     mvi    b,11        ;Length of names
  1209.     push    h
  1210.     inx    h        ;Step to actual name
  1211. DSPMLP:
  1212.     mov    a,m
  1213.     call    CO        ;Display one char
  1214.     inx    h
  1215.     dcr    b        ;Reduce count remaining
  1216.     jz    nmend        ;end of name
  1217. ;
  1218.     ENDIF
  1219.     IF    LIBRARY AND NOT OSBORNE
  1220. ;                (Bypass for Ozzys narrow screen)
  1221.     mov    a,b
  1222.     cpi    3        ;only 3 more?
  1223.     jnz    DSPMLP        ;No -
  1224.     mvi    a,'.'        ;Yes - put out dot
  1225.     call    CO
  1226. ;
  1227.     ENDIF
  1228.     IF    LIBRARY 
  1229.     jmp    DSPMLP        ;Go for next char
  1230. ;
  1231. ;            ;Displayed full name
  1232. nmend:
  1233. ;                In later versions multiple across
  1234.     lxi    h,namexc    ;Max no of names across sofar
  1235.     mov    a,m
  1236.     inx    h        ;Step to names across sofar
  1237.     inr    m        ;Count current
  1238.     cmp    m        ;Over max?
  1239.     jnc    notmax        ;not yet
  1240.     mvi    m,0        ;Yes - reset
  1241.     call    CDISP
  1242.     DB    CR,LF,0
  1243.     jmp    nyet1
  1244. notmax:
  1245.     call    CDISP
  1246. ;
  1247.     ENDIF
  1248.     IF    LIBRARY AND NOT OSBORNE
  1249. ;                (Bypass for Ozzys narrow screen)
  1250.     DB    ' '
  1251. ;
  1252.     ENDIF
  1253.     IF    LIBRARY
  1254. ;
  1255.     DB    '| ',0
  1256. nyet1:
  1257.     POP    H        ;Reset to start of this entry
  1258. ;            
  1259. nyet:
  1260.     lxi    b,20h        ;Length of each entry
  1261.     dad    b        ;Step to next
  1262.     pop    b        ;Get entry count (remaining)
  1263.     dcr    b
  1264.     jnz    dirlp        ;More members
  1265.     LDA    MEMNAM        ;Do we have member name on command line?
  1266.     ORA    A
  1267.     JZ    EXIT        ;No - just get out after dsp directory
  1268. ;                in future may ask what member to display
  1269.     call    CDISP
  1270.     db    cr,lf
  1271.     db    'Member file not found in LBR directory',cr,lf,0
  1272.     jmp    EXIT
  1273. ;
  1274. ;            Found the member name
  1275. ;
  1276. found:
  1277.     pop    b        ;Clear stack
  1278.     lxi    d,12
  1279.     dad    d
  1280.     push    h        ;save pointer for now,
  1281.     inx    h        ;point to size
  1282.     inx    h
  1283.     mov    a,m        ;get low byte
  1284.     inx    h
  1285.     mov    h,m
  1286.     mov    l,a
  1287.     ora    h        ;if a=0 then file is 0k
  1288.     jz    nullen        ;go complain
  1289.     xthl            ;get pointer back, save size
  1290.     mov    a,m        ;get file address
  1291.     inx    h
  1292.     mov    h,m
  1293.     mov    l,a
  1294.     SHLD    SCZERO        ;Save as first file sector
  1295.     POP    D        ; & get size back
  1296.     DAD    D        ;Convert to last sector no (inclusive)
  1297.     SHLD    SCLAST
  1298. ;
  1299.     ENDIF
  1300.     IF    LIBRARY AND SQUEEZE
  1301. ; 
  1302.     LDA    SQFLG        ;Get SQ flag in case of double squeeze
  1303.     ORA    A
  1304.     JZ    NOLBSQ        ;Ok, library itself not squeezed
  1305.     CALL    CDISP
  1306.     DB    CR,LF,'Cannot display member in squeezed library',CR,LF,0
  1307.     JMP    EXIT
  1308. NOLBSQ:
  1309.     CALL    CHKSQ        ;Check if  member squeezed
  1310. ;
  1311.     ENDIF
  1312.     IF    LIBRARY
  1313. ;
  1314.     CALL    FILBF0        ;Refill buffer, now for member
  1315. ;                 (FILBUF handles member offset in library)
  1316.     ret
  1317. ;
  1318. ;            ;Member is empty
  1319. nullen:
  1320.     CALL    CDISP
  1321.     DB    CR,LF,'Member is empty',CR,LF,0
  1322.     JMP    EXIT
  1323. ;
  1324.     ENDIF
  1325. ;
  1326. ;            Get input if any
  1327. GETIN:
  1328.     MVI    C,6        ;direct console I/O
  1329.     MVI    E,0FFH        ;__set up for input
  1330.     JMP    BDOS        ;Get char, exit via BDOS
  1331. ;
  1332. ;            Compare strings HL> to DE> over <B> 
  1333. ;            <DE> and <B> are changed, <HL> kept     
  1334. cpstr:
  1335.     push    h
  1336. cp$lp:
  1337.     ldax    d
  1338.     cmp    m
  1339.     jnz    cp$ex        ;No match
  1340.     inx    d
  1341.     inx    h
  1342.     dcr    b
  1343.     jnz    cp$lp
  1344. cp$ex:
  1345.     pop    h
  1346.     ret
  1347.  
  1348. ;
  1349. ;            Compare <HL> to <DE>
  1350. ;             Z - equal; C - <HL> less than <DE> 
  1351. ;             if equal returns <A>=0
  1352. cmphlde:
  1353.     mov    a,h
  1354.     sub    d
  1355.     rnz
  1356.     mov    a,l
  1357.     sub    e
  1358.     ret
  1359. ;
  1360. ;            Skip blanks in input
  1361. ;
  1362. EATSP:    MOV    A,M        ;get character if there is one
  1363.     INX    H
  1364.     DCR    B        ;b=number of characters left
  1365.     RZ            ;no more characters
  1366.     CPI    SPACE        ;ignore spaces
  1367.     JZ    EATSP
  1368.     DCX    H        ;Step back to 1st non-blank
  1369.     INR    B
  1370.     ORA    A        ;Force NZ
  1371.     RET
  1372. ;
  1373. ;            Skip name in input
  1374. ;
  1375. FILNAM:    MOV    A,M        ;get characters in file name
  1376.     INX    H
  1377.     DCR    B        ;b=number of characters left
  1378.     RZ            ;only file name in tail
  1379.     CPI    SPACE        ;wait for next space
  1380.     JNZ    FILNAM
  1381.     ORA    A        ;Force NZ
  1382.     RET            ;Blank
  1383. ;
  1384. ;            Move from HL> to DE> over <B>
  1385. ;
  1386. MOVE:
  1387.     MOV    A,M
  1388.     STAX    D
  1389.     INX    H        ;Step to next source
  1390.     INX    D        ; & destination
  1391.     DCR    B        ;Reduce count (00=256)
  1392.     JNZ    MOVE
  1393.     RET
  1394. ;
  1395. ;
  1396.     IF    SQUEEZE
  1397. *******************************************************
  1398. * USQ support code                      *
  1399. * 10/12/83 by Dave Rand                      *
  1400. *******************************************************
  1401. ;
  1402. ;            Check for SQ file, init tree if so
  1403. CHKSQ:
  1404. ;            Initialize
  1405.     xra    a
  1406.     mov    l,a
  1407.     mov    h,l        ;clear <hl>
  1408.     STA    SQFLG        ;Make sure not set as squeezed yet 
  1409.     sta    SQEOF        ; end of file on SQ
  1410.     sta    SQREWD        ;Clear "rewinding" SQ file 
  1411.     sta    bitlft        ;force init char read
  1412.     sta    rcnt        ;and zero repeats
  1413.     sta    FCBCRR+2    ; and overflow
  1414.     shld    numvals        ;Clear # nodes
  1415. ;
  1416.     ENDIF
  1417.     IF    SQUEEZE AND LIBRARY
  1418. ;
  1419.     LHLD    SCZERO        ;Get 1st sector for member
  1420.     SHLD    NXTSEC        ;& save as next sector
  1421. ;
  1422.     ENDIF
  1423.     IF    SQUEEZE
  1424. ;
  1425.     shld    FCBCRR        ;Clear next record
  1426. ;
  1427.     lxi    h,SQBUF        ;Set to input (squeezed) buffer 
  1428.     shld    inbufs
  1429.     shld    inbufu
  1430.     lxi    d,128
  1431.     dad    d
  1432.     shld    SQBUFE        ;Force exit on full buff aft 1 sect
  1433. ;                 causes the SQ buffer to contain
  1434. ;                 sectors 1+ only (not zero),
  1435. ;                 normally fine since sector 0 contains only
  1436. ;                 header info. Sector 0 will be reread
  1437. ;                 if contains data and needed  
  1438. ;            Read and validate signature word
  1439.     call    getw        ;Read  1st word in file
  1440.     lxi    d,sqsign    ;Get expected value
  1441.     call    cmphlde
  1442.     rnz
  1443.     mvi    a,1
  1444.     STA    SQFLG        ;Yes - set flag
  1445.     lhld    0006        ;Get top of memory
  1446.     lxi    d,sqbuf+100H*128 ;Limit buffer to max 100H
  1447.     call    cmphlde        ; sectors (FILBUF uses 8 bit count <B>)
  1448.     JC    toplow        ;use top
  1449.     xchg            ;use limit 
  1450. toplow:
  1451.     shld    SQBUFE        ;& store as full address 
  1452.     call    namlp        ;Skip past name
  1453.     call    usqtbl        ;Validate & load decoding tree
  1454.     jz    oak        ;tree ok
  1455.     call    CDISP
  1456.     db    cr,lf,'Invalid decode tree size',cr,lf,0
  1457.     jmp    EXIT
  1458. oak:
  1459.     lxi    h,SQMAP+2    ;Point to 1st entry 
  1460.     shld    SQMAP        ;Set to 1at entry in SQ mapper
  1461.     ret
  1462. ;
  1463. ;            Read & save checksum
  1464. rdchks:
  1465.     call    getw        ;get cksum, and store
  1466.     shld    filchks
  1467.     ret
  1468. ;            Read & skip name
  1469. namlp:    call    getc        ;Loop to skip name
  1470.     jnz    erext        ;I/O error or unexpected EOF
  1471.     ora    a
  1472.     jnz    namlp        ;Not yet end of name
  1473.     ret
  1474. ;
  1475. ;            Load decoding tree
  1476. ;            This version uses 1 byte abslute node indices
  1477. ;            (1-ffH) and is thus limited to 255 nodes and 255
  1478. ;            characters represented in the squeezed file.
  1479. ;            (All different characters present in the original
  1480. ;            file as well as any added through run encoding.
  1481. ;            Runs of 3 or more consecutive identical characters
  1482. ;            are encoded as char, DLE, count, where count
  1483. ;            is a one byte field 00 - FFH) 
  1484. ;
  1485. usqtbl:
  1486.      call    getw        ;Get no of nodes
  1487.     mov    a,h
  1488.     ora    l
  1489.     jz    nzexit        ;Null tree
  1490.     shld    numvals
  1491.     mov    a,h        ;Max 257, 256 char & spec eof
  1492. ;                in this version allow for only 256
  1493. ;                diff codes, every ASCII and non-ASCII
  1494. ;                char would have to be present, or
  1495. ;                run repeat counts 128-255 (every one)
  1496.     ora    a        ;H/o byte should be zero
  1497.     jnz    nzexit
  1498.     lxi    d,SQTREE    ;Set to decoding tree
  1499. nodelp:    shld    nxtadr        ;Save no of nodes
  1500.     mov    a,h
  1501.     ora    l
  1502.     rz            ;Done all nodes
  1503.     call    cvnode        ;get node, falg byte in <H>,
  1504. ;                 index/char in <L>
  1505.     push    h
  1506.     call    cvnode        ;get second child/char
  1507.     pop    b
  1508.     mov    a,b
  1509.     ral            ;Shift flags to 8, 4 posns 
  1510.     ora    h        ;Combine in 1st child flags 
  1511.     xchg            ;HL> SQTREE, <A>,<C>,<E> node 
  1512.     mov    m,a        ;Store flags in table
  1513.     inx    h
  1514.     mov    m,c
  1515.     inx    h
  1516.     mov    m,e
  1517.     inx    h
  1518.     xchg            ;DE> SQTREE
  1519.     lhld    nxtadr        ;Nodes remaining
  1520.     dcx    h
  1521.     jmp    nodelp
  1522. ;            Get encoded node
  1523. ;            Our nodes contain 3 bytes:
  1524. ;            - flag byte,
  1525. ;            - left child index/char
  1526. ;            - right child index/char
  1527. ;            Nodes on input are 4 bytes,
  1528. ;            with each half containing
  1529. ;            an index (1-100h) or character,
  1530. ;            where characters are encoded as
  1531. ;            negative values -(char+1)
  1532. ;            Eof is encoded as -(100h+1)
  1533. cvnode:
  1534.     push    d
  1535.     call    getw        ;Get word, chld ptr or char
  1536.     pop    d
  1537.     mov    a,h
  1538.     ora    a
  1539.     rz            ;Child index, <H>=0,<L>=index
  1540.     mov    a,l
  1541.     cma
  1542.     mov    l,a        ;convert char to reg form
  1543.     mov    a,h        ;get h/o byte again
  1544.     cma
  1545.     inr    a        ;Conv to 1 if char, 2 if EOF
  1546.     mov    h,a
  1547.     cpi    1        ;Was that reg char?
  1548.     rz            ;Yes - complete
  1549.     adi    3        ;No convert EOF flag to 0100
  1550.     mov    h,a
  1551.     ret
  1552.  
  1553. ;            Exit with NZ flag
  1554. nzexit:
  1555.     mvi    a,2        ;tree error
  1556.     ora    a        ;Set NZ flag
  1557.     ret
  1558.  
  1559. ;
  1560. ;
  1561. ;            Fill output buffer (unsqueezed char)
  1562. ;
  1563. filusq:
  1564.     lda    SQREWD        ;Rewinding SQ input?
  1565.     ora    a
  1566.     jz    norewd        ;No
  1567. ;            Reload SQ buffer
  1568.     lhld    inbufs
  1569.     push    h        ;getrf resets
  1570.     call    getrf        ;Yes - reload buffer & get 1st 8 bits
  1571.     pop    h
  1572.     shld    inbufs        ;Set to first data byte to use
  1573. badj:
  1574.     mov    c,a
  1575.     lda    bitlft        ;Get preset 1st wanted bit no
  1576.     mov    c,a
  1577.     mvi    a,8
  1578.     sub    b        ; Calc adjmt reqd  
  1579. badjlp:
  1580.     dcr    a
  1581.     jz    badjfn        ; bit adjust finished
  1582.     mov    b,a
  1583.     mov    a,c
  1584.     rrc
  1585.     mov    c,a
  1586.     mov    a,b
  1587.     jmp    badjlp
  1588. badjfn:
  1589.     sta    bitbuf
  1590.     xra    a
  1591.     sta    SQREWD        ; & clear rewind flag
  1592. norewd:
  1593.     lxi    h,DSKBUF    ;reset buffer pointer
  1594.     xra    a
  1595. buflp:
  1596.     shld    nxtadr        ;Save as next byte in buffer
  1597.     rnz            ;End of file (NZ flag)
  1598. ;                 as set by GETNXT rtn below
  1599.     lxi    d,SQTREE    ;Get end of input
  1600.     call    cmphlde        ;buffer full (de < hl - not full)
  1601.     jnc    full        ;buffer is full
  1602.     call    getnxt        ;Get next decoded char
  1603.                 ;No checksum taken
  1604.     lhld    nxtadr        ;Next out buffer posn
  1605.     mov    m,a        ;Store char returned, may be EOF char
  1606.     inx    h
  1607.     jmp    buflp
  1608. ;
  1609. full:
  1610.     xra    a        ;Ensure Z
  1611.     ret            ;Return on full buffer
  1612. ;
  1613. ;
  1614. ;            Get next decoded character
  1615. ;
  1616. getnxt:    lda    rcnt        ;see if in the middle of
  1617.     ora    a        ;repeat sequence...
  1618.     jz    norpt
  1619.     dcr    a        ;Yes - reduce repeat remaining 
  1620.     sta    rcnt
  1621.     lda    last        ;Get latest char again
  1622.     cmp    a
  1623.     ret            ;Return with Z for ok
  1624. norpt:    call    decode
  1625.     rnz            ;EOF? <A>=1AH
  1626.     cpi    dle        ;Run encoding flag?
  1627.     jnz    norun
  1628. ;            Handle DLE
  1629.     call    decode        ;get count
  1630.     rnz            ;EOF? (is really error after DLE)
  1631.     ora    a
  1632.     jnz    run        ;Non-zero, real run 
  1633.     mvi    a,dle        ;dle is encoded as dle,0
  1634.     cmp    a
  1635.     ret
  1636. ;            ;Run encoding found
  1637. run:    dcr    a        ;Allow for char already retnd
  1638.     dcr    a        ; & this one
  1639.     sta    rcnt        ;Keep count yet to be retd
  1640.     lda    last        ;return second time
  1641.     cmp    a
  1642.     ret
  1643. ;            ;Normal char, no run active 
  1644. norun:    sta    last        ;This may be the start
  1645.     cmp    a
  1646.     ret
  1647. ;
  1648. ;
  1649. ;            Read bits and decode to char
  1650. ;             note this version uses 3 bytes per node
  1651. ;             not 4.
  1652. ;             The first byte in each node is a flag byte
  1653. ;              .... x... - left node contains EOF marker
  1654. ;              .... .x.. - right node contains EOF marker
  1655. ;              .... ..x. - left node contains char
  1656. ;              .... ...x - right node contains char
  1657. ;
  1658. decode:    lxi    d,0        ;Set to node zero in table
  1659.     lda    bitbuf        ;Get bits from bit buffer
  1660.     mov    c,a
  1661. bitlp:    lda    bitlft        ;Any bits remaining? 
  1662.     ora    a
  1663.     jnz    nxtbit        ;Yes - go use
  1664.     push    d
  1665.     call    getc        ;No - replenish bit buffer
  1666.     jnz    badr        ;Unexpected eof
  1667.     pop    d
  1668.     mov    c,a
  1669.     mvi    a,8        ;Set as 8 bits inbuffer 
  1670. nxtbit:    dcr    a
  1671.     sta    bitlft        ;Save no of bit remaining 
  1672.     lxi    h,SQTREE    ;Set to node 0, left child ptr
  1673.     dad    d
  1674.     dad    d
  1675.     dad    d        ;Add in node no (4 bytes/node)
  1676.     mov    b,m        ;Get flag byte
  1677.     inx    h        ;Step to left child pointer
  1678.     mov    a,c        ;Get input bits 
  1679.     rrc            ;Shuffle LOW-ORDER bit to Carry
  1680.     mov    c,a
  1681.     mov    a,b        ;Get flag byte 
  1682.     jnc    getn3        ;Zero input bit,leave at left
  1683.     inx    h        ;add 1 to point to right child pointer
  1684.     add    b        ;Normalize wanted flags to .... x.x.
  1685. getn3:
  1686.     mov    e,m        ;Pick up child or char
  1687. ;                <D> should always remain zero 
  1688.     ani    1010B        ;Mask unwanted bits
  1689.     jz    bitlp        ;Reg child pointer
  1690. ;            Got to char or eof
  1691.     ani    1000B        ;End of file marker?
  1692.     jnz    goteof        ;Yes - get out with eof
  1693.     mov    a,c
  1694.     sta    bitbuf        ;Save bit buffer
  1695.     mov    a,e        ;Get decoded char (neg)
  1696.     ret
  1697. ;
  1698. ;            Exit on reg eof
  1699. goteof:
  1700.     mvi    a,eof
  1701.     ora    a
  1702.     ret
  1703. ;
  1704. ;            ;Get input word (lo/hi, unencoded)
  1705. getw:    call    getc
  1706.     jnz    badr        ;Unexpected eof
  1707.     push    psw
  1708.     call    getc
  1709.     jnz    badr        ;Unexpected eof
  1710.     mov    h,a
  1711.     pop    psw
  1712.     mov    l,a
  1713.     ret
  1714. ;
  1715. erext:
  1716. badr:    call    CDISP
  1717.     db    cr,lf,'Unexpected EOF',cr,lf,0
  1718.     jmp    EXIT
  1719. ;
  1720. ;            Get single (unencoded) char
  1721. getc:    lhld    inbufu
  1722.     xchg
  1723.     lhld    inbufs
  1724.     call    cmphlde        ;End of input buffer?
  1725.     jz    getrf        ;Yes
  1726. getc1:
  1727.     mov    a,m        ;No get next byte
  1728.     inx    h
  1729.     shld    inbufs        ;Save addr of next byte
  1730.     cmp    a
  1731.     ret
  1732. ;
  1733. ;            Refill input buffer
  1734. ;
  1735. getrf:
  1736.     lda    SQEOF        ;Is there anything else?
  1737.     ora    a
  1738.     jz    getok
  1739.     call    CDISP
  1740.     db    cr,lf,'Read past EOF on SQ file',cr,lf,0
  1741.     jmp    EXIT
  1742. getok:
  1743.     lhld    SECCNT        ;Save sector count (decoded buffer only)
  1744.     push    h
  1745.     lxi    h,SQBUF        ;Set input buffer as empty,
  1746.     shld    inbufs        ;_and start of buffer
  1747.     xchg            ;DE> buffer, next sector locn
  1748.     lhld    SQBUFE        ;End of input buffer
  1749.     shld    inbufu        ;Assume no end of file for now
  1750.     mov    a,l
  1751.     sub    e
  1752.     mov    l,a
  1753.     mov    a,h
  1754.     sbb    d        ;Calc buffer size
  1755.     mov    h,a
  1756.     dad    h        ;Convert to no of sectors
  1757.     mov    b,h        ;No of sectors to read
  1758. ;                # sectors limited to 100 max (<B>=0)
  1759.     lhld    FCBCRR        ;No of 1st sector to read
  1760.     shld    SQBSC1
  1761.     call    FILBU1        ;Read sector into SQBUF
  1762. ;                <B> no of sectors not read if eof
  1763. ;                HL> 128
  1764. ;                DE> last sector read, or after if eof
  1765.     lhld    FCBCRR        ;Get next SQ sector no
  1766.     shld    NXTSQS
  1767.     mov    a,b        ;Did we fill buffer?
  1768.     ora    a
  1769.     jz    getrf2        ;yes - no eof
  1770.     xchg            ;Eof, adjust buffer end marker
  1771.     shld    inbufu        ;Mark end of buffer used
  1772.     sta    SQEOF        ;& flag eof
  1773. ;
  1774. ;            Input buffer re-filled
  1775. getrf2:
  1776.     pop    h
  1777.     shld    SECCNT        ;Restore sector count (decoded buffer only)
  1778.     lhld    inbufu        ;Get end of buffer
  1779.     xchg
  1780.     lhld    inbufs        ;Get start of buffer
  1781.     call    cmphlde        ;Something there?
  1782.     jc    getc1        ;Yes - go for char
  1783.     jmp    erext        ;No - read past eof or empty file
  1784. ;
  1785. ;end of baseline USQ code
  1786. ;
  1787. otbufe:    dw    0        ;End of decoded char buffer
  1788. inbufs:    dw    0        ;Start of input buffer
  1789. inbufu:    dw    0        ;End of used part input buffer
  1790. SQBUFE:    dw    0        ;End of input buffer
  1791. ;
  1792. nxtadr:    dw    DSKBUF        ;Next byte in output buffer 
  1793.                 ; also used when loading tree
  1794. bitlft:    ds    1        ;No of bits left in bit buffer
  1795. rcnt:    ds    1        ;Run count remaining (DLE)
  1796. filchks:ds    2        ;Checksum read from file
  1797. last:    ds    1        ;Last reg char decoded
  1798. bitbuf:    ds    1        ;Latest 8 bits (encoded) from input file
  1799. numvals:ds    2        ;No of nodes in encodng tree
  1800. ;
  1801.     ENDIF
  1802. ;
  1803. ;    Memory allocation
  1804. ;
  1805. SECCNT:    DW    0        ;number of sectors read into buffer
  1806. LINMAX:    DB    SCROLN        ;number of to write lines on console
  1807. CHRMAX:    DB    MAXCHR-1    ;number of characters to display per line
  1808. CHRMIN:    DB    0        ;character to start displaying on line
  1809. CHRCNT:    DS    1        ;character number in line
  1810. LINCNT:    DS    1        ;line number on write or move back in buffer
  1811. TOPBUF:    DB    0        ;Top of file is now in buffer
  1812. ;                 Z - yes, NZ - no
  1813. ;
  1814.     IF    SQUEEZE
  1815. ;
  1816. NXTSEC:    DW    0        ;Next (unsqueezed) sector not yet in BSKBUF
  1817. ;                 set (and used) only by FILSQ
  1818. SQFLG:    DB    0        ;File is squeezed
  1819. SQEOF:    DB    0        ;End of file on squeezed file
  1820. SQREWD:    DB    0        ;Flag the SQ input file is being re-read
  1821. ;                 buffer refill rtn (getrf) to set inbufs
  1822. ;                 as per offset in SQBYT, and pre-load
  1823. ;                 bit buffer. Bit buffer to be adj
  1824. ;                 as per Bitlft
  1825. SQBYT:    DW    0        ;Offset of first data byte in SQ buffer
  1826. SQBSC1:    DW    0        ;No of 1st sector in SQ buffer
  1827. NXTSQS:    DW    0        ;No of last sector in SQ buffer
  1828. ;
  1829.     ENDIF
  1830. ;
  1831. ;
  1832.     IF    LIBRARY
  1833. namexc:    db    (MAXCHR/11)-1    ;No of directory names across display
  1834.     db    0        ;No of names so far
  1835. dirsiz:    db    0        ;# of members possible in directory
  1836. memnam    db    0        ;Member name specified on command line
  1837. SCZERO:    DW    0        ;First sector for member
  1838. SCLAST:    DW    0FFFFH        ;Last sector for member (included in member)
  1839. ;                 SCZERO and SCLAST are relative in file
  1840. LBFLG:    DB    0        ;File is a library file
  1841. memfcb:    ds    12        ;Name of member file
  1842. ;
  1843.     ENDIF
  1844.     DS    60        ;stack area
  1845. STACK:    DS    2        ;old stack saved here
  1846. DSKBUF:    EQU    $        ;disk buffer area above the program
  1847. ;
  1848. ENDBUF    EQU    DSKBUF+MAXSEC*128
  1849. ;
  1850.     IF    SQUEEZE
  1851. ;
  1852. SQTREE    EQU    ENDBUF        ;Space for SQ decoding tree
  1853. SQMAP    EQU    SQTREE+256*3
  1854. ;                Space for SQ buffer mapping table
  1855. ;                contains sq sect #, sq byte & bit offset
  1856. ;                for every time DSKBUF was filled
  1857. ;                1st entry contains index to latest mapping
  1858. ;                triplet
  1859. ;                To handle run compr straddling buffer end,
  1860. ;                should also store rcnt & last 
  1861. SQBUF    EQU    SQMAP+100*4    ;(allows for 100 8k buffers)
  1862. ;                Input (squeezed) buffer
  1863. ;                Runs up to top of free mem 
  1864.     ENDIF
  1865. ;
  1866.     END    TPA
  1867.