home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / sigm / vols100 / vol156 / xmr2-1.asm < prev   
Encoding:
Assembly Source File  |  1994-07-13  |  8.3 KB  |  246 lines
  1.  
  2. ; XMR2-1.ASM - XMODEMxx PATCH FILE FOR TRS-80 2/12/16/16B     12/02/83
  3. ;
  4. ;------------------------------------------------------------------------
  5. ; 12/02/83    Adapted for Z80 SIO, CTC as used in TRS-80 2/12/16/16B
  6. ; XMR2-1.ASM                    - Herb Robinson
  7. ;------------------------------------------------------------------------
  8. ;
  9. ; This file adapts XMODEMxx to an external modem.  This particular setup
  10. ; uses Z-80 SIO and CTC chips.    To use, first edit any options desired into
  11. ; XMODEMxx.ASM, then assemble (can use ASM.COM) and load which supplies
  12. ; XMODEMxx.COM.  Then edit this file as needed (check the CONOUT routine
  13. ; if you want to locally see file transfer time and the record count
  14. ; while programs are being sent).  Then assemble (can use ASM.COM) and
  15. ; merge via DDT or SID:
  16. ;
  17. ;    B>DDT XMODEMxx.COM
  18. ;    DDT VERS 2.2
  19. ;    NEXT  PC
  20. ;    1180 0100
  21. ;    -IXMR2-1.HEX        (note the 'I' command)
  22. ;    -R            ('R' loads in the .HEX file)
  23. ;    NEXT  PC
  24. ;    1180 0000
  25. ;    -G0            (return to CP/M)
  26. ;    B>SAVE 16 XMODEMxx.COM    (now have a modified .COM file)
  27. ;
  28. ; NOTE: Save 21 (rather than 16) if LOGCAL is YES
  29. ;
  30. ;=======================================================================
  31. ;
  32. ; 12/02/83 - Renamed to XMR2-1.ASM    - Herb Robinson
  33. ; 11/17/83 - Renamed to XMEX-1.ASM    - Irv Hoff
  34. ; 10/22/83 - Updated to XMODEM77    - Irv Hoff
  35. ; 04/04/83 - Updated to XMODEM74    - Irv Hoff
  36. ; 03/27/83 - Updated to XMODEM73    - Irv Hoff
  37. ; 03/17/83 - Updated to XMODEM72    - Irv Hoff
  38. ; 03/15/83 - Updated to XMODEM71    - Irv Hoff
  39. ;
  40. ; 03/07/83  Added instructions on how to adapt this file to XMODEM70.COM.
  41. ;        Standardized the format.  Added automatic MSPEED from "BYE"
  42. ;        program.  Added CONOUT information.  Adapted from XM70PMMI.
  43. ;                    - Irv Hoff
  44. ;
  45. ;=======================================================================
  46. ; 
  47. YES:    EQU    0FFH
  48. NO:    EQU    0
  49. ;
  50. ;=======================================================================
  51. ;
  52. MODDATP: EQU    0F4H        ;data in port
  53. MODDATO: EQU    MODDATP     ;data out port
  54. MODCTLP: EQU    MODDATP+2    ;control/status port
  55. MODSNDB: EQU    04H        ;bit to test for send
  56. MODSNDR: EQU    04H        ;value when ready
  57. MODRCVB: EQU    01H        ;bit to test for receive
  58. MODRCVR: EQU    01H        ;value when ready
  59. ;
  60. RESSTA:  EQU    00010000b    ;Reset ext/status
  61. ;
  62. MODDCDB: EQU    00001000b    ;carrier detect bit
  63. MODDCDA: EQU    00001000b    ;value when active
  64. MODPARE: EQU    00010000b    ;value for parity error
  65. MODOVRE: EQU    00100000b    ;value for overrun error
  66. MODFRME: EQU    01000000b    ;value for framing error
  67. ;
  68.  
  69. LSPEED: EQU    YES        ;yes if using 'BYE' with speed selection
  70.                 ;no if using 'SPEED' manual selection
  71. MSPEED: EQU    3CH        ;location of baud rate factor (set by
  72.                 ;'BYE')  set location in 'BYE' to agree.
  73.                 ;3dh and 3eh often used by newer ver-
  74.                 ;sions of 'ZCPR'.
  75. XSPEED: EQU    5        ;speed for file time transfer without
  76.                 ;auto-set.  use one of the following:
  77.                 ;0=110 1=300 2=450 3=600 4=710 5=1200
  78. BASE:    EQU    100H        ;start of cp/m normal program area
  79. ;
  80. ;-------------------------------------------------------------------
  81. ;
  82. ; Jump table: The jump table must be in exactly the same sequence as the
  83. ; one in XMODEM.  Note the ORG of 103H - This jump table has no jump to
  84. ; 'BEGIN'.
  85.  
  86. ;
  87.      ORG    BASE+3        ;start after 'JMP BEGIN'
  88. ;
  89. CONOUT:  JMP    00000H        ;must be 00000h if not used, see below
  90. PMINIT:  JMP    MINIT        ;initialization routine (if needed)
  91. PUNINIT: JMP    UNINIT        ;undo whatever 'MINIT' did (or return)
  92. PSENDR:  JMP    SENDR        ;send character (via pop psw)
  93. PCAROK:  JMP    CAROK        ;test for carrier
  94. PMDIN:     JMP    MDIN        ;receive data byte
  95. PGETCHR: JMP    GETCHR        ;get character from modem
  96. PRCVRDY: JMP    RCVRDY        ;check receive ready
  97. PSNDRDY: JMP    SNDRDY        ;check send ready
  98. PSPEED:  JMP    SPEED        ;get speed value for file transfer time
  99. PEXTRA1: JMP    EXTRA1        ;extra for custom routine
  100. PEXTRA2: JMP    EXTRA2        ;extra for custom routine
  101. PEXTRA3: JMP    EXTRA3        ;extra for custom routine
  102. ;
  103. ;=======================================================================
  104. ;
  105. ; -- To Display the Record Count on the CRT During Program Transfers --
  106. ;    
  107. ;    This one addition requires some work on the part of the user.
  108. ; When "BYE" is added, CP/M is normally moved lower to accomodate the
  109. ; new program above CP/M.  Whenever BYE is called to enable the RCPM
  110. ; capability, it steals some of the addresses contained in the BIOS jump
  111. ; vector table.  In order to display on the CRT during program transfers
  112. ; you need to get into the BIOS console output routine directly, else
  113. ; what is being displayed also tries to go out the modem.  This is a big
  114. ; NO-NO at that time.  (This cannot be done automatically by XMODEM,
  115. ; since BYE has already taken the address we need to find, by the time
  116. ; XMODEM is automatically activated by the remote station.)
  117. ;
  118. ;    So with the disk containing BYE, but prior to activating BYE, do
  119. ; this:
  120. ;        1) Cold reboot to move CP/M (and BIOS) to the new area
  121. ;            needed when BYE is activated on the same disk.
  122. ;        2) Use DDT and dump the area from 0000H to 0002H.  This
  123. ;            gives the warm reboot address in BIOS.
  124. ;        3) Add 9 Bytes to that address to get your console out-
  125. ;             put jump vector.
  126. ;        4) Pick off the address contained in the jump vector and
  127. ;             install that in "CONOUT", below.  Example of one
  128. ;             system in use:
  129. ;
  130. ;            FIRST, COLD REBOOT WITH DISK CONTAINING "BYE"
  131. ;
  132. ;      0000    C3 03 E0    (location of warm reboot on disk with BYE
  133. ;
  134. ;            PRIOR TO ACTIVATING BYE BUT ON SAME DISK
  135. ;
  136. ;      E003    C3 E9 E0    (BIOS warm reboot jump vector on this disk)
  137. ;      E006    C3 00 E9    (BIOS get console status routine)
  138. ;      E009    C3 B7 E1    (BIOS console input routine)
  139. ;      E00C    C3 D4 E1    (BIOS console output routine)
  140. ;
  141. ;        The address we need is thus E1D4.  Put that below, in
  142. ;        our example it would be:    CONOUT   JMP   0E1D4H
  143. ;
  144. ;
  145. ;    CONOUT:   JMP    00000H    ;If you wish to show the record count
  146. ;                ;during program transfer, fill in this
  147. ;                ;address at 'CONOUT' above.
  148. ;
  149. ;                    - Irv Hoff
  150. ;
  151. ;=======================================================================
  152. ;
  153. ; ---> CAROK - check for presence of carrier.  RET with Z = carrier on
  154. ;
  155. CAROK:    MVI    A,RESSTA
  156.     OUT    MODCTLP
  157.     IN    MODCTLP     ;get status
  158.     ANI    MODDCDB     ;get carrier detect bit
  159.     CPI    MODDCDA     ;test bit
  160.     RET
  161. ;
  162. ;=======================================================================
  163. ;
  164. EXTRA1: RET            ;for later use
  165. EXTRA2: RET            ;for later use
  166. EXTRA3: RET            ;for later use
  167. ;
  168. ;=======================================================================
  169. ;
  170. ; ---> GETCHR - get a character, same as MDIN
  171. ; ---> MDIN - - get a character, same as GETCHR
  172. ;
  173. GETCHR:
  174. MDIN:    IN    MODDATP     ;get character from data in port
  175.     RET
  176. ;
  177. ;=======================================================================
  178. ;
  179. MINIT:    RET            ;no initialization required
  180. ;
  181. ;=======================================================================
  182. ;
  183. ; ---> RCVRDY - check receive ready.  RET with Z = character available.
  184. ;        Return with error code in A-reg.
  185. ;
  186. RCVRDY: MVI    A,10H
  187.     OUT    MODCTLP
  188.     IN    MODCTLP
  189.     PUSH    B        ;save scratch register
  190.     PUSH    PSW        ;stack read reg 0
  191.     MVI    A,01H
  192.     OUT    MODCTLP
  193.     IN    MODCTLP     ;get read reg 1
  194.     ANI    MODFRME+MODOVRE+MODPARE
  195.     MOV    B,A        ;save it for a moment
  196.     POP    PSW
  197.     ANI    MODRCVB     ;isolate ready bit
  198.     CPI    MODRCVR     ;test it
  199.     MOV    A,B        ;get the error code char. back
  200.     POP    B
  201.     RET
  202. ;
  203. ;=======================================================================
  204. ;
  205. ; ---> SENDR - send character
  206. ;
  207. SENDR:    POP    PSW        ;get the character back
  208.     OUT    MODDATO     ;send it to the modem output
  209.     RET
  210. ;
  211. ;=======================================================================
  212. ;
  213. ; ---> SNDRDY - check if ready to send.
  214. ;
  215. SNDRDY: MVI    A,10H        ;select read reg 0
  216.     OUT    MODCTLP
  217.     IN    MODCTLP     ;get status byte
  218.     ANI    MODSNDB     ;isolate ready bit
  219.     CPI    MODSNDR     ;ready to send?
  220.     RET
  221. ;
  222. ;=======================================================================
  223. ;
  224. ; ---> SPEED - sets the time shown for program transfer.
  225. ;
  226. SPEED:     IF    LSPEED
  227.     LDA    MSPEED        ;get index for baud rate from 'BYE'
  228.      ENDIF
  229. ;
  230.      IF    NOT LSPEED
  231.     MVI    A,XSPEED    ;get index for baud rate from 'XSPEED'
  232.      ENDIF
  233. ;
  234.     RET
  235. ;
  236. ;=======================================================================
  237. ;
  238. UNINIT: RET            ;not initialized, so no 'UN-INITIALIZE'
  239. ;
  240. ;=======================================================================
  241. ;
  242. ;
  243.             ;not initialized, so no 'UN-INITIALIZE'
  244. ;
  245. ;=======================================================================
  246. ;