home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / sigm / vols000 / vol096 / findbad.a86 < prev    next >
Encoding:
Text File  |  1984-04-29  |  31.3 KB  |  1,153 lines
  1.     TITLE    'FINDBAD Ver 1.0 - Universal Version for CP/M-86'
  2. ;
  3. ;            FINDBAD.A86 Ver. 1.0
  4. ;
  5. ;    Modified for CP/M-86 from FINDBAD52.ASM of 02/16/82
  6. ;
  7. ;FINDBAD will find all bad blocks on a disk and build a file
  8. ;named [UNUSED].BAD to allocate them, thus "locking out" the
  9. ;bad blocks so CP/M-86 will not use them.
  10. ;
  11. ;Originally written by Gene Cotton,  published in "Interface
  12. ;Age", September 1980 issue, page 80.
  13. ;
  14. ;               SYSTST and BADUSR options:
  15. ;
  16. ;  Many double-density disk systems have single-density system 
  17. ;tracks.  If this is true with your system, you can change the 
  18. ;program to skip the system tracks,  without re-assembling it.  
  19. ;To do this, set the byte at 103H to a 0 if you don't want the 
  20. ;system  tracks tested,  otherwise leave it 0.   This is  also 
  21. ;necessary if you have a "blocked" disk system;  that is, when 
  22. ;the same physical disk is seperated into logical disks by use 
  23. ;of the SYSTRK word in the disk parameter block.
  24. ;
  25. ;   If  you  are a CP/M-86 1.x user,  you may assign the  user 
  26. ;number  where  [UNUSED.BAD] will be created by  changing  the  
  27. ;byte  at 104H  to  the  desired user number.   If you want it  
  28. ;in  the default user,  then leave it 0FFH.
  29. ;
  30. ;
  31. ;-------------------------------------------------------------
  32. ;NOTE: If you want to  update this program, make sure you have 
  33. ;the latest version first.   After adding your changes, please 
  34. ;modem  a  copy of the new file to CP/M-NET  in  Simi  Valley, 
  35. ;California - phone (805) 527-9321 (50,  110,  300, 450 or 600 
  36. ;baud). Use the filename FNDBDA86.NEW. (K. Smith)
  37. ;
  38. ;Modifications/updates:
  39. ;
  40. ;02/03/82  Changed to CP/M-86 compatibility with the help  of 
  41. ;          DR's XLT86 utility, made changes for goofs made by 
  42. ;           XLT86,  removed ANYTHING to do with CP/M-80  Ver. 
  43. ;          1.4. (K. Smith, CP/M-Net 'SYSOP')
  44. ; 
  45. ;         Note: You must assemble with ASM86.CMD as follows:
  46. ;
  47. ;               ASM86 FINDBAD<cr>
  48. ;
  49. ;               Then create a '.CMD' as,
  50. ;
  51. ;               GENCMD FINDBAD 8080<cr>
  52. ;
  53. ;04/10/81 Changed extent DB from -1 to 0FFH so program can be
  54. ;      assembled by ASM.  Added BADUSR info to instructions
  55. ;      for altering with DDT.  (KBP)
  56. ;
  57. ;04/09/81 Changed sign-on message, added control-c abort test,
  58. ;      added '*' to console once each track    (RGF)
  59. ;
  60. ;04/07/81 Re-wrote to add the following features:
  61. ;        1) "universal" operation
  62. ;        2) DDT-changeable "SYSTRK" boolean (see above)
  63. ;        3) Report to console when bad blocks are detected
  64. ;        4) Changed the method of printing the number of
  65. ;           bad blocks found (at end of run)...the old
  66. ;           method used too much code, and was too cum-
  67. ;           bersome.
  68. ;        5) Made several cosmetic changes
  69. ;
  70. ;            Ron Fowler
  71. ;            Westland, Mich
  72. ;
  73. ;03/23/81 Set equates to standard drive and not double-sided. (KBP)
  74. ;
  75. ;03/01/81 Corrected error for a Horizon with double sided drive.
  76. ;      This uses 32k extents, which code did not take into account.
  77. ;      (Bob Clyne)
  78. ;
  79. ;02/05/81 Merged 2/2/81 and 1/24/81 changes, which were done
  80. ;      independently by Clyne and Mack.  (KBP)
  81. ;
  82. ;02/02/81 Added equates for North Star Horizon - 5.25" drives,
  83. ;      double density, single and double sided. (Bob Clyne)
  84. ;
  85. ;01/24/81 Added equates for Jade DD disk controller
  86. ;      (Pete H. Mack)
  87. ;
  88. ;01/19/81 Added equates for Icom Microfloppy 5.25" drives.
  89. ;      (Eddie Currie)
  90. ;
  91. ;01/05/81 Added equates for Heath H-17 5.25" drives.
  92. ;      (Ben Goldfarb)
  93. ;
  94. ;12/08/80 Added equates for National Multiplex D3S/D4S
  95. ;      double-density board in various formats.
  96. ;      (David Fiedler)
  97. ;
  98. ;09/22/80 Added equates for Morrow Disk Jockey 2D/SS, 256,
  99. ;      512 and 1024-byte sector options.  Fix 'S2' update
  100. ;      flag for larger max number of extents. Cleaned up
  101. ;      file. (Ben Bronson and KBP)
  102. ;
  103. ;09/14/80 Corrected DGROUP equate for MMDBL. Added new routine
  104. ;      to correct for IMDOS group allocation.  Corrected
  105. ;      error in instructions for using TEST routine.
  106. ;      (CHS) (AJ) (KBP) - (a group effort)
  107. ;
  108. ;09/08/80 Fixed several errors in Al Jewer's mods.  Changed
  109. ;      return to CP/M to warm boot so bitmap in memory will
  110. ;      be properly updated. Added conditional assembly for
  111. ;      testing program. (KBP)
  112. ;
  113. ;09/02/80 Added IMDOS double-density equates & modified for 
  114. ;      more then 256 blocks per disk. (Al Jewer)
  115. ;
  116. ;09/01/80 Changed equates so that parameters are automatically
  117. ;      set for each disk system conditional assembly (KBP)
  118. ;
  119. ;08/31/80 Add conditional assembly for Digital Microsystems FDC3
  120. ;      controller board in double-density format and fix to
  121. ;      do 256 blocks in one register. (Thomas V. Churbuck)
  122. ;
  123. ;08/31/80 Correct MAXB equate - MAXB must include the directory
  124. ;      blocks as well as the data blocks.  Fix to make sure
  125. ;      any [UNUSED].BAD file is erased before data area is
  126. ;      checked. (KBP)
  127. ;
  128. ;08/30/80 Added conditional assembly for Micromation
  129. ;      double-density format. (Charles H. Strom)
  130. ;
  131. ;08/27/80 Fix missing conditional assembly in FINDB routine.
  132. ;      Put version number in sign-on message. (KBP)
  133. ;
  134. ;08/26/80 Modified by Keith Petersen, W8SDZ, to:
  135. ;      (1) Add conditional assembly for 1k/2k groups
  136. ;      (2) Add conditional assembly for standard drives
  137. ;          and Micropolis MOD II
  138. ;      (3) Make compatible with CP/M-2.x
  139. ;      (4) Remove unneeded code to check for drive name
  140. ;          (CP/M does it for you and returns it in the FCB)
  141. ;      (5) Changed to open additional extents as needed for
  142. ;          overflow, instead of additional files
  143. ;      (6) Add conditional assembly for system tracks check
  144. ;          (some double-density disks have single-density
  145. ;          system tracks which cannot be read by this program)
  146. ;      (7) Increased stack area (some systems use more than
  147. ;          others).
  148. ;
  149. ;08/06/80 Added comments and crunched some code.
  150. ;      KELLY SMITH.    805-527-9321 (Modem, 300 Baud)
  151. ;            805-527-0518 (Verbal)
  152. ;
  153. ;
  154. ;            Using the Program
  155. ;
  156. ; Before  using this program to "reclaim" a diskette,  it  is
  157. ;recommended that the diskette be reformatted. If this is not
  158. ;possible,  at least assure yourself that any existing    files
  159. ;on the diskette  do not contain unreadable  sectors.  If you
  160. ;have changed disks since the last warm-boot, you  must warm-
  161. ;boot again before running this program.
  162. ;
  163. ; To  use the program,    insert    both the disk containing  the
  164. ;program  FINDBAD.CMD and the diskette to be checked into the
  165. ;disk drives. It is possible that the diskette containing the
  166. ;program is the one to be checked. Assume that the program is
  167. ;on drive "A" and the suspected bad disk is on drive "B".  In
  168. ;response to the CP/M prompt "A>",  type in FINDBAD B:.  This
  169. ;will  load the file FINDBAD.CMD from drive "A" and test  the
  170. ;diskette  on  drive "B" for  unreadable  sectors.  The  only
  171. ;allowable  parameter  after  the  program name  is  a    drive
  172. ;specification    (of the form " N:") for up to four (A  to  D)
  173. ;disk drives.  If no drive is specified, the currently logged
  174. ;in drive is assumed to contain the diskette to check.
  175. ;
  176. ; The  program first checks the CP/M System tracks (0 and 1),
  177. ;and  any  errors here prohibit the disk from being  used  on
  178. ;drive    "A",  since all "warm  boots" occur using the  system
  179. ;tracks from the "A" drive.
  180. ;
  181. ; The  program next checks the first two data blocks  (groups
  182. ;to some of us) containing the directory of the diskette.  If
  183. ;errors  occur    here,  the  program  terminates  and  control
  184. ;returns  to  CP/M  (no other data blocks are  checked    since
  185. ;errors in the directory render the disk useless).
  186. ;
  187. ; Finally,  all  the remaining data blocks are    checked.  Any
  188. ;sectors  which  are  unreadable cause the data  block    which
  189. ;contains them to be stored temporarily as a "bad block".  At
  190. ;the end of this phase,  the message "XX bad blocks found" is
  191. ;displayed (where XX is replaced by the number of bad blocks,
  192. ;or "No" if no read errors occur).  If bad blocks occur,  the
  193. ;filname [UNUSED].BAD is created, the list of "bad blocks" is
  194. ;placed  in  the allocation map of the    directory  entry  for
  195. ;[UNUSED].BAD,    and the file is closed.  Note,    that when the
  196. ;number of "bad blocks" exceeds 16,  the  program  will  open
  197. ;additional  extents  as  required  to    hold the overflow.  I
  198. ;suggest that if the diskette has more than  32 "bad blocks",
  199. ;perhaps it should be sent to the "big disk drive in the sky"
  200. ;for the rest it deserves.
  201. ;
  202. ; The  nifty part of all this is that if any "bad blocks"  do
  203. ;occur, they are allocated to [UNUSED].BAD and no longer will
  204. ;be available to CP/M-86 for future allocation... bad sectors
  205. ;are logically locked out on the diskette
  206. ;
  207. ;
  208. ;           Using the TEST conditional assembly
  209. ;
  210. ;A  conditional  assembly has been added to allow  testing  this 
  211. ;program  to  make sure it is reading all sectors on  your  disk 
  212. ;that  are accessible to CP/M.    The program reads the disk on  a 
  213. ;block by block basis, so it is necessary to first determine the 
  214. ;number of blocks present.  To start, we must know the number of 
  215. ;sectors/block (8 sectors/block for standard IBM single  density 
  216. ;format).  If  this  value  is    not  known,  it  can  easily  be 
  217. ;determined  by saving one page in a test file and interrogating 
  218. ;using the STAT command:
  219. ;
  220. ;For standard single-density STAT will report this file as being
  221. ;1k.  The file size reported (in bytes) is the size of a  block. 
  222. ;This  value  divided  by 128 bytes/sector  (the  standard  CP/M 
  223. ;sector  size)    will  give sectors/block.  For    our  IBM  single 
  224. ;density example, we have:
  225. ;
  226. ;  (1024 bytes/block) / (128 bytes/sector) = 8 sectors/block.
  227. ;
  228. ;We  can now calculate blocks/track (assuming we know the number 
  229. ;sectors/track). In our example:
  230. ;
  231. ;  (26 sectors/track) / (8 sectors/block) = 3.25 blocks/track
  232. ;
  233. ;Now  armed with the total number of data tracks (75 in our  IBM 
  234. ;single density example), we get total blocks accessible: 
  235. ;
  236. ;  75 (tracks/disk) x (3.25 blocks/track) = 243.75 blocks/disk 
  237. ;
  238. ;CP/M cannot access a fractional block, so we round down (to 243 
  239. ;blocks  in  our  example).  Now  multiplying  total  blocks  by 
  240. ;sectors/block    results in total sectors as should  be    reported 
  241. ;when TEST is set TRUE and a good disk is read. For our example, 
  242. ;this value is 1944 sectors. 
  243. ;
  244. ;Finally,  note that if SYSTEM is set TRUE,  the sectors present 
  245. ;on  the  first  two tracks must be added in  as  well.  In  the 
  246. ;previous  example,  this  results in  1944 + 52 = 1996  sectors 
  247. ;reported by the TEST conditional.
  248. ;
  249. ;Run the program on a KNOWN-GOOD disk.    It should report that it
  250. ;has read  the    correct number of sectors.  The test conditional
  251. ;assembly should then be set FALSE and the program re-assembled.
  252. ;The test routines  cannot be left in  because this program does
  253. ;not read all the sectors in a block that is found to be bad and
  254. ;thus will report an inaccurate number of sectors read.
  255. ;
  256. ;
  257. ;Define TRUE and FALSE
  258. ;
  259. FALSE    EQU    0
  260. TRUE    EQU    NOT FALSE
  261. ;
  262. ;******************************************************************
  263. ;
  264. ;Conditional assembly switch for testing this program
  265. ;(for initial testing phase only - see remarks above)
  266. ;
  267. TEST    EQU    FALSE            ;TRUE FOR TESTING ONLY
  268. ;
  269. ;******************************************************************
  270. ;
  271. ;System equates
  272. ;
  273. BASE    EQU    0            ;STANDARD CP/M BASE ADDRESS
  274. FCB    EQU    BASE+5CH        ;CP/M DEFAULT FCB LOCATION
  275. ;
  276. ;Define ASCII characters used
  277. ;
  278. CR    EQU    0DH            ;CARRIAGE RETURN CHARACTER
  279. LF    EQU    0AH            ;LINE FEED CHARACTER
  280. TAB    EQU    09H            ;TAB CHARACTER
  281. BEL    EQU    07H            ;BELL CHARACTER
  282. ;
  283. M    EQU    Byte Ptr    0[BX]
  284. ;
  285.     cseg
  286.     ORG    BASE+100H
  287. ;
  288.     JMPS    START            ;JMP AROUND OPTION BYTES
  289. ;
  290. ;If you want the system tracks tested, then put a 1 here, otherwise 0.
  291. ;
  292. SYSTST    DB    1            ;0 IF NO SYS TRACKS, OTHERWISE 1
  293. ;
  294. ;   Change this byte to the user number you want [UNUSED].BAD 
  295. ;to reside in.  If you want it in the default user, then leave 
  296. ;it 0FFH.
  297. ;
  298. BADUSR    DB    0FFH            ;USER # WHERE [UNUSED.BAD] GOES
  299. ;0FFH = DEFAULT USER
  300. ;
  301. START:    CALL    START2            ;GO PRINT SIGNON
  302. ;
  303.     DB    CR,LF,'FINDBAD - Ver 1.0, Bad Sector Lockout Utility'
  304.     DB    CR,LF
  305.     DB    '------- Universal Version for CP/M-86 -------'
  306.     DB    CR,LF,CR,LF,'Type CTL-C to abort',CR,LF,'$'
  307. ;
  308. START2:    POP    DX            ;GET MSG ADRS
  309.     MOV    CL,9            ;bdos PRINT BUFFER function
  310.     INT    224            ;bdos PRINT SIGN-ON MSG
  311.     CALL    SETUP            ;SET BIOS ENTRY, AND CHECK DRIVE
  312.     CALL    FINDB            ;ESTABLISH ALL BAD BLOCKS
  313.     JZ    NOBAD            ;SAY NO BAD BLOCKS, IF SO
  314.     CALL    SETDM            ;FIX DM BYTES IN FCB
  315. ;
  316. NOBAD:    CALL    CRLF
  317.     MOV    AL,TAB
  318.     CALL    DISPLAY
  319.     MOV    DX,(Offset NOMSG)    ;POINT FIRST TO 'NO'
  320.     MOV    BX,Word Ptr BADBKS    ;PICK UP # BAD BLOCKS
  321.     MOV    AL,BH            ;CHECK FOR ZERO
  322.     OR    AL,BL
  323.     JZ    PMSG1            ;JUMP IF NONE
  324.     CALL    DECOUT            ;OOPS..HAD SOME BAD ONES, REPORT
  325.     JMPS    PMSG2
  326. ;
  327. PMSG1:    MOV    CL,9            ;bdos PRINT BUFFER function
  328.     INT    224
  329. ;
  330. PMSG2:    MOV    DX,(Offset ENDMSG)    ;REST OF EXIT MESSAGE
  331. ;
  332. PMSG:    MOV    CL,9
  333.     INT    224
  334. ;
  335.     MOV    CL,0            ;EXIT TO CP/M WARM BOOT
  336.     MOV    DL,0
  337.     INT    224
  338. ;
  339. ;Get actual address of BIOS routines
  340. ;
  341. SETUP    EQU    $    ;Check for drive specification
  342. ;
  343. GDRIV:    MOV    AL,Byte Ptr .FCB    ;GET DRIVE NAME
  344.     MOV    CL,AL
  345.     OR    AL,AL            ;ZERO?
  346.     JNZ    GD2            ;IF NOT,THEN GO SPECIFY DRIVE
  347.     MOV    CL,25            ;GET LOGGED-IN DRIVE
  348.     INT    224
  349.     INC    AL            ;MAKE 1-RELATIVE
  350.     MOV    CL,AL
  351. ;
  352. GD2:    CMP    AL,15+1            ;CHECK FOR HIGHEST DRIVE NUMBER
  353.     JNAE    GD3    
  354.     JMP    SELERR            ;SELECT ERROR
  355. ;
  356. GD3:    DEC    CL            ;BACK OFF FOR CP/M
  357.     PUSH    CX            ;SAVE DISK SELECTION
  358.     MOV    DL,CL            ;ALIGN FOR BDOS
  359.     MOV    CL,14            ;SELECT DISK function
  360.     INT    224
  361.     POP    CX            ;GET BACK DISK NUMBER
  362. ;
  363. SETDSK:    MOV    Byte Ptr FUNC,9        ;bios select disk function
  364.     MOV    Word Ptr BIOS_DESC,CX    ;pass disk number to bios descriptor
  365.     MOV    Word Ptr BIOS_DESC+2,0    ;fill remaining descriptor (DX) zero
  366.     MOV    DX,(Offset FUNC)    ;point to function parameter block
  367.     MOV    CL,50            ;direct bios call
  368.     INT    224            ;do it, to it...
  369. ;
  370.     MOV    DL,ES: M        ;GET SECTOR TABLE PNTR
  371.     LAHF
  372.     INC    BX
  373.     SAHF
  374.     MOV    DH,ES: M
  375.     LAHF
  376.     INC    BX
  377.     SAHF
  378.     XCHG    BX,DX
  379.     MOV    Word Ptr SECTBL,BX    ;STORE IT AWAY
  380.     MOV    BX,8            ;OFFSET TO DPB POINTER
  381.     LAHF
  382.     ADD    BX,DX
  383.     RCR    SI,1
  384.     SAHF
  385.     RCL    SI,1
  386.     MOV    AL,ES: M            ;PICK UP DPB POINTER
  387.     LAHF                ;  TO USE
  388.     INC    BX
  389.     SAHF
  390.     MOV    BH,ES: M            ;  AS PARAMETER
  391.     MOV    BL,AL            ;  TO LOGIT
  392. ;
  393. DOLOG:    CALL    LOGIT            ;LOG IN DRIVE, GET DISK PARMS
  394.     CALL    GETDIR            ;CALCULATE DIRECTORY INFORMATION
  395. ;
  396. ;
  397. HOMDSK:    MOV    Byte Ptr FUNC,8        ;bios HOME DISK function
  398.     MOV    Word Ptr BIOS_DESC,0    ;pass 'nothing' number to bios descriptor
  399.     MOV    Word Ptr BIOS_DESC+2,0    ;fill remaining descriptor (DX) zero
  400.     MOV    DX,(Offset FUNC)    ;point to function parameter block
  401.     MOV    CL,50            ;direct bios call
  402.     INT    224            ;do it, to it...
  403. ;
  404. ;Now set the required user number
  405. ;
  406.     MOV    AL,Byte Ptr BADUSR    ;GET THE USER NUMBER
  407.     CMP    AL,0FFH            ;IF IT IS 0FFH, THEN RETURN
  408.     JNZ    L_6
  409.     RET
  410. L_6:
  411.     MOV    CL,32            ;GET/SET USER CODE
  412.     INT    224
  413.     RET
  414. ;
  415. ;Look for bad blocks
  416. ;
  417. FINDB:    MOV    AL,Byte Ptr SYSTST
  418.     OR    AL,AL
  419.     JZ    DODIR            ;JUMP IF NO SYS TRACKS TO BE TESTED
  420.     CALL    CHKSYS            ;CHECK FOR BAD BLOCKS ON TRACK 0 AND 1
  421. ;
  422. DODIR:    CALL    CHKDIR            ;CHECK FOR BAD BLOCKS IN DIRECTORY
  423.     CALL    TELL1
  424. ;
  425.     DB    CR,LF,'Testing data area...',CR,LF,'$'
  426. ;
  427. TELL1:    POP    DX
  428.     MOV    CL,9            ;bdos PRINT STRING function
  429.     INT    224
  430.     CALL    ERAB            ;ERASE ANY [UNUSED].BAD FILE
  431.     MOV    BX,Word Ptr DIRBKS    ;START AT FIRST DATA BLOCK
  432.     MOV    CX,BX            ;PUT INTO [CX]
  433. ;
  434. FINDBA:    CALL    READB            ;READ THE BLOCK
  435.     JZ    L_7    
  436.     CALL    SETBD            ;IF BAD, ADD BLOCK TO LIST
  437. L_7:
  438.     LAHF                ;BUMP TO NEXT BLOCK
  439.     INC    CX
  440.     SAHF
  441.     MOV    BX,Word Ptr DSM
  442.     MOV    DX,CX            ;SET UP FOR (MAXGRP - CURGRP)
  443.     SBB    BX,DX            ;DO SUBTRACT: (MAXGRP - CURGRP)
  444.     JNB    FINDBA            ;UNTIL CURGRP>MAXGRP
  445.     CALL    CRLF
  446.     MOV    BX,Word Ptr DMCNT    ;GET NUMBER OF BAD SECTORS
  447.     MOV    AL,BH
  448.     OR    AL,BL            ;SET ZERO FLAG, IF NO BAD BLOCKS
  449.     RET                ;RETURN FROM "FINDB"
  450. ;
  451. ;Check system tracks, notify user if bad, but continue
  452. ;
  453. CHKSYS:    CALL    CHSY1            ;bdos PRINT MESSAGE
  454. ;
  455.     DB    CR,LF,'Testing system tracks...',CR,LF,'$'
  456. ;
  457. CHSY1:    POP    DX
  458.     MOV    CL,9            ;bdos PRINT STRING function
  459.     INT    224
  460.     MOV    BX,0            ;SET TRACK 0, SECTOR 1
  461.     MOV    Word Ptr TRACK,BX
  462.     LAHF
  463.     INC    BX
  464.     SAHF
  465.     MOV    Word Ptr SECTOR,BX
  466. ;
  467. CHKSY1:    CALL    READS            ;READ A SECTOR
  468.     JNZ    SYSERR            ;NOTIFY, IF BAD BLOCKS HERE
  469.     MOV    BX,Word Ptr SYSTRK    ;SET UP (TRACK-SYSTRK)
  470.     XCHG    BX,DX
  471.     MOV    BX,Word Ptr TRACK
  472.     SBB    BX,DX            ;DO THE SUBTRACT
  473.     JB    CHKSY1            ;LOOP WHILE TRACK < SYSTRK
  474.     RET                ;RETURN FROM "CHKSYS"
  475. ;
  476. SYSERR:    MOV    DX,(Offset ERMSG5)    ;SAY NO GO, AND BAIL OUT
  477.     MOV    CL,9            ;bdos PRINT BUFFER function
  478.     INT    224
  479.     RET                ;RETURN FROM "SYSERR"
  480. ;
  481. ;Check for bad blocks in directory area
  482. ;
  483. CHKDIR:    CALL    CHKD1
  484. ;
  485.     DB    CR,LF,'Testing directory area...',CR,LF,'$'
  486. ;
  487. CHKD1:    POP    DX
  488.     MOV    CL,9            ;bdos PRINT STRING function
  489.     INT    224
  490.     MOV    CX,0            ;START AT BLOCK 0
  491. ;
  492. CHKDI1:    CALL    READB            ;READ A BLOCK
  493.     JZ    L_8    
  494.     JMP    ERROR6            ;IF BAD, INDICATE ERROR IN DIRECTORY AREA
  495. L_8:
  496.     LAHF                ;BUMP FOR NEXT BLOCK
  497.     INC    CX
  498.     SAHF
  499.     MOV    BX,Word Ptr DIRBKS    ;SET UP (CURGRP - DIRBKS)
  500.     LAHF                ;MAKE 0-RELATIVE
  501.     DEC    BX
  502.     SAHF
  503.     MOV    DX,CX
  504.     SBB    BX,DX            ;DO THE SUBTRACT
  505.     JNB    CHKDI1            ;LOOP UNTIL CURGRP > DIRGRP
  506.     RET                ;RETURN FROM "CHKDIR"
  507. ;
  508. ;Read all sectors in block, and return zero flag set if none bad
  509. ;
  510. READB:    CALL    CNVRTB            ;CONVERT TO TRACK/SECTOR IN H&L REGS.
  511.     MOV    AL,Byte Ptr BLM
  512.     INC    AL            ;NUMBER OF SECTORS/BLOCK
  513.     MOV    DH,AL            ;  IN D REG
  514. ;
  515. READBA:    PUSH    DX
  516.     CALL    READS            ;READ SKEWED SECTOR
  517.     POP    DX
  518.     JZ    L_9    
  519.     RET                ;ERROR IF NOT ZERO...
  520. L_9:
  521.     DEC    DH            ;DEBUMP SECTOR/BLOCK
  522.     JNZ    READBA            ;DO NEXT, IF NOT FINISHED
  523.     RET                ;RETURN FROM "READBA"
  524. ;
  525. ;Convert block number to track and skewed sector number
  526. ;
  527. CNVRTB:    PUSH    CX            ;SAVE CURRENT GROUP
  528.     MOV    BX,CX            ;NEED IT IN [BX], FOR EASY SHIFTING
  529.     MOV    AL,Byte Ptr BSH        ;DPB VALUE THAT TELLS HOW TO
  530. ;
  531. SHIFT:    SHL    BX,1            ;  SHIFT GROUP NUMBER TO GET
  532.     DEC    AL            ;  DISK-DATA-AREA RELATIVE
  533.     JNZ    SHIFT            ;  SECTOR NUMBER
  534.     XCHG    BX,DX            ;REL SECTOR # INTO DE
  535.     MOV    BX,Word Ptr SPT        ;SECTORS PER TRACK FROM DPB
  536.     NOT    BX            ;1ST 1'S COMPLEMENT...
  537.     INC    BX            ;...THEN 2'S COMPLEMENT
  538.     XCHG    BX,DX
  539.     MOV    CX,0            ;INITIALIZE QUOTIENT
  540. ;
  541. ;Divide by number of sectors
  542. ;    quotient = track
  543. ;         mod = sector
  544. ;
  545. DIVLP:    LAHF                ;DIRTY DIVISION
  546.     INC    CX
  547.     SAHF
  548.     LAHF
  549.     ADD    BX,DX
  550.     RCR    SI,1
  551.     SAHF
  552.     RCL    SI,1
  553.     JB    DIVLP
  554.     LAHF                ;FIXUP LAST
  555.     DEC    CX
  556.     SAHF
  557.     XCHG    BX,DX
  558.     MOV    BX,Word Ptr SPT
  559.     LAHF
  560.     ADD    BX,DX
  561.     SAHF
  562.     LAHF
  563.     INC    BX
  564.     SAHF
  565.     MOV    Word Ptr SECTOR,BX    ;NOW HAVE LOGICAL SECTOR
  566.     MOV    BX,Word Ptr SYSTRK    ;BUT BEFORE WE HAVE TRACK #,
  567.     LAHF                ;  WE HAVE TO ADD SYS TRACK OFFSET
  568.     ADD    BX,CX
  569.     RCR    SI,1
  570.     SAHF
  571.     RCL    SI,1
  572.     MOV    Word Ptr TRACK,BX
  573.     POP    CX            ;THIS WAS OUR GROUP NUMBER
  574.     RET
  575. ;
  576. ;READS reads a logical sector (if it can)
  577. ;and returns zero flag set if no error.
  578. ;
  579. READS:    PUSH    CX            ;SAVE THE GROUP NUMBER
  580. ;
  581.     CALL    LTOP            ;CONVERT LOGICAL TO PHYSICAL
  582.     MOV    BX,Word Ptr PHYSEC    ;GET PHYSICAL SECTOR
  583.     MOV    CX,BX            ;INTO [CX]
  584. ;
  585. SETSEC:    MOV    BYTE PTR FUNC,11    ;bios SET SECTOR function
  586.     MOV    WORD PTR BIOS_DESC,CX    ;pass sector number to bios descriptor
  587.     MOV    WORD PTR BIOS_DESC+2,0    ;fill remaining descriptor (DX) zero
  588.     MOV    DX,(Offset FUNC)    ;point to function parameter block
  589.     MOV    CL,50            ;direct bios call
  590.     INT    224            ;do it, to it...
  591. ;
  592.     MOV    BX,Word Ptr TRACK    ;NOW SET THE TRACK
  593.     MOV    CX,BX            ;CP/M WANTS IT IN [CX]
  594. ;
  595. SETTRK:    MOV    BYTE PTR FUNC,10    ;bios SELECT TRACK function
  596.     MOV    WORD PTR BIOS_DESC,CX    ;pass track number to bios descriptor
  597.     MOV    WORD PTR BIOS_DESC+2,0    ;fill remaining descriptor (DX) zero
  598.     MOV    DX,(Offset FUNC)    ;point to function parameter block
  599.     MOV    CL,50            ;direct bios call
  600.     INT    224            ;do it, to it...
  601. ;
  602. ;Now do the sector read
  603. ;
  604. DREAD:    MOV    BYTE PTR FUNC,13    ;bios READ SECTOR function
  605.     MOV    WORD PTR BIOS_DESC,0    ;pass 'nothing' number to bios descriptor
  606.     MOV    WORD PTR BIOS_DESC+2,0    ;fill remaining descriptor (DX) zero
  607.     MOV    DX,(Offset FUNC)    ;point to function parameter block
  608.     MOV    CL,50            ;direct bios call
  609.     INT    224            ;do it, to it...
  610. ;
  611.     OR    AL,AL            ;SET FLAGS
  612.     LAHF                ;SAVE ERROR FLAG
  613.     XCHG    AL,AH
  614.     PUSH    AX
  615.     MOV    BX,Word Ptr SECTOR    ;GET LOGICAL SECTOR #
  616.     LAHF                ;WE WANT TO INCREMENT TO NEXT
  617.     INC    BX
  618.     SAHF
  619.     XCHG    BX,DX            ;BUT FIRST...CHECK OVERFLOW
  620.     MOV    BX,Word Ptr SPT        ;  BY DOING (SECPERTRK-SECTOR)
  621.     SBB    BX,DX            ;DO THE SUBTRACTION
  622.     XCHG    BX,DX
  623.     JNB    NOOVF            ;JUMP IF NOT SECTOR>SECPERTRK
  624. ;
  625. ;Sector overflow...bump track number, reset sector
  626. ;
  627.     MOV    BX,Word Ptr TRACK
  628.     LAHF
  629.     INC    BX
  630.     SAHF
  631.     MOV    Word Ptr TRACK,BX
  632.     MOV    AL,'*'            ;TELL CONSOLE ANOTHER TRACK DONE
  633.     CALL    DISPLAY
  634.     CALL    STOP            ;SEE IF CONSOLE WANTS TO QUIT
  635.     MOV    BX,1            ;NEW SECTOR NUMBER ON NEXT TRACK
  636. ;
  637. NOOVF:    MOV    Word Ptr SECTOR,BX    ;PUT SECTOR AWAY
  638.     POP    AX            ;GET BACK ERROR FLAGS
  639.     XCHG    AL,AH
  640.     SAHF
  641.     POP    CX            ;RESTORE GROUP NUMBER
  642.     RET
  643. ;
  644. ;Convert logical sector # to physical
  645. ;
  646. LTOP:    MOV    BX,Word Ptr SECTBL    ;SET UP PARAMETERS
  647.     XCHG    BX,DX            ;  FOR CALL TO SECTRAN
  648.     MOV    BX,Word Ptr SECTOR
  649.     MOV    CX,BX
  650.     DEC    CX            ;ALWAYS CALL SECTRAN W/ZERO-REL SEC #
  651. ;
  652. SECT1:    CALL    SECTRN            ;DO THE SECTOR TRANSLATION
  653.     MOV    AL,Byte Ptr SPT+1    ;CHECK IF BIG TRACKS
  654.     OR    AL,AL            ;SET FLAGS (TRACKS > 256 SECTORS)
  655.     JNZ    LTOP1            ;NO SO SKIP
  656.     MOV    BH,AL            ;ZERO OUT UPPER 8 BITS
  657. ;
  658. LTOP1:    MOV    Word Ptr PHYSEC,BX    ;PUT AWAY PHYSICAL SECTOR
  659.     RET
  660. ;
  661. ;Sector translation vector
  662. ;
  663. SECTRN:    MOV    BYTE PTR FUNC,16    ;bios SECTOR TRANSLATE function
  664.     MOV    WORD PTR BIOS_DESC,CX    ;pass sector to bios descriptor
  665.     MOV    WORD PTR BIOS_DESC+2,DX    ;translate table offset
  666.     MOV    DX,(Offset FUNC)    ;point to function parameter block
  667.     MOV    CL,50            ;direct bios call
  668.     INT    224            ;do it, to it...
  669.     ret                ;return from 'sectrn'
  670. ;
  671. ;Put bad block in bad block list
  672. ;
  673. SETBD:    PUSH    CX
  674.     CALL    SETBD1
  675.     DB    CR,LF,BEL,'Bad block: $'
  676. ;
  677. SETBD1:    POP    DX            ;RETRIEVE ARG
  678.     MOV    CL,9            ;bdos PRINT STRING
  679.     INT    224
  680.     POP    CX            ;GET BACK BLOCK NUMBER
  681.     MOV    AL,CH
  682.     CALL    HEXO            ;bdos PRINT IN HEX
  683.     MOV    AL,CL
  684.     CALL    HEXO
  685.     CALL    CRLF
  686.     MOV    BX,Word Ptr DMCNT    ;GET NUMBER OF SECTORS
  687.     MOV    AL,Byte Ptr BLM        ;GET BLOCK SHIFT VALUE
  688.     INC    AL            ;MAKES SECTOR/GROUP VALUE
  689.     MOV    DL,AL            ;WE WANT 16 BITS
  690.     MOV    DH,0
  691.     ADD    BX,DX            ;BUMP BY NUMBER IN THIS BLOCK
  692.     MOV    Word Ptr DMCNT,BX    ;UPDATE NUMBER OF SECTORS
  693.     MOV    BX,Word Ptr BADBKS    ;INCREMENT NUMBER OF BAD BLOCKS
  694.     INC    BX
  695.     MOV    Word Ptr BADBKS,BX
  696.     MOV    BX,Word Ptr DMPTR    ;GET POINTER INTO DM
  697.     MOV    M,CL            ;...AND PUT BAD BLOCK NUMBER
  698.     INC    BX            ;BUMP TO NEXT AVAILABLE EXTENT
  699.     MOV    AL,Byte Ptr DSM+1    ;CHECK IF 8 OR 16 BIT BLOCK SIZE
  700.     OR    AL,AL
  701.     JZ    SMGRP            ;JUMP IF 8 BIT BLOCKS
  702.     MOV    M,CH            ;ELSE STORE HI BYTE OF BLOCK #
  703.     LAHF                ;AND BUMP POINTER
  704.     INC    BX
  705.     SAHF
  706. ;
  707. SMGRP:    MOV    Word Ptr DMPTR,BX    ;SAVE DM POINTER, FOR NEXT TIME THROUGH HERE
  708.     RET                ;RETURN FROM "SETBD"
  709. ;
  710. ;Eliminate any previous [UNUSED].BAD entries
  711. ;
  712. ERAB:    MOV    DX,(Offset BFCB)    ;POINT TO BAD FCB
  713.     MOV    CL,19            ;bdos DELETE FILE function
  714.     INT    224
  715.     RET
  716. ;
  717. ;Create [UNUSED].BAD file entry
  718. ;
  719. OPENB:    MOV    DX,(Offset BFCB)    ;POINT TO BAD FCB
  720.     MOV    CL,22            ;bdos MAKE FILE function
  721.     INT    224
  722.     CMP    AL,0FFH            ;CHECK FOR OPEN ERROR
  723.     JZ    L_10    
  724.     RET                ;RETURN FROM "OPENB", IF NO ERROR
  725. L_10:
  726.     JMP    ERROR7            ;BAIL OUT...CAN'T CREATE [UNUSED].BAD
  727. ;
  728. CLOSEB:    XOR    AL,AL
  729.     MOV    AL,Byte Ptr BFCB+14    ;GET CP/M 'S2' BYTE
  730.     AND    AL,1FH            ;ZERO UPDATE FLAGS
  731.     MOV    Byte Ptr BFCB+14,AL    ;RESTORE IT TO OUR FCB
  732.     MOV    DX,(Offset BFCB)    ;FCB FOR [UNUSED].BAD
  733.     MOV    CL,16            ;bdos CLOSE FILE function
  734.     INT    224
  735.     RET                ;RETURN FROM "CLOSEB"
  736. ;
  737. ;Move bad area DM to BFCB
  738. ;
  739. SETDM:    MOV    BX,(Offset DM)        ;GET DM
  740.     MOV    Word Ptr DMPTR,BX    ;SAVE AS NEW POINTER
  741.     MOV    AL,Byte Ptr EXM        ;GET THE EXTENT SHIFT FACTOR
  742.     MOV    CL,0            ;INIT BIT COUNT
  743.     CALL    COLECT            ;GET SHIFT VALUE
  744.     MOV    BX,128            ;STARTING EXTENT SIZE
  745.     MOV    AL,CL            ;FIRST SEE IF ANY SHIFTS TO DO
  746.     OR    AL,AL
  747.     JZ    NOSHFT            ;JUMP IF NONE
  748. ;
  749. ESHFT:    SHL    BX,1            ;SHIFT
  750.     DEC    AL            ;BUMP
  751.     JNZ    ESHFT            ;LOOP
  752. ;
  753. NOSHFT:    PUSH    BX            ;SAVE THIS, IT IS RECORDS PER EXTENT
  754.     MOV    AL,Byte Ptr BSH        ;GET BLOCK SHIFT
  755.     MOV    CH,AL
  756. ;
  757. BSHFT:    CLC                ;CLEAR CARRY FLAG
  758.     RCR    BX,1            ;SHIFT RIGHT
  759.     DEC    CH
  760.     JNZ    BSHFT            ;TO GET BLOCKS PER EXTENT
  761.     MOV    AL,BL            ;IT'S IN [BL] (CAN'T BE >16)
  762.     MOV    Byte Ptr BLKEXT,AL    ;SET BLOCK EXTENT, WILL NEED THIS LATER
  763.     POP    BX            ;GET BACK REC/EXT
  764. ;
  765. SET1:    XCHG    BX,DX            ;NOW HAVE REC/EXTENT IN [DX]
  766.     MOV    BX,Word Ptr DMCNT    ;COUNT OF BAD SECTORS
  767. ;
  768. SETDMO:    PUSH    BX            ;SET FLAGS ON (DMCNT-BADCNT)
  769.     SBB    BX,DX            ;HAVE TO SUBTRACT FIRST
  770.     MOV    CX,BX            ;SAVE RESULT IN [CX]
  771.     POP    BX            ;THIS POP MAKES IT COMPARE ONLY
  772.     JB    SETDME            ;JUMP IF LESS THAN 1 EXTENT WORTH
  773.     MOV    AL,CH
  774.     OR    AL,CL            ;TEST IF SUBTRACT WAS 0
  775.     JZ    EVENEX            ;EXTENT IS EXACTLY FILLED (SPL CASE)
  776.     MOV    BX,CX            ;RESTORE RESULT TO [BX]
  777.     PUSH    BX            ;SAVE TOTAL
  778.     PUSH    DX            ;AND SECTORS/EXTENT
  779.     XCHG    BX,DX
  780.     CALL    SETDME            ;PUT AWAY ONE EXTENT
  781.     XCHG    BX,DX
  782.     MOV    Word Ptr DMPTR,BX    ;PUT BACK NEW DM POINTER
  783.     POP    DX            ;GET BACK SECTORS/EXTENT
  784.     POP    BX            ;AND COUNT OF BAD SECTORS
  785.     JMPS    SETDMO            ;AND LOOP
  786. ;
  787. ;Handle the special case of a file that ends on an extent
  788. ;boundary.  CP/M requires that such a file have a succeeding
  789. ;empty extent in order for the BDOS to properly access the file.
  790. ;
  791. EVENEX:    XCHG    BX,DX            ;FIRST SET EXTENT W/BAD BLOCKS
  792.     CALL    SETDME
  793.     XCHG    BX,DX
  794.     MOV    Word Ptr DMPTR,BX
  795.     MOV    BX,0            ;NOW SET ONE WITH NO DATA BLOCKS
  796. ;
  797. ;Fill in an extent's worth of bad sectors/block numbers.
  798. ;Also fill in the extent number in the FCB.
  799. ;
  800. SETDME:    PUSH    BX            ;SAVE RECORD COUNT
  801.     MOV    AL,Byte Ptr EXTNUM    ;UPDATE EXTENT BYTE
  802.     INC    AL
  803.     MOV    Byte Ptr EXTNUM,AL    ;SAVE FOR LATER
  804.     MOV    Byte Ptr BFCB+12,AL    ; AND PUT IN FCB
  805.     CALL    OPENB            ;OPEN THIS EXTENT
  806.     POP    BX            ;RETRIEVE REC COUNT
  807. ;
  808. ;Divide record count by 128 to get the number
  809. ;of logical extents to put in the EX field
  810. ;
  811.     MOV    CH,0            ;INIT QUOTIENT
  812.     MOV    DX,-128            ;-DIVISOR
  813.     MOV    AL,BH            ;TEST FOR SPL CASE
  814.     OR    AL,BL            ;  OF NO RECORDS
  815.     JZ    SKIP
  816. ;
  817. DIVLOP:    ADD    BX,DX            ;SUBTRACT
  818.     INC    CH            ;BUMP QUOTIENT
  819.     JB    DIVLOP
  820.     MOV    DX,128            ;FIX UP OVERSHOOT
  821.     ADD    BX,DX
  822.     DEC    CH
  823.     MOV    AL,BH            ;TEST FOR WRAPAROUND
  824.     OR    AL,BL
  825.     JNZ    SKIP
  826.     MOV    BL,80H            ;RECORD LENGTH
  827.     DEC    CH
  828. ;
  829. SKIP:    MOV    AL,Byte Ptr EXTNUM    ;NOW FIX UP EXTENT NUM
  830.     ADD    AL,CH
  831.     MOV    Byte Ptr EXTNUM,AL
  832.     MOV    Byte Ptr BFCB+12,AL
  833.     MOV    AL,BL            ;MOD IS RECORD COUNT
  834.     MOV    Byte Ptr BFCB+15,AL    ;THAT GOES IN RC BYTE
  835. ;
  836. MOVDM:    MOV    AL,Byte Ptr BLKEXT    ;GET BLOCKS PER EXTENT
  837.     MOV    CH,AL            ;INTO B
  838. ;
  839. SETD1:    MOV    BX,Word Ptr DMPTR    ;POINT TO BAD ALLOCATION MAP
  840.     XCHG    BX,DX
  841.     MOV    BX,(Offset BFCB)+16    ;DISK ALLOC MAP IN FCB
  842. ;
  843. SETDML:    MOV    SI,DX
  844.     MOV    AL,[SI]
  845.     MOV    M,AL
  846.     INC    BX
  847.     INC    DX
  848. ;
  849. ;Now see if 16 bit groups...if so,
  850. ;we have to move another byte
  851. ;
  852.     MOV    AL,Byte Ptr DSM+1    ;THIS TELLS US
  853.     OR    AL,AL
  854.     JZ    BUMP1            ;IF ZERO, THEN NOT
  855.     MOV    SI,DX            ;IS 16 BITS, SO DO ANOTHER
  856.     MOV    AL,[SI]
  857.     MOV    M,AL
  858.     LAHF
  859.     INC    BX
  860.     SAHF
  861.     LAHF
  862.     INC    DX
  863.     SAHF
  864. ;
  865. BUMP1:    DEC    CH            ;COUNT DOWN
  866.     JNZ    SETDML
  867.     PUSH    DX
  868.     CALL    CLOSEB            ;CLOSE THIS EXTENT
  869.     POP    DX
  870.     RET
  871. ;
  872. ;Error messages
  873. ;
  874. SELERR:    MOV    DX,(Offset SELEMS)    ;SAY NO GO, AND BAIL OUT
  875.     JMP    PMSG
  876. ;
  877. SELEMS    DB    CR,LF,'Drive specifier out of range$'
  878. ;
  879. ERMSG5    DB    CR,LF,BEL,'+++ Warning...System tracks'
  880.     DB    ' bad +++',CR,LF,CR,LF,'$'
  881. ;
  882. ERROR6:    MOV    DX,(Offset ERMSG6)    ;OOPS...CLOBBERED DIRECTORY
  883.     JMP    PMSG
  884. ;
  885. ERMSG6    DB    CR,LF,BEL,'Bad directory area, try reformatting$'
  886. ;
  887. ERROR7:    MOV    DX,(Offset ERMSG7)    ;SAY NO GO, AND BAIL OUT
  888.     JMP    PMSG
  889. ;
  890. ERMSG7    DB    CR,LF,'Can''t create [UNUSED].BAD$'
  891. ;
  892. ;
  893. ;==== SUBROUTINES ====
  894. ;
  895. ;Decimal output routine
  896. ;
  897. DECOUT:    PUSH    CX
  898.     PUSH    DX
  899.     PUSH    BX
  900.     MOV    CX,-10
  901.     MOV    DX,-1
  902. ;
  903. DECOU2:    ADD    BX,CX
  904.     INC    DX
  905.     JB    DECOU2
  906.     MOV    CX,10
  907.     ADD    BX,CX
  908.     XCHG    BX,DX
  909.     MOV    AL,BH
  910.     OR    AL,BL
  911.     JZ    L_17    
  912.     CALL    DECOUT
  913. L_17:
  914.     MOV    AL,DL
  915.     ADD    AL,'0'
  916.     CALL    DISPLAY
  917.     POP    BX
  918.     POP    DX
  919.     POP    CX
  920.     RET
  921. ;
  922. ;Carriage-return/line-feed to console
  923. ;
  924. CRLF:    MOV    AL,CR
  925.     CALL    DISPLAY
  926.     MOV    AL,LF            ;FALL INTO 'DISPLAY'
  927. ;
  928. DISPLAY:PUSH    CX
  929.     PUSH    DX
  930.     PUSH    BX
  931.     MOV    DL,AL            ;CHARACTER TO [DX] FOR CP/M
  932.     MOV    CL,2            ;bdos PRINT CONSOLE function
  933.     INT    224            ;bdos PRINT CHARACTER
  934.     POP    BX
  935.     POP    DX
  936.     POP    CX
  937.     RET
  938. ;
  939. ;Subroutine to test console for control-c abort
  940. ;
  941. STOP:    MOV    BYTE PTR FUNC,2        ;BIOS CONSOLE STATUS FUNCTION
  942.     MOV    WORD PTR BIOS_DESC,0    ;PASS 'NOTHING' NUMBER TO BIOS DESCRIPTOR
  943.     MOV    WORD PTR BIOS_DESC+2,0    ;FILL REMAINING DESCRIPTOR (DX) ZERO
  944.     MOV    DX,(OFFSET FUNC)    ;POINT TO FUNCTION PARAMETER BLOCK
  945.     MOV    CL,50            ;direct bios call
  946.     INT    224            ;do it, to it...
  947. ;
  948.     OR    AL,AL            ;TEST FLAGS ON ZERO
  949.     JNZ    L_18    
  950.     RET                ;RETURN IF NO CHAR
  951. L_18:    MOV    BYTE PTR FUNC,3        ;BIOS READ CONSOLE CHARACTER FUNCTION
  952.     MOV    WORD PTR BIOS_DESC,0    ;PASS 'NOTHING' NUMBER TO BIOS DESCRIPTOR
  953.     MOV    WORD PTR BIOS_DESC+2,0    ;FILL REMAINING DESCRIPTOR (DX) ZERO
  954.     MOV    DX,(OFFSET FUNC)    ;POINT TO FUNCTION PARAMETER BLOCK
  955.     MOV    CL,50            ;direct bios call
  956.     INT    224            ;do it, to it...
  957. ;
  958.     CMP    AL,'C'-40H        ;IS IT CONTROL-C?
  959.     JZ    L_19    
  960.     RET                ;RETURN IF NOT
  961. L_19:
  962.     MOV    DX,(Offset ABORTM)    ;EXIT WITH MESSAGE
  963.     JMP    PMSG
  964. ;
  965. ABORTM    DB    CR,LF
  966.     DB    'Test aborted by control-C'
  967.     DB    CR,LF,'$'
  968. ;
  969. ;Move from [BX] to [DX], Count in [CX]
  970. ;
  971. MOVE:    MOV    AL,ES: M
  972.     MOV    SI,DX
  973.     MOV    [SI],AL
  974.     LAHF
  975.     INC    BX
  976.     SAHF
  977.     LAHF
  978.     INC    DX
  979.     SAHF
  980.     DEC    CH
  981.     JNZ    MOVE
  982.     RET
  983. ;
  984. ;Print byte in accumulator in hex
  985. ;
  986. HEXO:    LAHF                ;SAVE FOR SECOND HALF
  987.     XCHG    AL,AH
  988.     PUSH    AX
  989.     XCHG    AL,AH
  990.     ROR    AL,1            ;MOVE INTO POSITION
  991.     ROR    AL,1
  992.     ROR    AL,1
  993.     ROR    AL,1
  994.     CALL    NYBBLE            ;bdos PRINT MS NYBBLE
  995.     POP    AX
  996.     XCHG    AL,AH
  997. ;
  998. NYBBLE:    AND    AL,0FH            ;LO NYBBLE ONLY
  999.     ADD    AL,90H
  1000.     DAA
  1001.     ADC    AL,40H
  1002.     DAA
  1003.     JMP    DISPLAY            ;bdos PRINT IN HEX
  1004. ;
  1005. ;Subroutine to determine the number
  1006. ;of groups reserved for the directory
  1007. ;
  1008. GETDIR:    MOV    CL,0            ;INIT BIT COUNT
  1009.     MOV    AL,Byte Ptr AL0        ;READ DIR GRP BITS
  1010.     CALL    COLECT            ;COLLECT COUNT OF DIR GRPS..
  1011.     MOV    AL,Byte Ptr AL1        ;..IN REGISTER [CL]
  1012.     CALL    COLECT
  1013.     MOV    BL,CL
  1014.     MOV    BH,0            ;[CX] NOW HAS A DEFAULT START GRP #
  1015.     MOV    Word Ptr DIRBKS,BX    ;SAVE FOR LATER
  1016.     RET
  1017. ;
  1018. ;Collect the number of '1' bits in A as a count in [CL]
  1019. ;
  1020. COLECT:    MOV    CH,8
  1021. ;
  1022. COLOP:    RCL    AL,1
  1023.     JNB    COSKIP
  1024.     INC    CL
  1025. ;
  1026. COSKIP:    DEC    CH
  1027.     JNZ    COLOP
  1028.     RET
  1029. ;
  1030. ;Routine to fill in disk parameters
  1031. ;
  1032. LOGIT:    MOV    DX,(Offset DPB)        ;   THEN MOVE TO LOCAL
  1033.     MOV    CH,(Offset DPBLEN)    ;  WORKSPACE
  1034.     CALL    MOVE
  1035.     RET
  1036. ;
  1037. L_22    EQU    $
  1038.     dseg    $
  1039.     ORG    Offset L_22
  1040. ;
  1041. ;--------------------------------------------------
  1042. ;The disk parameter block is moved here from CP/M-86
  1043. ;
  1044. DPB    EQU    (Offset $)        ;DISK PARAMETER BLOCK (COPY)
  1045. ;
  1046. SPT    RS    2            ;SECTORS PER TRACK
  1047. BSH    RS    1            ;BLOCK SHIFT
  1048. BLM    RS    1            ;BLOCK MASK
  1049. EXM    RS    1            ;EXTENT MASK
  1050. DSM    RS    2            ;MAXIMUM BLOCK NUMBER
  1051. DRM    RS    2            ;MAXIMUM DIRECTORY BLOCK NUMBER
  1052. AL0    RS    1            ;DIRECTORY ALLOCATION VECTOR
  1053. AL1    RS    1            ;DIRECTORY ALLOCATION VECTOR
  1054. CKS    RS    2            ;CHECKED DIRECTORY ENTRIES
  1055. SYSTRK    RS    2            ;SYSTEM TRACKS
  1056. ;
  1057. ;End of disk parameter block
  1058. ;
  1059. DPBLEN    EQU    (Offset $)-(Offset DPB)    ;LENGTH OF DISK PARM BLOCK
  1060. ;
  1061. ;--------------------------------------------------
  1062. BLKEXT    DB    0            ;BLOCKS PER EXTENT
  1063. DIRBKS    DW    0            ;CALCULATED # OF DIR BLOCKS
  1064. ;
  1065. BFCB    DB    0,'[UNUSED]BAD',0,0,0,0
  1066. FCBDM    RS    17
  1067. ;
  1068. NOMSG    DB    'No$'
  1069. ENDMSG    DB    ' bad blocks found',CR,LF,'$'
  1070. ;
  1071. BADBKS    DW    0            ;COUNT OF BAD BLOCKS
  1072. SECTOR    DW    0            ;CURRENT SECTOR NUMBER
  1073. TRACK    DW    0            ;CURRENT TRACK NUMBER
  1074. PHYSEC    DW    0            ;CURRENT PHYSICAL SECTOR NUMBER
  1075. SECTBL    DW    0            ;SECTOR SKEW TABLE POINTER
  1076. ;
  1077. EXTNUM    DB    0FFH            ;USED FOR UPDATING EXTENT NUMBER
  1078. DMCNT    DW    0            ;NUMBER OF BAD SECTORS
  1079. DMPTR    DW    (Offset DM)        ;POINTER TO NEXT BLOCK ID
  1080. ;
  1081. ;storage for 5 byte BIOS function descriptor
  1082. ;
  1083. FUNC        RS    1        ;bios function code goes here
  1084. BIOS_DESC    RS    2        ;[CX] data goes here
  1085.         RS    2        ;[DX] data goes here
  1086. ;
  1087. DM    EQU    (Offset $)        ;BAD BLOCK ALLOCATION MAP
  1088. ;
  1089.     DW    0            ;RESERVE 2 BYTES
  1090.     DW    0            ;RESERVE 2 BYTES
  1091.     DW    0            ;RESERVE 2 BYTES
  1092.     DW    0            ;RESERVE 2 BYTES
  1093.     DW    0            ;RESERVE 2 BYTES
  1094.     DW    0            ;RESERVE 2 BYTES
  1095.     DW    0            ;RESERVE 2 BYTES
  1096.     DW    0            ;RESERVE 2 BYTES
  1097.     DW    0            ;RESERVE 2 BYTES
  1098.     DW    0            ;RESERVE 2 BYTES
  1099.     DW    0            ;RESERVE 2 BYTES
  1100.     DW    0            ;RESERVE 2 BYTES
  1101.     DW    0            ;RESERVE 2 BYTES
  1102.     DW    0            ;RESERVE 2 BYTES
  1103.     DW    0            ;RESERVE 2 BYTES
  1104.     DW    0            ;RESERVE 2 BYTES
  1105.     DW    0            ;RESERVE 2 BYTES
  1106.     DW    0            ;RESERVE 2 BYTES
  1107.     DW    0            ;RESERVE 2 BYTES
  1108.     DW    0            ;RESERVE 2 BYTES
  1109.     DW    0            ;RESERVE 2 BYTES
  1110.     DW    0            ;RESERVE 2 BYTES
  1111.     DW    0            ;RESERVE 2 BYTES
  1112.     DW    0            ;RESERVE 2 BYTES
  1113.     DW    0            ;RESERVE 2 BYTES
  1114.     DW    0            ;RESERVE 2 BYTES
  1115.     DW    0            ;RESERVE 2 BYTES
  1116.     DW    0            ;RESERVE 2 BYTES
  1117.     DW    0            ;RESERVE 2 BYTES
  1118.     DW    0            ;RESERVE 2 BYTES
  1119.     DW    0            ;RESERVE 2 BYTES
  1120.     DW    0            ;RESERVE 2 BYTES
  1121.     DW    0            ;RESERVE 2 BYTES
  1122.     DW    0            ;RESERVE 2 BYTES
  1123.     DW    0            ;RESERVE 2 BYTES
  1124.     DW    0            ;RESERVE 2 BYTES
  1125.     DW    0            ;RESERVE 2 BYTES
  1126.     DW    0            ;RESERVE 2 BYTES
  1127.     DW    0            ;RESERVE 2 BYTES
  1128.     DW    0            ;RESERVE 2 BYTES
  1129.     DW    0            ;RESERVE 2 BYTES
  1130.     DW    0            ;RESERVE 2 BYTES
  1131.     DW    0            ;RESERVE 2 BYTES
  1132.     DW    0            ;RESERVE 2 BYTES
  1133.     DW    0            ;RESERVE 2 BYTES
  1134.     DW    0            ;RESERVE 2 BYTES
  1135.     DW    0            ;RESERVE 2 BYTES
  1136.     DW    0            ;RESERVE 2 BYTES
  1137.     DW    0            ;RESERVE 2 BYTES
  1138.     DW    0            ;RESERVE 2 BYTES
  1139.     DW    0            ;RESERVE 2 BYTES
  1140.     DW    0            ;RESERVE 2 BYTES
  1141.     DW    0            ;RESERVE 2 BYTES
  1142.     DW    0            ;RESERVE 2 BYTES
  1143.     DW    0            ;RESERVE 2 BYTES
  1144.     DW    0            ;RESERVE 2 BYTES
  1145.     DW    0            ;RESERVE 2 BYTES
  1146.     DW    0            ;RESERVE 2 BYTES
  1147.     DW    0            ;RESERVE 2 BYTES
  1148.     DW    0            ;RESERVE 2 BYTES
  1149.     DW    0            ;RESERVE 2 BYTES
  1150.     DW    0            ;RESERVE 2 BYTES
  1151. ;
  1152.     END
  1153.