home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / sigm / vols000 / vol079 / plidio.asm < prev    next >
Encoding:
Assembly Source File  |  1984-04-29  |  20.9 KB  |  604 lines
  1.     name    'DIOMOD'
  2.     title    'Direct CP/M Calls From PL/I-80'
  3. ;
  4. ;***********************************************************
  5. ;*                                                         *
  6. ;*    cp/m calls from pl/i for direct i/o                *
  7. ;*                                                         *
  8. ;***********************************************************
  9.     public    memptr    ;return pointer to base of free mem
  10.     public    memsiz    ;return size of memory in bytes
  11.     public    memwds    ;return size of memory in words
  12.     public    dfcb0    ;return address of default fcb 0
  13.     public    dfcb1    ;return address of default fcb 1
  14.     public    dbuff    ;return address of default buffer
  15.     public    reboot    ;system reboot (#0)
  16.     public    rdcon    ;read console character (#1)
  17.     public    wrcon    ;write console character(#2)
  18.     public    rdrdr    ;read reader character (#3)
  19.     public    wrpun    ;write punch character (#4)
  20.     public    wrlst    ;write list character (#5)
  21.     public    coninp    ;direct console input (#6a)
  22.     public    conout    ;direct console output (#6b)
  23.     public    rdstat    ;read console status (#6c)
  24.     public    getio    ;get io byte (#8)
  25.     public    setio    ;set i/o byte (#9)
  26.     public    wrstr    ;write string (#10)
  27.     public    rdbuf    ;read console buffer (#10)
  28.     public    break    ;get console status (#11)
  29.     public    vers    ;get version number (#12)
  30.     public    reset    ;reset disk system (#13)
  31.     public    select    ;select disk (#14)
  32.     public    open    ;open file (#15)
  33.     public    close    ;close file (#16)
  34.     public    sear    ;search for file (#17)
  35.     public    searn    ;search for next (#18)
  36.     public    delete    ;delete file (#19)
  37.     public    rdseq    ;read file sequential mode (#20)
  38.     public    wrseq    ;write file sequential mode (#21)
  39.     public    make    ;create file (#22)
  40.     public    rename    ;rename file (#23)
  41.     public    logvec    ;return login vector (#24)
  42.     public    curdsk    ;return current disk number (#25)
  43.     public    setdma    ;set DMA address (#26)
  44.     public    allvec    ;return address of alloc vector (#27)
  45.     public    wpdisk    ;write protect disk (#28)
  46.     public    rovec    ;return read/only vector (#29)
  47.     public    filatt    ;set file attributes (#30)
  48.     public    getdpb    ;get base of disk parm block (#31)
  49.     public    getusr    ;get user code (#32a)
  50.     public    setusr    ;set user code (#32b)
  51.     public    rdran    ;read random (#33)
  52.     public    wrran    ;write random (#34)
  53.     public    filsiz    ;random file size (#35)
  54.     public    setrec    ;set random record pos (#36)
  55.     public    resdrv    ;reset drive (#37)
  56.     public    wrranz    ;write random, zero fill (#40)
  57. ;
  58. ;
  59.     extrn    ?begin    ;beginning of free list
  60.     extrn    ?boot    ;system reboot entry point
  61.     extrn    ?bdos    ;bdos entry point
  62.     extrn    ?dfcb0    ;default fcb 0
  63.     extrn    ?dfcb1    ;default fcb 1
  64.     extrn    ?dbuff    ;default buffer
  65. ;
  66. ;***********************************************************
  67. ;*                                                         *
  68. ;*        equates for interface to cp/m bdos               *
  69. ;*                                                         *
  70. ;***********************************************************
  71. cr    equ    0dh    ;carriage return
  72. lf    equ    0ah    ;line feed
  73. eof    equ    1ah    ;end of file
  74. ;
  75. readc    equ    1    ;read character from console
  76. writc    equ    2    ;write console character
  77. rdrf    equ    3    ;reader input
  78. punf    equ    4    ;punch output
  79. listf    equ    5    ;list output function
  80. diof    equ    6    ;direct i/o, version 2.0
  81. getiof    equ    7    ;get i/o byte
  82. setiof    equ    8    ;set i/o byte
  83. printf    equ    9    ;print string function
  84. rdconf    equ    10    ;read console buffer
  85. statf    equ    11    ;return console status
  86. versf    equ    12    ;get version number
  87. resetf    equ    13    ;system reset
  88. seldf    equ    14    ;select disk function
  89. openf    equ    15    ;open file function
  90. closef    equ    16    ;close file
  91. serchf    equ    17    ;search for file
  92. serchn    equ    18    ;search next
  93. deletf    equ    19    ;delete file
  94. readf    equ    20    ;read next record
  95. writf    equ    21    ;write next record
  96. makef    equ    22    ;make file
  97. renamf    equ    23    ;rename file
  98. loginf    equ    24    ;get login vector
  99. cdiskf    equ    25    ;get current disk number
  100. setdmf    equ    26    ;set dma function
  101. getalf    equ    27    ;get allocation base
  102. wrprof    equ    28    ;write protect disk
  103. getrof    equ    29    ;get r/o vector
  104. setatf    equ    30    ;set file attributes
  105. getdpf    equ    31    ;get disk parameter block
  106. userf    equ    32    ;set/get user code
  107. rdranf    equ    33    ;read random
  108. wrranf    equ    34    ;write random
  109. filszf    equ    35    ;compute file size
  110. setrcf    equ    36    ;set random record position
  111. rsdrvf    equ    37    ;reset drive function
  112. wrrnzf    equ    40    ;write random zero fill
  113. ;
  114. ;    utility functions
  115. ;***********************************************************
  116. ;*                                                         *
  117. ;*       general purpose routines used upon entry          *
  118. ;*                                                         *
  119. ;***********************************************************
  120. ;
  121. getp1:    ;get single byte parameter to register e
  122.     mov    e,m        ;low (addr)
  123.     inx    h
  124.     mov    d,m        ;high(addr)
  125.     xchg            ;hl = .char
  126.     mov    e,m        ;to register e
  127.     ret
  128. ;
  129. getp2:    ;get single word value to DE
  130. getp2i:    ;(equivalent to getp2)
  131.     call    getp1
  132.     inx    h
  133.     mov    d,m        ;get high byte as well
  134.     ret
  135. ;
  136. getver:    ;get cp/m or mp/m version number
  137.     push    h        ;save possible data adr
  138.     mvi    c,versf
  139.     call    ?bdos
  140.     pop    h        ;recall data addr
  141.     ret
  142. ;
  143. chkv20:    ;check for version 2.0 or greater
  144.     call    getver
  145.     cpi    20
  146.     rnc            ;return if > 2.0
  147. ;    error message and stop
  148.     jmp    vererr        ;version error
  149. ;
  150. chkv22:    ;check for version 2.2 or greater
  151.     call    getver
  152.     cpi    22h
  153.     rnc            ;return if >= 2.2
  154. vererr:
  155.     ;version error, report and terminate
  156.     lxi    d,vermsg
  157.     mvi    c,printf
  158.     call    ?bdos        ;write message
  159.     jmp    ?boot        ;and reboot
  160. vermsg:    db    cr,lf,'Later CP/M or MP/M Version Required$'
  161. ;
  162. ;***********************************************************
  163. ;*                                                         *
  164. ;***********************************************************
  165. memptr:    ;return pointer to base of free storage
  166.     lhld    ?begin
  167.     ret
  168. ;
  169. ;***********************************************************
  170. ;*                                                         *
  171. ;***********************************************************
  172. memsiz:    ;return size of free memory in bytes
  173.     lhld    ?bdos+1        ;base of bdos
  174.     xchg            ;de = .bdos
  175.     lhld    ?begin        ;beginning of free storage
  176.     mov    a,e        ;low(.bdos)
  177.     sub    l        ;-low(begin)
  178.     mov    l,a        ;back to l
  179.     mov    a,d        ;high(.bdos)
  180.     sbb    h
  181.     mov    h,a        ;hl = mem size remaining
  182.     ret
  183. ;
  184. ;***********************************************************
  185. ;*                                                         *
  186. ;***********************************************************
  187. memwds:    ;return size of free memory in words
  188.     call    memsiz        ;hl = size in bytes
  189.     mov    a,h        ;high(size)
  190.     ora    a        ;cy = 0
  191.     rar            ;cy = ls bit
  192.     mov    h,a        ;back to h
  193.     mov    a,l        ;low(size)
  194.     rar            ;include ls bit
  195.     mov    l,a        ;back to l
  196.     ret            ;with wds in hl
  197. ;
  198. ;***********************************************************
  199. ;*                                                         *
  200. ;***********************************************************
  201. dfcb0:    ;return address of default fcb 0
  202.     lxi    h,?dfcb0
  203.     ret
  204. ;
  205. ;***********************************************************
  206. ;*                                                         *
  207. ;***********************************************************
  208. dfcb1:    ;return address of default fcb 1
  209.     lxi    h,?dfcb1
  210.     ret
  211. ;
  212. ;***********************************************************
  213. ;*                                                         *
  214. ;***********************************************************
  215. dbuff:    ;return address of default buffer
  216.     lxi    h,?dbuff
  217.     ret
  218. ;
  219. ;***********************************************************
  220. ;*                                                         *
  221. ;***********************************************************
  222. reboot:    ;system reboot (#0)
  223.     jmp    ?boot
  224. ;
  225. ;***********************************************************
  226. ;*                                                         *
  227. ;***********************************************************
  228. rdcon:    ;read console character (#1)
  229.     ;return character value to stack
  230.     mvi    c,readc
  231.     jmp    chrin        ;common code to read char
  232. ;
  233. ;***********************************************************
  234. ;*                                                         *
  235. ;***********************************************************
  236. wrcon:    ;write console character(#2)
  237.     ;1->char(1)
  238.     mvi    c,writc        ;console write function
  239.     jmp    chrout        ;to write the character
  240. ;
  241. ;***********************************************************
  242. ;*                                                         *
  243. ;***********************************************************
  244. rdrdr:    ;read reader character (#3)
  245.     mvi    c,rdrf        ;reader function
  246. chrin:
  247.     ;common code for character input
  248.     call    ?bdos        ;value returned to A
  249.     jmp    chrstr        ;create a char(1) string
  250. ;
  251. ;***********************************************************
  252. ;*                                                         *
  253. ;***********************************************************
  254. wrpun:    ;write punch character (#4)
  255.     ;1->char(1)
  256.     mvi    c,punf        ;punch output function
  257.     jmp    chrout        ;common code to write chr
  258. ;
  259. ;***********************************************************
  260. ;*                                                         *
  261. ;***********************************************************
  262. wrlst:    ;write list character (#5)
  263.     ;1->char(1)
  264.     mvi    c,listf        ;list output function
  265. chrout:
  266.     ;common code to write character
  267.     ;1-> character to write
  268.     call    getp1        ;output char to register e
  269.     jmp    ?bdos        ;to write and return
  270. ;
  271. ;***********************************************************
  272. ;*                                                         *
  273. ;***********************************************************
  274. coninp:    ;perform console input, char returned in stack
  275.     lxi    h,chrstr    ;return address
  276.     push    h        ;to stack for return
  277.     lhld    ?boot+1        ;base of bios jmp vector
  278.     lxi    d,2*3        ;offset to jmp conin
  279.     dad    d
  280.     pchl            ;return to chrstr
  281. ;
  282. chrstr:    ;create character string, length 1
  283.     pop    h        ;recall return address
  284.     push    psw        ;save character on stack
  285.     inx    sp        ;delete psw flags
  286.     mvi    a,1        ;character length is 1
  287.     pchl            ;return to caller
  288. ;
  289. ;***********************************************************
  290. ;*                                                         *
  291. ;***********************************************************
  292. conout:    ;direct console output
  293.     ;1->char(1)
  294.     call    getp1        ;get parameter
  295.     mov    c,e        ;character to c
  296.     lhld    ?boot+1        ;base of bios jmp
  297.     lxi    d,3*3        ;console output offset
  298.     dad    d        ;hl = .jmp conout
  299.     pchl            ;return through handler
  300. ;
  301. ;***********************************************************
  302. ;*                                                         *
  303. ;***********************************************************
  304. rdstat:    ;direct console status read
  305.     lxi    h,rdsret    ;read status return
  306.     push    h        ;return to rdsret
  307.     lhld    ?boot+1        ;base of jmp vector
  308.     lxi    d,1*3        ;offset to .jmp const
  309.     dad    d        ;hl = .jmp const
  310.     pchl
  311. ;
  312. ;***********************************************************
  313. ;*                                                         *
  314. ;***********************************************************
  315. getio:    ;get io byte (#8)
  316.     mvi    c,getiof
  317.     jmp    ?bdos        ;value returned to A
  318. ;
  319. ;***********************************************************
  320. ;*                                                         *
  321. ;***********************************************************
  322. setio:    ;set i/o byte (#9)
  323.     ;1->i/o byte
  324.     call    getp1        ;new i/o byte to E
  325.     mvi    c,setiof
  326.     jmp    ?bdos        ;return through bdos
  327. ;
  328. ;***********************************************************
  329. ;*                                                         *
  330. ;***********************************************************
  331. wrstr:    ;write string (#10)
  332.     ;1->addr(string)
  333.     call    getp2        ;get parameter value to DE
  334.     mvi    c,printf    ;print string function
  335.     jmp    ?bdos        ;return through bdos
  336. ;
  337. ;***********************************************************
  338. ;*                                                         *
  339. ;***********************************************************
  340. rdbuf:    ;read console buffer (#10)
  341.     ;1->addr(buff)
  342.     call    getp2i        ;DE = .buff
  343.     mvi    c,rdconf    ;read console function
  344.     jmp    ?bdos        ;return through bdos
  345. ;
  346. ;***********************************************************
  347. ;*                                                         *
  348. ;***********************************************************
  349. break:    ;get console status (#11)
  350.     mvi    c,statf
  351.     call    ?bdos        ;return through bdos
  352. ;
  353. rdsret:    ;return clean true value
  354.     ora    a        ;zero?
  355.     rz            ;return if so
  356.     mvi    a,0ffh        ;clean true value
  357.     ret
  358. ;
  359. ;***********************************************************
  360. ;*                                                         *
  361. ;***********************************************************
  362. vers:    ;get version number (#12)
  363.     mvi    c,versf
  364.     jmp    ?bdos        ;return through bdos
  365. ;
  366. ;***********************************************************
  367. ;*                                                         *
  368. ;***********************************************************
  369. reset:    ;reset disk system (#13)
  370.     mvi    c,resetf
  371.     jmp    ?bdos
  372. ;
  373. ;***********************************************************
  374. ;*                                                         *
  375. ;***********************************************************
  376. select:    ;select disk (#14)
  377.     ;1->fixed(7) drive number
  378.     call    getp1        ;disk number to E
  379.     mvi    c,seldf
  380.     jmp    ?bdos        ;return through bdos
  381. ;***********************************************************
  382. ;*                                                         *
  383. ;***********************************************************
  384. open:    ;open file (#15)
  385.     ;1-> addr(fcb)
  386.     call    getp2i        ;fcb address to de
  387.     mvi    c,openf
  388.     jmp    ?bdos        ;return through bdos
  389. ;
  390. ;***********************************************************
  391. ;*                                                         *
  392. ;***********************************************************
  393. close:    ;close file (#16)
  394.     ;1-> addr(fcb)
  395.     call    getp2i        ;.fcb to DE
  396.     mvi    c,closef
  397.     jmp    ?bdos        ;return through bdos
  398. ;
  399. ;***********************************************************
  400. ;*                                                         *
  401. ;***********************************************************
  402. sear:    ;search for file (#17)
  403.     ;1-> addr(fcb)
  404.     call    getp2i        ;.fcb to DE
  405.     mvi    c,serchf
  406.     jmp    ?bdos
  407. ;
  408. ;***********************************************************
  409. ;*                                                         *
  410. ;***********************************************************
  411. searn:    ;search for next (#18)
  412.     mvi    c,serchn    ;search next function
  413.     jmp    ?bdos        ;return through bdos
  414. ;
  415. ;***********************************************************
  416. ;*                                                         *
  417. ;***********************************************************
  418. delete:    ;delete file (#19)
  419.     ;1-> addr(fcb)
  420.     call    getp2i        ;.fcb to DE
  421.     mvi    c,deletf
  422.     jmp    ?bdos        ;return through bdos
  423. ;
  424. ;***********************************************************
  425. ;*                                                         *
  426. ;***********************************************************
  427. rdseq:    ;read file sequential mode (#20)
  428.     ;1-> addr(fcb)
  429.     call    getp2i        ;.fcb to DE
  430.     mvi    c,readf
  431.     jmp    ?bdos        ;return through bdos
  432. ;
  433. ;***********************************************************
  434. ;*                                                         *
  435. ;***********************************************************
  436. wrseq:    ;write file sequential mode (#21)
  437.     ;1-> addr(fcb)
  438.     call    getp2i        ;.fcb to DE
  439.     mvi    c,writf
  440.     jmp    ?bdos        ;return through bdos
  441. ;
  442. ;***********************************************************
  443. ;*                                                         *
  444. ;***********************************************************
  445. make:    ;create file (#22)
  446.     ;1-> addr(fcb)
  447.     call    getp2i        ;.fcb to DE
  448.     mvi    c,makef
  449.     jmp    ?bdos        ;return through bdos
  450. ;
  451. ;***********************************************************
  452. ;*                                                         *
  453. ;***********************************************************
  454. rename:    ;rename file (#23)
  455.     ;1-> addr(fcb)
  456.     call    getp2i        ;.fcb to DE
  457.     mvi    c,renamf
  458.     jmp    ?bdos        ;return through bdos
  459. ;
  460. ;***********************************************************
  461. ;*                                                         *
  462. ;***********************************************************
  463. logvec:    ;return login vector (#24)
  464.     mvi    c,loginf
  465.     jmp    ?bdos        ;return through BDOS
  466. ;
  467. ;***********************************************************
  468. ;*                                                         *
  469. ;***********************************************************
  470. curdsk:    ;return current disk number (#25)
  471.     mvi    c,cdiskf
  472.     jmp    ?bdos        ;return value in A
  473. ;
  474. ;***********************************************************
  475. ;*                                                         *
  476. ;***********************************************************
  477. setdma:    ;set DMA address (#26)
  478.     ;1-> pointer (dma address)
  479.     call    getp2        ;dma address to DE
  480.     mvi    c,setdmf
  481.     jmp    ?bdos        ;return through bdos
  482. ;
  483. ;***********************************************************
  484. ;*                                                         *
  485. ;***********************************************************
  486. allvec:    ;return address of allocation vector (#27)
  487.     mvi    c,getalf
  488.     jmp    ?bdos        ;return through bdos
  489. ;
  490. ;***********************************************************
  491. ;*                                                         *
  492. ;***********************************************************
  493. wpdisk:    ;write protect disk (#28)
  494.     call    chkv20        ;must be 2.0 or greater
  495.     mvi    c,wrprof
  496.     jmp    ?bdos
  497. ;
  498. ;***********************************************************
  499. ;*                                                         *
  500. ;***********************************************************
  501. rovec:    ;return read/only vector (#29)
  502.     call    chkv20        ;must be 2.0 or greater
  503.     mvi    c,getrof
  504.     jmp    ?bdos        ;value returned in HL
  505. ;
  506. ;***********************************************************
  507. ;*                                                         *
  508. ;***********************************************************
  509. filatt:    ;set file attributes (#30)
  510.     ;1-> addr(fcb)
  511.     call    chkv20        ;must be 2.0 or greater
  512.     call    getp2i        ;.fcb to DE
  513.     mvi    c,setatf
  514.     jmp    ?bdos
  515. ;
  516. ;***********************************************************
  517. ;*                                                         *
  518. ;***********************************************************
  519. getdpb:    ;get base of current disk parm block (#31)
  520.     call    chkv20        ;check for 2.0 or greater
  521.     mvi    c,getdpf
  522.     jmp    ?bdos        ;addr returned in HL
  523. ;
  524. ;***********************************************************
  525. ;*                                                         *
  526. ;***********************************************************
  527. getusr:    ;get user code to register A
  528.     call    chkv20        ;check for 2.0 or greater
  529.     mvi    e,0ffh        ;to get user code
  530.     mvi    c,userf
  531.     jmp    ?bdos
  532. ;
  533. ;***********************************************************
  534. ;*                                                         *
  535. ;***********************************************************
  536. setusr:    ;set user code
  537.     call    chkv20        ;check for 2.0 or greater
  538.     call    getp1        ;code to E
  539.     mvi    c,userf
  540.     jmp    ?bdos
  541. ;
  542. ;***********************************************************
  543. ;*                                                         *
  544. ;***********************************************************
  545. rdran:    ;read random (#33)
  546.     ;1-> addr(fcb)
  547.     call    chkv20        ;check for 2.0 or greater
  548.     call    getp2i        ;.fcb to DE
  549.     mvi    c,rdranf
  550.     jmp    ?bdos        ;return through bdos
  551. ;
  552. ;***********************************************************
  553. ;*                                                         *
  554. ;***********************************************************
  555. wrran:    ;write random (#34)
  556.     ;1-> addr(fcb)
  557.     call    chkv20        ;check for 2.0 or greater
  558.     call    getp2i        ;.fcb to DE
  559.     mvi    c,wrranf
  560.     jmp    ?bdos        ;return through bdos
  561. ;
  562. ;***********************************************************
  563. ;*                                                         *
  564. ;***********************************************************
  565. filsiz:    ;compute file size (#35)
  566.     call    chkv20        ;must be 2.0 or greater
  567.     call    getp2        ;.fcb to DE
  568.     mvi    c,filszf
  569.     jmp    ?bdos        ;return through bdos
  570. ;
  571. ;***********************************************************
  572. ;*                                                         *
  573. ;***********************************************************
  574. setrec:    ;set random record position (#36)
  575.     call    chkv20        ;must be 2.0 or greater
  576.     call    getp2        ;.fcb to DE
  577.     mvi    c,setrcf
  578.     jmp    ?bdos        ;return through bdos
  579. ;
  580. ;***********************************************************
  581. ;*                                                         *
  582. ;***********************************************************
  583. resdrv:    ;reset drive function (#37)
  584.     ;1->drive vector - bit(16)
  585.     call    chkv22        ;must be 2.2 or greater
  586.     call    getp2        ;drive reset vector to DE
  587.     mvi    c,rsdrvf
  588.     jmp    ?bdos        ;return through bdos
  589. ;
  590. ;***********************************************************
  591. ;*                                                         *
  592. ;***********************************************************
  593. wrranz:    ;write random, zero fill function
  594.     ;1-> addr(fcb)
  595.     call    chkv22    ;must be 2.2 or greater
  596.     call    getp2i        ;.fcb to DE
  597.     mvi    c,wrrnzf
  598.     jmp    ?bdos
  599. ;
  600. ;***********************************************************
  601. ;*                                                         *
  602. ;***********************************************************
  603.     end
  604.