home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / sigm / vols000 / vol074 / uccs7710.asm < prev    next >
Encoding:
Assembly Source File  |  1984-04-29  |  1.9 KB  |  104 lines
  1. ;********************************************************
  2. ;*                            *    
  3. ;*  BSTAM INTERFACE CCS 7710A CARD IN APPLE CP/M SYSTEM    *
  4. ;*                            *
  5. ;********************************************************
  6. ;
  7. ;        Jan 10, 1981
  8. ;
  9. ;    By    Bill Bolton
  10. ;        Software Tools
  11. ;        P.O. Box 80
  12. ;        Newport Beach
  13. ;        NSW, 2106
  14. ;        Australia
  15. ;
  16. ;        TCY396
  17. ;
  18. ;
  19. ;VERSION 6850/4.5
  20. ;
  21. BEGIN    ORG    103H
  22. INITIL    JMP    INITIU            ;UART/USART INITIALATION ENTRY POINT
  23. INSPORT    JMP    INSPRU            ;STATUS PORT READ ENTRY POINT
  24. ERRSET    JMP    ERRSTU            ;UART/USART ERROR RESET ENTRY POINT
  25. INPORT    JMP    INPRTU            ;READ DATA PORT ENTRY POINT
  26. OUTPORT    JMP    OUTPRU            ;WRITE DATA PORT ENTRY POINT
  27. ;
  28. ;
  29. ;
  30. TPS    EQU    0E0A0H            ;STATUS PORT
  31. TP    EQU    TPS+1            ;DATA PORT
  32. ;
  33. ;
  34. INITIU:
  35.     CALL    SIGNON
  36. RESET:
  37.     MVI    A,17H            ;RESET ACIA
  38.     STA    TPS
  39.     MVI    A,11H            ;8 BITS, 2 STOP, 16X CLK, NO PAR
  40.     STA    TPS
  41.     RET                ;RETURN TO BSTAM
  42. ;
  43. ;
  44. ;
  45. ;
  46. INSPRU:
  47.     PUSH    B
  48.     LDA    TPS            ;GET STATUS
  49.     MOV    C,A            ;C <--- STATUS
  50.     MVI    B,1            ;PRESET 8251 TX READY
  51.     ANI    1            ;6850 RX DATA?
  52.     JZ    CHKTXE            ;NO
  53.     MVI    A,02H            ;YES, SET 8251 RX DATA
  54.     ORA    B            ;COMBINE WITH B
  55.     MOV    B,A
  56. CHKTXE:    MOV    A,C            ;A <--- STATUS
  57.     ANI    02H            ;TX EMPTY?
  58.     JZ    CHKOVR            ;NO
  59.     MVI    A,04H            ;YES, SET 8251 TXE
  60.     ORA    B            ;COMBINE WITH B
  61.     MOV    B,A
  62. CHKOVR:    MOV    A,C            ;A <--- STATUS
  63.     ANI    20H            ;RX OVERRUN
  64.     JZ    ENDCHK            ;NO
  65.     MVI    A,10H            ;YES, SET 8251 OE
  66.     ORA    B            ;COMBINE WITH B
  67.     MOV    B,A
  68. ENDCHK:    MOV    A,B            ;A <--- 8251 LIKE STATUS
  69.     POP    B
  70.     RET
  71. ;
  72. ERRSTU:
  73.     CALL    RESET            ;RESET ACIA
  74.     RET                ;RETURN TO BSTAM
  75. ;
  76. ;
  77. INPRTU:
  78.     LDA    TP    ;GET DATA FROM PORT
  79.     RET        ;RETURN TO BSTAM
  80. ;
  81. ;
  82. OUTPRU:
  83.     STA    TP    ;SEND DATA TO REMOTE CPU
  84.     RET        ;RETURN TO BSTAM
  85. ;
  86. ;
  87. MESSGE:    DB    0DH,0AH,0DH,0AH
  88.     DB    'Version 4.5 - Software Tools',0DH,0AH
  89.     DB    'For APPLE CP/M 2.2 with',0DH,0AH
  90.     DB    'CCS 7710A (6850), no parity',0DH,0AH,'$'
  91. ;
  92. SIGNON:    PUSH    B
  93.     PUSH    D
  94.     PUSH    H
  95.     LXI    D,MESSGE
  96.     MVI    C,9
  97.     CALL    5        ;ANOUNCE VERSION TO USER
  98.     POP    H
  99.     POP    D
  100.     POP    B
  101.     RET
  102. ;
  103.     END    BEGIN
  104.