home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / sigm / vols000 / vol074 / u2651.asm < prev    next >
Encoding:
Assembly Source File  |  1984-04-29  |  5.5 KB  |  247 lines
  1. ;****************************************************************
  2. ;*                                *
  3. ;*       BSTAM/BSTMS Interface routines for 2651 UART.    *
  4. ;*        on Godbout System Support 1 Board        *
  5. ;*         or Godbout Interfacer 3/4 Board        *
  6. ;*                                *
  7. ;****************************************************************
  8. ;
  9. ;    By    Bill Bolton
  10. ;        Software Tools,
  11. ;        P.O. Box 80,
  12. ;        Newport Beach,
  13. ;        NSW, 2106
  14. ;        AUSTRALIA
  15. ;
  16.     TITLE    '2651 UART Interface for BSTAM, Software Tools'
  17. ; 
  18. ;************************************************
  19. ;*                        *
  20. ;*         Miscellaneous Equates        *
  21. ;*                        *
  22. ;************************************************
  23. ;
  24. TRUE    EQU    0FFFFH
  25. FALSE    EQU    NOT TRUE
  26.  
  27. BDOS    EQU    0005            ;CP/M BDOS entry point
  28. ALF    EQU    0AH            ;ASCII line feed
  29. ACR    EQU    0DH            ;ASCII carriage return
  30. ;
  31. ;************************************************
  32. ;*                        *
  33. ;*         2651 Baud Rate Table        *
  34. ;*                        *
  35. ;************************************************
  36. ;
  37. B50    EQU    0000B            ;50 bps
  38. B75    EQU    0001B            ;75 bps
  39. B110    EQU    0010B            ;110 bps
  40. B134    EQU    0011B            ;134.5 bps
  41. B150    EQU    0100B            ;150 bps
  42. B300    EQU    0101B            ;300 bps
  43. B600    EQU    0110B            ;600 bps
  44. B1200    EQU    0111B            ;1200 bps
  45. B1800    EQU    1000B            ;1800 bps
  46. B2000    EQU    1001B            ;2000 bps
  47. B2400    EQU    1010B            ;2400 bps
  48. B3600    EQU    1011B            ;3600 bps
  49. B4800    EQU    1100B            ;4800 bps
  50. B7200    EQU    1101B            ;7200 bps
  51. B9600    EQU    1110B            ;9600 bps
  52. B19200    EQU    1111B            ;19200 bps
  53. ;
  54. ;************************************************
  55. ;*                        *
  56. ;*        2651 Equates            *
  57. ;*                        *
  58. ;************************************************
  59. ;
  60. BASE    EQU    5CH            ;UART base register
  61. DATA    EQU    BASE+0            ;Data port
  62. STATUS    EQU    BASE+1            ;Status port
  63. MODE    EQU    BASE+2            ;Mode register
  64. CMMD    EQU    BASE+3            ;Command register
  65. USER    EQU    BASE+7            ;User select port
  66. UNUM    EQU    6            ;Modem user number
  67. MODE1    EQU    01101110B        ;Asynch,16x,8 data bits,
  68.                     ; no parity, even, 1 stop bit
  69. MODE2    EQU    01110000B + B300    ;Baud rate
  70. CMMDB    EQU    00100111B        ;Tx enabled, RX enabled, no break
  71.                     ; DTR high, RTS high
  72. ERESET    EQU    CMMDB+8            ;Error reset
  73. ;
  74. SYSSPT    EQU    TRUE            ;True for Godbout system support
  75. INTER3    EQU    NOT SYSSPT        ;True for Godbout Interfacer 3
  76. ;
  77.     ORG    103H
  78. ;
  79. BEGIN:
  80. INITIL:
  81.     JMP    INITIU        ;UART/USART INITIALATION ENTRY POINT
  82. INSPORT:
  83.     JMP    INSPRU        ;STATUS PORT READ ENTRY POINT
  84. ERRSET:
  85.     JMP    ERRSTU        ;UART/USART ERROR RESET ENTRY POINT
  86. INPORT:
  87.     JMP    INPRTU        ;READ DATA PORT ENTRY POINT
  88. OUTPORT:
  89.     JMP    OUTPRU        ;WRITE DATA PORT ENTRY POINT
  90. ;
  91. ;
  92. ;            THIS IS THE UART/USART INITIALATION ROUTINE.
  93. ;            TO BE COMPATIBLE WITH MOST BSTAM USERS USE FOLLOWING
  94. ;            INITIALISATION GUIDE LINES:
  95. ;            1. USE 1 STOP BIT    (OPTIONAL - 2)
  96. ;            2. USE 8 DATA BITS    (MUST)
  97. ;            3. USE 1 START BIT    (MUST)
  98. ;            4. USE 16X FOR CLOCK RATE     (MUST)
  99. ;            5. USE ASYNCHRONOUS MODE ONLY    (MUST)
  100. ;
  101. INITIU:
  102.     CALL    SIGNON        ;Announce version
  103.  
  104.     if    inter3
  105.     MVI    A,UNUM
  106.     OUT    USER        ;Select UART
  107.     endif    ;inter3
  108.  
  109.     MVI    A,MODE1        ;Get first mode word
  110.     OUT    MODE
  111.     MVI    A,MODE2        ;Get second mode word
  112.     OUT    MODE
  113.     MVI    A,CMMDB        ;Get command byte
  114.     OUT    CMMD
  115.     RET        ;RETURN TO BSTAM
  116. ;
  117. ;
  118. ;            THIS IS THE STATUS READ PORT ROUTINE.
  119. ;            WHEN EXITING THIS ROUTINE BSTAM EXPECTS IN REGISTER A
  120. ;            THE FOLLOWING BITS TO BE SET IF NEEDED:
  121. ;            1. 20 BIT SET IF FRAMING ERROR
  122. ;            2. 10 BIT SET IF OVERRUN ERROR
  123. ;            3. 08 BIT SET IF PARITY  ERROR
  124. ;            4. 04 BIT SET IF TRANSMITTER EMPTY
  125. ;                IF YOUR UART/USART DOES NOT HAVE TRANSMITTER
  126. ;                EMPTY FEATURE, THEN ALWAYS SET THIS BIT ON.
  127. ;            5. 02 BIT SET IF RECEIVER READY
  128. ;            6. 01 BIT SET IF TRANSMITTER READY
  129. ;            7. DO NOT SET THE 80 BIT OR 40 BIT
  130. ;
  131. ;
  132. ;
  133. INSPRU:
  134.     if    inter3
  135.     MVI    A,UNUM
  136.     OUT    USER        ;Select UART
  137.     endif    ;inter3
  138.  
  139.     IN    STATUS        ;Get status
  140.     ORI    4        ;Force Tx empty high
  141.     RET
  142. ;
  143. ;
  144. ;            YOUR UART/USART MAY NOT NEED TO BE RESET IF FRAMING,
  145. ;            OVERRUN, OR PARITY ERROR IS FOUND. IF THIS IS YOUR
  146. ;            CASE, JUST DO A RETURN.
  147. ;
  148. ;
  149. ;
  150. ;
  151. ERRSTU:
  152.     if    inter3
  153.     MVI    A,UNUM
  154.     OUT    USER        ;Select UART
  155.     endif    ;inter3
  156.  
  157.     MVI    A,ERESET    ;Reset error flags in 2651
  158.     OUT    CMMD
  159.     MVI    A,CMMDB        ;Restore normal operation
  160.     OUT    CMMD
  161.     RET
  162. ;
  163. ;            THIS IS THE READ DATA PORT ROUTINE.
  164. ;            BEFORE THIS ROUTINE IS ENTERED THE 02 BIT OF
  165. ;            STATUS READ ROUTINE MUST HAVE BEEN SET.
  166. ;            DO NOT CLEAR THE 80 BIT FROM THE DATA INPUT PORT.
  167. ;            RETURN WITH REGISTER A LOADED WITH INPUT DATA.
  168. ;
  169. ;
  170. INPRTU:
  171.     if    inter3
  172.     MVI    A,UNUM
  173.     OUT    USER        ;Select UART
  174.     endif    ;inter3
  175.  
  176.     IN    DATA        ;Get data
  177.     RET
  178. ;
  179. ;            THIS IS THE WRITE DATA PORT ROUTINE.
  180. ;            BEFORE THIS ROUTINE IS ENTERED THE 04 BIT AND 01 BIT
  181. ;            OF STATUS READ MUST BE SET.
  182. ;            DO NOT CLEAR THE 80 BIT FROM THE DATA OUTPUT PORT.
  183. ;            REGISTER A CONTAINS THE OUTPUT DATA.
  184. ;
  185. OUTPRU:
  186.     if    inter3
  187.     PUSH    PSW
  188.     MVI    A,UNUM
  189.     OUT    USER        ;Select UART
  190.     POP    PSW
  191.     endif    ;inter3
  192.  
  193.     OUT    DATA        ;Send data
  194.     RET
  195. ;
  196. ;
  197. SIGNON:    PUSH    B        ;Save  the environment
  198.     PUSH    D
  199.     PUSH    H
  200.     LXI    D,MESSGE
  201.     MVI    C,9        ;BDOS display string command
  202.     CALL    BDOS        ;Announce version to user
  203.     POP    H        ;Restore the enviroment
  204.     POP    D
  205.     POP    B
  206.     RET
  207. ;
  208. hexnum    macro    num
  209.     if    (num/16) > 9     
  210.     db    (num/16 and 0fh) + 'A' - 10
  211.     else
  212.     db    (num/16 and 0fh) + '0'
  213.     endif
  214.     if    (num and 0fh) > 9
  215.     db    (num and 0fh) + 'A' - 10
  216.     else
  217.     db    (num and 0fh) + '0'
  218.     endif
  219.     endm
  220.  
  221. MESSGE:    DB    ACR,ALF,ALF
  222.     DB    'Version 4.5, March 29, 1982 by Software Tools',ACR,ALF
  223.     DB    '2651 UART on '
  224.  
  225.     if    sysspt
  226.     DB    'Godbout System Support 1 Board'
  227.     endif    ;sysspt
  228.  
  229.     if    inter3
  230.     DB    'Godbout Interfacer 3 Board'
  231.     endif    ;sysspt
  232.  
  233.     DB    ACR,ALF
  234.     DB    'UART Addressed at ' 
  235.     hexnum    %BASE
  236.     DB    'H, 300 bps, no parity.',ACR,ALF
  237.  
  238.     if    inter3
  239.     DB    'UART Relative User '
  240.     hexnum    %UNUM
  241.     DB    ',',ACR,ALF
  242.     endif    ;inter3
  243.  
  244.     DB    '$'
  245. ;
  246.     END    BEGIN
  247.