home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / sigm / vols000 / vol073 / diablo.asm < prev    next >
Encoding:
Assembly Source File  |  1984-04-29  |  5.7 KB  |  262 lines
  1. ;********************************************************
  2. ;*                            *
  3. ;*        BI-DIRECTIONAL PRINTING DRIVER         *
  4. ;*          FOR DIABLO 1620 OR SIMILAR        *
  5. ;*          DAISYWHEEL PRINTER            *
  6. ;*                            *
  7. ;********************************************************
  8. ;
  9. ;    VERSION:    1.00
  10. ;
  11. ;    DATE:        03/Mar/1980
  12. ;
  13. ;    HISTORY:    Modified for CP/M use 
  14. ;            from PTDOS program
  15. ;            originally published by PROTEUS
  16. ;
  17. ;    Modifications by:
  18. ;            Bill Bolton
  19. ;            Software Tools
  20. ;            P.O. Box 80,
  21. ;            Newport Beach,
  22. ;            NSW, 2106,
  23. ;            Australia
  24. ;
  25. NULL    EQU    000H        ;ASCII NULL
  26. DEL    EQU    07FH        ;ASCII DELETE
  27. CR    EQU    00DH        ;ASCII CARRIAGE RETURN
  28. LF    EQU    00AH        ;ASCII LINE FEED
  29. FF    EQU    00CH        ;ASCII FORM FEED
  30. ESC    EQU    01BH        ;ASCII ESCAPE
  31. HTAB    EQU    009H        ;ASCII HORIZONTAL TAB
  32. SPACE    EQU    020H        ;ASCII ' '
  33. BACKSP    EQU    008H        ;ASCII BACKSPACE
  34. ACK    EQU    006H        ;ASCII ACKNOWLEDGE
  35. ETX    EQU    003H        ;ASCII END OF TEXT
  36. STPORT    EQU    003H        ;HORIZON 1ST SERIAL STATUS
  37. DPORT    EQU    STPORT-1    ;HORIZON 1ST SERIAL DATA
  38. OUTMASK    EQU    001H        ;OUTPUT STATUS MASK
  39. INMASK    EQU    002H        ;INPUT STATUS MASK
  40. COUNT    EQU    150        ;DIABLO BUFFER LENGTH
  41. ;
  42.     ORG    0F200H        ;Or wherever suits
  43. ;
  44. PROCESS:
  45.     MOV    A,C
  46.     CPI    CR        ;CARRIAGE RETURN ?
  47.     JZ    PRINT        ;YES, PRINT OUT THE BUFFER
  48.     CPI    LF        ;LINE FEED ?
  49.     JZ    PUTC        ;YES, SEND IT
  50.     CPI    FF        ;FORM FEED ?
  51.     JZ    PUTC        ;YES, SEND IT
  52.     CPI    DEL        ;DELETE ?
  53.     RZ            ;YES, IGNORE IT
  54.     CPI    NULL        ;NULL ?
  55.     RZ            ;IGNORE IT
  56. ;
  57. PRO2:
  58.     LDA    EOLINE        ;INCREMENT END OF LINE
  59.     INR    A
  60.     STA    EOLINE
  61.     LHLD    TXTPT        ;GET TEXT POINTER
  62.     MOV    M,C        ;CHARACTER WAS IN C
  63.     INX    H        ;BUMP POINTER
  64.     MVI    M,0        ;BUFFER END MARK IS 0
  65.     SHLD    TXTPT        ;STORE POINTER
  66.     RET
  67. ;
  68. ;*    This routine strips leading and lagging blanks from
  69. ;*    the buffer before sending the buffer out to the printer.
  70. ;
  71. ;*    Strip the leading blanks
  72. ;
  73. PRINT:
  74.     LXI    H,BUFFER+1    ;POINT TO 1ST CHARACTER POSITION
  75.     MVI    D,0        ;BLANKS COUNTER
  76.     MVI    A,SPACE        ;BLANK FOR COMPARISION
  77. P1:
  78.     CMP    M        ;BLANK ?
  79.     JNZ    P2        ;NO, STOP COUNTING
  80.     INR    D
  81.     INX    H
  82.     JMP    P1
  83. ;
  84. P2:
  85.     DCX    H        ;POINT TO CHAR-1
  86.     MVI    M,0        ;PUT IN A MARKER
  87.     MOV    A,D        ;GET BLANK COUNT
  88.     STA    BOLINE        ;AND SAVE IT
  89. ;
  90. ;*    Strip the lagging blanks
  91. ;
  92.     LHLD    TXTPT        ;POINT TO BUFFER END MARK
  93.     LDA    EOLINE        ;GET CHARACTER COUNT
  94.     MOV    D,A
  95.     MVI    A,SPACE        ;GET A SPACE
  96. ;
  97. P3:
  98.     DCX    H
  99.     DCR    D        ;BLANK COUNTER
  100.     CMP    M        ;IS IT A SPACE ?
  101.     JZ    P3        ;YES, KEEP COUNTING
  102. ;
  103. P4:
  104.     INX    H        ;NO, BACK UP THE POINTER
  105.     MVI    M,0        ;STORE END MARKER
  106.     MOV    A,D
  107.     STA    EOLINE        ;STORE NEW COUNT
  108.     SHLD    TXTPT        ;STORE NEW BUFER END
  109. ;
  110. ;*    Calculate the most efficient direction to print
  111. ;*    (logic seeking).
  112. ; 
  113. DRCTN:
  114.     LDA    HDPOS        ;GET PRINT HEAD POSITION
  115.     PUSH    PSW        ;SAVE IT
  116.     LXI    H,BOLINE    ;POINT TO BEGINNING OF LINE
  117.     SUB    M        ;FIND THE DIFFERENCE
  118.     CM    ABSVAL        ;TAKE THE ABSOLUTE VALUE
  119.     MOV    B,A        ;SAVE IT IN B
  120.     INX    H        ;GET THE END OF LINE
  121.     POP    PSW        ;GET HEAD POSITION
  122.     SUB    M        ;FIND THE DIFFERENCE
  123.     CM    ABSVAL        ;TAKE THE ABSOLUTE VALUE
  124.     SUB    B        ;COMPARE DISTANCE TO BOL AND EOL
  125.     JP    MFWRD        ;IF PLUS FORWARD IS FASTER
  126. ;
  127. ;*    Print backwards
  128. ;
  129. MBWRD:
  130.     MVI    D,'6'        ;DIABLO BACKWARD PRINT CODE
  131.     LDA    EOLINE        ;GET END OF LINE
  132.     CALL    ALIGN        ;PROCESS THE DATA
  133.     LDA    BOLINE        ;POSITION OF 1ST BUFFER CHARACTER
  134.     ORA    A        ;IS IT THE ZERO POSITION
  135.     JZ    MB2        ;YES, CANT TAB LEFT OF MARGIN
  136.     DCR    A
  137. ;
  138. MB2:
  139.     STA    HDPOS        ;UPDATE HEAD POSITION
  140.     LXI    D,-1
  141.     LHLD    TXTPT        ;POINT TO END OF BUFFER
  142.     JMP    PRLINE        ;PRINT THE BUFFER
  143. ;
  144. ;*    Print forwards
  145. ;
  146. MFWRD:
  147.     MVI    D,'5'        ;DIABLO FORWARD PRINT CODE
  148.     LDA    BOLINE        ;GET BEGINNING OF LINE
  149.     CALL    ALIGN
  150.     LDA    EOLINE        ;GET LAST CHARACTER POSITION
  151.     INR    A
  152.     STA    HDPOS        ;SAVE NEW HEAD POSITION
  153.     LXI    H,BUFFER    ;POINT TO BUFFER START
  154.     LDA    BOLINE        ;COMPUTE POSITION OF 1ST NON BLANK
  155.     MVI    D,0
  156.     MOV    E,A
  157.     DAD    D
  158.     LXI    D,1        ;SET UP TO READ BUFFER FORWARD
  159. ;
  160. ;*    Print the buffer
  161. ;
  162. PRLINE:
  163.     DAD    D        ;BUMP    HL
  164.     MOV    A,M        ;MOVE CHARACTER IN BUFFER TO A
  165.     ORA    A        ;END OF BUFFER ?
  166.     JZ    CLRBUF        ;YES, GO CLEAN UP
  167.     CALL    PUTC        ;PRINT THE CHARACTER
  168.     JMP    PRLINE
  169. ;
  170. ;*        Align the Print Head to the correct position
  171. ;*        to start printing
  172. ;
  173. ;*        NOTE: The diablo 1610/1620 can only do an
  174. ;*        "absolute tab" to the first 126 character
  175. ;*        positions.
  176. ;
  177. ;*        D = Direction of printing
  178. ;*        A = BOLINE or EOLINE
  179. ;
  180. ALIGN:
  181.     MOV    E,A        ;SAVE BOLINE/EOLINE
  182.     MVI    A,ESC        ;GET "COMMAND" CODE
  183.     CALL    PUTC        ;SEND IT
  184.     MOV    A,D        ;GET THE DIRECTION CODE
  185.     CALL    PUTC        ;SEND IT
  186. ;
  187.     MVI    A,ESC        ;GET "COMMAND" CODE
  188.     CALL    PUTC        ;SEND IT
  189.     MVI    A,HTAB        ;GET ABSOLUTE TAB CODE
  190.     CALL    PUTC        ;SEND IT
  191.     MOV    A,E        ;GET LOCATION TO TAB TO
  192.     ADI    1        ;ADD TO SATISFY DIABLO
  193.     JMP    PUTC        ;SEND IT AND RETURN
  194. ;
  195. CLRBUF:
  196.     LXI    H,BUFFER+1    ;CLEAR BUFFER
  197.     SHLD    TXTPT
  198.     XRA    A
  199.     STA    EOLINE        ;RESET COUNTERS
  200.     STA    BOLINE
  201.     STA    BUFFER+1
  202.     RET
  203. ;
  204. ABSVAL:
  205.     CMA            ;TAKE THE ABSOLUTE VALUE
  206.     INR    A
  207.     RET
  208. ;
  209. PUTC:
  210.     MOV    C,A
  211.     CALL    OUTPUT        ;SEND THE CHARACTER
  212.     CPI    ESC        ;WAS IT AN ESCAPE?
  213.     JZ    ESCSEQ        ;YES, NEEDS SPECIAL TREATMENT
  214.     LDA    OUTCNT        ;CHARS SENT SINCE O/P COUNT RESET
  215.     DCR    A
  216. STORE:
  217.     STA    OUTCNT        ;SAVE UPDATED COUNT
  218.     RNZ            ;NO, RETURN
  219.     MVI    A,COUNT        ;SET COUNT
  220.     STA    OUTCNT
  221.     MVI    C,ETX        ;YES, GET ETX
  222.     CALL    OUTPUT        ;SEND IT
  223. ACKLOOP:
  224.     CALL    INPUT        ;GET CHARACTER FROM PRINTER
  225.     CPI    ACK        ;DIABLO SENDS ACK WHEN IT GETS ETX
  226.                 ;FROM ITS CHARACTER BUFFER
  227.     JNZ    ACKLOOP        ;NOT FOUND, KEEP LOOKING
  228.     RET
  229. ;
  230. ESCSEQ:
  231.     LDA    OUTCNT        ;GET OUTPUT COUNT
  232.     ADI    2        ;MAKE SURE NEXT TWO CHARS,
  233.     JMP    STORE        ;GET SENT BEFORE ETX
  234. ;
  235. OUTPUT:
  236.     IN    STPORT        ;1ST SERIAL PORT
  237.     ANI    OUTMASK
  238.     JZ    OUTPUT
  239.     MOV    A,C
  240.     OUT    DPORT
  241.     RET
  242. ;
  243. INPUT:
  244.     IN    STPORT
  245.     ANI    INMASK
  246.     JZ    INPUT
  247.     IN    DPORT
  248.     ANI    07FH
  249.     RET
  250. ;
  251. ;
  252. HDPOS    DB    0        ;CURRENT HEAD POSITION
  253. BOLINE    DB    0        ;BEGINNING OF LINE POINTER
  254. EOLINE    DB    0        ;END OF LINE POINTER
  255. TXTPT    DW    BUFFER+1    ;BUFFER POINTER
  256. OUTCNT    DB    COUNT        ;CHARACTERS SENT TO PRINTER
  257. ;
  258. BUFFER    DW    0000H
  259.     DS    160        ;CHARACTER BUFFER
  260. ;
  261.     END    PROCESS
  262.