home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / sigm / vols000 / vol040 / mds.z80 < prev    next >
Encoding:
Text File  |  1984-04-29  |  13.1 KB  |  637 lines
  1. ; INTEL MDS FDC CARD EMULATOR
  2. ;
  3. ; SOURCED NOV 79 BY TREVOR MARSHALL
  4. ;            Dept E & E Eng
  5. ;            University of West Australia
  6. ;            NEDLANDS, W.A. 6009
  7. ;
  8. ; This version of the source produces, after linking,
  9. ; object code in memory from 600H to A000H to enable
  10. ; a Prom Programmer resident in the host system
  11. ; to directly program the object file
  12. ;
  13. ; A version ORGed at F800H is compiled seperately
  14. ; and is provided on the master disk as MDSABS.Z80
  15. ;
  16. ;
  17. ; REGISTER USAGE DURING READ AND WRITE:
  18. ; D contains the (auto wait) drive control byte
  19. ; IX points to the IOPB base
  20. ; HL points to the current memory DMA address
  21. ; B contains the input byte counter for INI & OUTI
  22. ; C contains DDATA for INI & OUTI
  23. ; B' (alternate) contains the number of records required
  24. ; D' (alternate) contains the current sector address
  25. ; E' (alternate) contains the retry count
  26. ; H' (alternate) contains the previously logged track
  27. ; AF' (alternate) contains the previous drive mask
  28. ; to skip read trk# if it is already logged
  29. ; and allow for fast response without interleaving
  30. ;
  31. ; FDC CONTROLLER DEFINITIONS:
  32. DCONTROL:EQU    63H    ;Control Port
  33. DFLAGS:     EQU    63H    ;FDC Status Port
  34. DDATA:   EQU    67H    ;1793 Data Port
  35. DSTATUS: EQU    64H    ;1793 Status Port
  36. DCOMMAND:EQU    64H    ;1793 Command Port
  37. DTRACK:     EQU    65H    ;1793 Track Port
  38. DSECTOR: EQU    66H    ;1793 Sector Port
  39. DSIDE:    EQU    4    ;Bit 1=0 selects side 1
  40.             ; of D/S drives
  41. ;
  42. ; DISK CONTROL PORT HARDWARE ENVIRONMENT
  43. ; Bits 0-3 select drives 1-4
  44. ; Bit 7 enables auto wait on accesses to DDATA
  45. ; Bit 5 enables dsk drive motors 
  46. ; Bit 4 selects single density (S/D)
  47. ;
  48. ; DISK STATUS PORT HARDWARE REQUIREMENTS
  49. ; Bit 0 is 1793 INTREQ status output
  50. ; Bit 5 indicates head is loaded
  51. ;
  52. ; DISK DENSITY DEFINITIONS
  53. MAXSECTORS: EQU 1AH  ;Single Density
  54. MAXTRACKS:   EQU 4CH  ; 8" Disks
  55. ;
  56. ; PIO DEFINITIONS:
  57. ACOMMAND:EQU    7AH
  58. ADATA:   EQU    78H
  59. BCOMMAND:EQU    7BH
  60. BDATA:   EQU    79H
  61. ;
  62. ; BUS CONTROL:
  63. RELEASE: EQU    7FH    ;I/O To this addr releases bus
  64. HOLD:    EQU    7CH    ;I/O to this addr requests bus
  65. ;
  66. ; MDS PORT DEFINITIONS:
  67. STATUS:  EQU    7EH    ;S100 Bus reads 78H
  68. ;Note that port 78H is referenced directly in ASERVICE
  69. ;TYPE:    Not Implemented
  70. RESULT:  EQU    7DH    ;S100 Bus reads 7BH
  71. ;RESET: Not Implemented
  72. IOPBLOW: EQU    79H
  73. IOPBHIGH:EQU    7AH
  74. ;
  75. ; DISKETTE INSTRUCTION CODES:
  76. NOP:     EQU    0    
  77. SEEK:     EQU    1
  78. FORMAT:     EQU    2
  79. RECALIB: EQU     3
  80. READ:     EQU    4
  81. VERIFY:     EQU    5
  82. WRITE:     EQU    6
  83. WRITEDEL:EQU    7    ;Write deleted data mark;
  84. ;
  85. ; AS THERE IS NO STACK RAM AVAILABLE ALL CODE
  86. ; MUST BE SEQUENTIAL
  87. ;
  88. ; THE PROM PROGRAMMER REQUIRES AN ADDRESS OFFSET
  89. ; OF 0F200H FOR THIS ORG 0F800H CODE
  90. ;
  91. ; THE FOLLOWING MACROS FORM COMMONLY USED ROUTINES
  92. ;
  93. STOP:    MACRO
  94.     LD    SP,STACK; Point at ROM stack
  95.     IN    A,RELEASE
  96.     RETI
  97.     MEND
  98. DONE: MACRO   ;Set up status port & stop
  99.     LD    A,0FH
  100.     OUT    STATUS,A
  101.     STOP
  102.     MEND
  103. ;
  104. INTREQ:    MACRO    ;Wait for intreq
  105. LL#SYM:    IN    A,DFLAGS ;Loop until 1793 INTREQ active
  106.     RRA
  107.     JR    NC,LL#SYM
  108.     MEND
  109. ;
  110. ERRORS: MACRO    #LOOP,#MASK ;Check 1793 for errors
  111.     INTREQ
  112.     IN    A,DSTATUS
  113.     EXX    ;Save working registers
  114.     LD    C,A    ;Save error byte
  115.     AND    80H    ;Not ready mask
  116.     EXX
  117.     JR    NZ,#LOOP    ;Loop until drive ready
  118.     EXX
  119.     LD    A,C
  120.     AND    #MASK    ;General error mask
  121.     JP    NZ,SELECT+OFFSET ;Retry if any errors
  122.     EXX
  123.     MEND
  124. ;
  125. SETUP:    MACRO    ;Set up read and write common parameters
  126. LP:    DL    AA#SYM
  127. AA#SYM:    INC    D    ;Sector #
  128.     LD    A,D
  129.     OUT    DSECTOR,A
  130.     EXX
  131.     LD    A,D
  132.     OUT    DCONTROL,A
  133.     LD    B,80H    ;Input byte count
  134.     IN    A,DFLAGS ;Is head loaded?
  135.     AND    20H
  136.     JR    Z,J2#SYM ;No
  137.     LD    A,0
  138.     JR    J3#SYM
  139. J2#SYM: LD    A,04H    ;Head load mask for 1793
  140. J3#SYM    DL    $
  141.     MEND
  142. ;
  143. CHECK:    MACRO    ;See if read or write is complete
  144.     EXX
  145.     DJNZ    LP
  146.     EXX
  147.     LD    B,0    ;Done
  148.     JP    FINISH+OFFSET
  149.     MEND
  150. ;
  151. ; NOTE THAT THE 1793 NEEDS TIME TO CALCULATE CRC
  152. ; BEFORE THE ERROR STATUS IS AVAILABLE
  153. ; IF THE DRQ IS NOT SERVICED
  154. ; The following delay loop is sufficient (4MHz Z-80)
  155. DELAY:    MACRO
  156.     LD    B,30H    ;12 to 15 give CRC errors
  157. ; 0 to 12 give BUSY flag
  158.     DJNZ    $
  159.     MEND
  160. ;
  161. ; Check for 1793 errors during read and write
  162. DERROR: MACRO    #MASK
  163.     INTREQ
  164.     IN    A,DSTATUS
  165.     EXX
  166.     LD    C,A    ;Save error byte
  167.     EXX
  168. ; Note that we will not check for deleted data marks
  169.     AND    #MASK
  170.     JP    NZ,S2+OFFSET ; Retry errors
  171.     MEND
  172.  
  173. ; LINKER AND PROM PROGRAMMER CODE REQUIREMENTS
  174.     ORG    100H
  175.     JP    0
  176. OFFSET: EQU    0F800H-600H
  177. ; Setup vectors at top of ROM
  178.     ORG    9F4H    ;Effectively FBF4
  179. VEC1:    DW    ASERVICE+OFFSET
  180. VEC2:    DW    BSERVICE+OFFSET
  181. WAIT:    EI
  182.     HALT    ;wait for interrupt
  183. ; STACK: To enable interrupt structure we need a 'stack'
  184.     DW    WAIT+OFFSET
  185. STACK:    EQU    $+OFFSET
  186.     DW    WAIT+OFFSET 
  187.     DW    WAIT+OFFSET
  188. ;
  189. ; Hardware Reset Code
  190.     ORG    600H
  191. START:    JP    0F804H
  192.     NOP
  193. ; The ORG address is now effectively F804H
  194. ; Now setup PIO & Interupts
  195. ;
  196.     IM2
  197.     LD    A,0FBH
  198.     LD    I,A    ;Int vector table near FBF2
  199.     LD    A,0F4H    ;IVEC(A) = FBF4
  200.     OUT    ACOMMAND,A
  201.     LD    A,0F6H    ;IVEC(B) = FBF6
  202.     OUT    BCOMMAND,A
  203.     LD    A,4FH    ;MODE 1
  204.     OUT    ACOMMAND,A
  205.     OUT    BCOMMAND,A
  206.     IN    A,ADATA    ;Set READY handshake
  207.     IN    A,BDATA
  208.     LD    A,87H    ;Enable PIO interrupt mode
  209.     OUT    ACOMMAND,A
  210.     OUT    BCOMMAND,A
  211. ; Now setup output latches
  212.     LD    A,00
  213.     OUT    RESULT,A
  214.     LD    A,0BH    ;:F0:,:F1: ready, not D/D
  215.     OUT    STATUS,A
  216.     EX    AF,AF'
  217.     LD    A,0    ;Clear drive select mask
  218.     EX    AF,AF'
  219.     EXX
  220.     LD    H,0FFH    ;Clear logged trk
  221.     EXX
  222.     LD    SP,STACK
  223.     EI
  224.     HALT
  225. ; Routine to service PIO inputs
  226. ; (79) go to IX lower, (7A) to IX upper
  227. ;
  228. ASERVICE: DI
  229.     OUT    HOLD,A    ; Lock out bus until done
  230.     NOP    ;Allow time for bus control
  231.     NOP
  232.     IN    A,78H ; S100 Status port read (& reset)
  233. ;              ; must be done during bus access
  234.     IN    A,ADATA
  235.     LD    IX,0
  236.     LD    C,A
  237.     LD    B,0
  238.     ADD    IX,BC    ;Now have A in IX
  239.     STOP
  240. BSERVICE: DI
  241.      OUT    HOLD,A    ; Lock out bus until done
  242.     IN    A,BDATA
  243.     LD    B,A
  244.     LD    C,0
  245.     ADD    IX,BC    ; IX now points to IOPB
  246. ; Now select side 0 of disks
  247.     LD    A,2    ;Set bit 1
  248.     OUT    DSIDE,A
  249. ;
  250.     EXX
  251.     LD    E,0AH    ;10 retries
  252.     JR    SELECT
  253. ;
  254. ; NOW BEGIN DECODING COMMAND WORD
  255. ; 
  256. ; FIRST SELECT THE DRIVE (:F0:=A:, :F1:=C:)
  257. ;
  258. S2:    EXX
  259.     LD    H,0FFH    ;Log off track if error occurs
  260. ;            ;This will cause a RESTORE cmd
  261. ;            ;To be executed for SEEK errors
  262. SELECT:    LD    A,E
  263.     CP    0    ;Have we retried 10 times?
  264.     LD    A,C    ;Error byte
  265.  
  266.     JP    Z,EXIT+OFFSET
  267.     DEC    E
  268.     EXX
  269.     LD    A,(IX+0)
  270.     AND    3FH ;Check for acceptable channel word
  271.     JP    NZ,CHERROR+OFFSET ; Channel error
  272. ;
  273. ;If the op is NOP,FORMAT or RECALIBRATE 
  274. ;Dont check address field
  275.     LD    A,(IX+1)
  276.     AND    07H    ;Now have opcode field
  277.     CP    1    ;Seek
  278.     JR    Z,DONTSKIP
  279.     SUB    4
  280.     JR    C,SKIP    ; <=3
  281. DONTSKIP:
  282.  
  283. ; Now check for valid IOPB addresses
  284. N12:    LD    A,(IX+3) ;Track address
  285.     SUB    MAXTRACKS+1  ;max track # + 1
  286.     JP    NC,ADDERROR+OFFSET
  287.     LD    A,(IX+4)
  288. ;
  289. ; Must reset bits 4 & 5 of sector byte (a drive select bit)
  290. ; to retain compatibility with S/D MDS systems
  291.     AND    A,09FH
  292.     JP    Z,ADDERROR+OFFSET ;Zero sector #
  293.     SUB    MAXSECTORS+1 ;Max sector # + 1
  294.     JP    NC,ADDERROR+OFFSET
  295.     LD    A,(IX+4) ;Sector addr
  296. ;
  297. ; Must reset bit 5 of sector byte (a drive select bit)
  298. ; to retain compatibility with S/D MDS systems
  299.     AND    A,09FH
  300.     LD    C,(IX+2) ;Number of records requested
  301.     ADD    A,C
  302.     SUB    A,MAXSECTORS+2
  303.     JP    NC,ADDERROR+OFFSET ;Final sector >1AH
  304. ; Address errors trapped, now seek to required track
  305. ;
  306. SKIP:    LD    A,(IX+1) ;Instruction word
  307.     AND    30H    ;Get drive mask
  308.     RRC    A
  309.     RRC    A
  310.     RRC    A
  311.     RRC    A
  312.     CP    3 ; S/D MDS drive #1 mask
  313.     JR    Z,BSELECT ;Select drive B
  314. ; Dont allow for more than 2 drives
  315.     LD    D,0B1H    ;Auto wait,motor on,S/D,A:
  316.     JR    J3
  317. BSELECT: LD    D,0B2H    ;Auto wait,motor on,S/D,B:
  318. ; D contains the drive control byte with auto wait set
  319. ;
  320. ; Now check for recalibrate, nop & format instructions
  321. ;
  322. J3:    LD    A,(IX+1)
  323.     AND    07H
  324.     CP    RECALIB    
  325.     JR    Z,RESTORE
  326.     CP    NOP
  327.     JR    Z,DONOP
  328.     CP    FORMAT
  329.     JR    Z,DONOP
  330.     JR    DOSEEK;Not one of these ops
  331. DONOP:    LD    B,0
  332.     JP    FINISH+OFFSET
  333. RESTORE: LD    A,D    ;Drive control byte
  334.     AND    7FH    ;Reset auto wait
  335.     OUT    DCONTROL,A
  336.      LD    A,0DH    ;1793 Restore command
  337.     OUT    DCOMMAND,A
  338.     ERRORS    RESTORE,99H
  339.     LD    B,0
  340.     JP    FINISH+OFFSET
  341. ;
  342. DOSEEK:     ;Read, write, verify & seek
  343.         ;all require a seek op first
  344. ; Now check if drive is logged
  345. ; trk # will then be available without the read addr op
  346. ;
  347.     EX    AF,AF'
  348.     CP    A,D    ;Is it the same as the last?
  349.     LD    A,D
  350.     JR    NZ,LOG    ;No, log it
  351.     EX    AF,AF'
  352.     EXX
  353.     LD    A,H    ; fetch last trk #
  354.     EXX
  355.     LD    B,A    ;Save it
  356.     CP    (IX+3) ;Is the desired trk the same?
  357.     JR    NZ,LOG2 ;No, read address
  358.     JP    LOGGED+OFFSET
  359. ; Check current track # by reading address from disk
  360. ;NOTE THAT THE 1793 DOES NOT HEAD LOAD ON 'READ ADDRESS'
  361. ; IF THE READY INPUT IS NOT ACTIVE
  362. ; so we must issue a dummy SEEK command first
  363. ;
  364. LOG:    EX    AF,AF'
  365. ; Will first execute a RESTORE command on the new drive
  366. REST1:    LD    A,D
  367.     AND    7FH    ;Reset auto wait
  368.     OUT    DCONTROL,A
  369.     LD    A,0DH    ;1793 Restore command
  370.     OUT    DCOMMAND,A
  371.     ERRORS    REST1,99H
  372. ;
  373. ; Now seek to desired track
  374. LOG2:    LD    A,D
  375.     AND    7FH    ;Reset auto wait
  376.     OUT    DCONTROL,A
  377.     IN    A,DTRACK
  378.     OUT    DDATA,A ;desired trk=current one
  379. L3:    LD    A,1AH   ;Seek, no verify
  380.     OUT    DCOMMAND,A
  381.     ERRORS    LOG2,99H
  382. ;
  383. L2:    LD    A,0C4H    ;1793 Read address cmd
  384.     OUT    DCOMMAND,A
  385.   ;Discard the data bytes
  386.     INTREQ
  387.     DELAY
  388.     IN    A,DSTATUS
  389.     AND    19H    ; status would not be valid
  390.     JR    NZ,L2
  391.     IN    A,DSECTOR   ;where the 1793 puts the trk
  392.     LD    B,A      ;Save it
  393.     EXX
  394.     LD    H,A    ; log it
  395.     EXX
  396. ;
  397. ; Now must clear the data request by reading DDATA
  398.     IN    A,DDATA
  399. ;
  400. LOGGED:    LD    A,B    ;Fetch current track addr
  401.     CP    (IX+3)  ;Is it the same?
  402.     OUT    DTRACK,A
  403.     JR    Z,J11    ;Yes, skip read addr
  404.     LD    A,(IX+3)
  405.     OUT    DDATA,A
  406. S1:    LD    A,D
  407.     AND    7FH
  408.     OUT    DCONTROL,A ;Disable auto wait
  409.     LD    A,1DH    ;Seek with verify
  410.     OUT    DCOMMAND,A
  411.     ERRORS    S1,99H
  412. ; Now have desired track, check to see if op was seek
  413. ;
  414. J11:    LD    A,(IX+1)
  415.     AND    07H
  416.     CP    SEEK
  417.     JP    Z,FINISH+OFFSET ; was seek only
  418. ;
  419. ; Now calculate the number of records
  420. ; and setup dedicated register values
  421. ;
  422.     EXX
  423.     LD    B,(IX+2)  ;Number of records
  424.     LD    A,(IX+4)
  425. ;
  426. ; Must reset bit 5 of sector byte (a drive select bit)
  427. ; to retain compatibility with S/D MDS systems
  428.     LD    D,09FH
  429.     AND    A,D
  430.     LD    D,A
  431.     DEC    D     ;Initial sector (-1 for SETUP)
  432.     EXX
  433. ;
  434.     LD    H,(IX+6) 
  435.     LD    L,(IX+5)
  436.     LD    C,DDATA
  437. ;
  438. ; Was it a read, write or writedel operation?
  439.     LD    A,(IX+1)
  440.     AND    07H
  441.     CP    READ
  442.     JR    Z,DOREAD
  443.     CP    WRITE
  444.     JP    Z,DOWRT+OFFSET
  445.     CP    WRITEDEL
  446.     JP    Z,DOWRTDEL+OFFSET
  447.     CP    VERIFY
  448.     JP    DOVERIFY+OFFSET
  449. ;
  450. DOREAD: EXX
  451.     SETUP
  452.     ADD    A,88H    ;1797 Read command
  453.     OUT    DCOMMAND,A
  454. J13:    IN    A,DFLAGS
  455.     RRA
  456.     JR    C,J12 ;INTREQ = error or read complete
  457.     INI
  458.     JP    NZ,J13+OFFSET ;Fetch next data byte
  459. ; Z set when B=0, ie 128 bytes have been read
  460. J12:    DERROR    9DH
  461.     CHECK
  462. ;
  463. DOVERIFY: EXX    ;Similar to DOREAD
  464.     SETUP
  465.     ADD    88H    ;1797 compatible
  466.     OUT    DCOMMAND,A
  467. J14:    IN    A,DFLAGS
  468.     RRA
  469.     JR    C,J15
  470.     IN A,(C)    ;Discard input data
  471.     JP    J14+OFFSET
  472. J15:    DERROR    9DH
  473.     CHECK
  474. ;
  475. DOWRT:    EXX    ;Similar to read in structure
  476.     SETUP
  477.     ADD    A,0A8H    ;1797 compatible
  478.     OUT    DCOMMAND,A
  479. J16:    IN    A,DFLAGS
  480.     RRA
  481.     JR    C,J17
  482.     OUTI
  483.     JP    NZ,J16+OFFSET
  484. J17:    DERROR 0FDH
  485.     CHECK
  486. ;
  487. DOWRTDEL: EXX
  488.     SETUP
  489.     ADD    A,0A9H    ;1797 compatible
  490.     OUT    DCOMMAND,A
  491. J20:    IN    A,DFLAGS
  492.     RRA
  493.     JR    C,J19
  494.     OUTI
  495.     JP    NZ,J20+OFFSET
  496. J19:    DERROR    0FDH
  497.     CHECK
  498. ;
  499. ; Address and Channel error routines
  500. ;
  501. ;THIS ENTRY IS VALID DURING ERROR TRAPS
  502. A1:    LD    A,08H
  503.     OUT    RESULT,A
  504.     JP    STAT+OFFSET
  505. ;
  506. ; 1793 Error exit routines
  507. ;
  508. ; Will print out error messages for ease of debugging
  509. ; Will use the RST7,RST6 area of RAM for stack
  510. ;
  511. EXIT:    EXX
  512.     LD    SP,0038H ; Out of ISIS area
  513.     PUSH    AF
  514.     CALL    PMSGFOLLOWING+OFFSET
  515.     DB    0DH,'1793',0A0H
  516.     POP    AF
  517.     PUSH    AF
  518.     CALL    P2HEX+OFFSET
  519.     CALL    PRINTIOPB+OFFSET
  520.     POP    AF
  521.     LD    B,0    ;Use B to hold result byte
  522.     BIT    0,A
  523.     JR    Z,J5
  524.     SET    0,B
  525.     SET    7,B
  526. J5    BIT    1,A    ;DRQ error
  527.     JR    Z,J6
  528.     SET    4,B
  529. J6:    BIT    2,A    ;Lost data
  530.     JR    Z,J7
  531.     SET    4,B
  532. J7:    BIT    3,A    ;CRC
  533.     JR    Z,J8
  534.     SET    1,B
  535. J8:    BIT    4,A    ;Seek error
  536.     JR    Z,J9
  537.     SET    2,B
  538. J9:    BIT    6,A
  539.     JR    Z,FINISH
  540.     SET    5,B
  541. FINISH:    LD    A,B
  542.     OUT    RESULT,A
  543. ; The following code has been nulled as it
  544. ; causes the motors to 'cycle' in speed too much.
  545. ; A delayed turnoff is needed
  546. ; Switch off the drive motors
  547. ;    LD    A,D
  548. ;    AND    5FH    ;motors + wait off
  549. ;    OUT    DCONTROL,A
  550. STAT:    DONE
  551. ;
  552. ; OUTPUT MESSAGE ROUTINES
  553. PRINTIOPB: CALL    PMSGFOLLOWING+OFFSET
  554.     DB    ' ERROR, IOPB A',0D4H
  555.     PUSH    IX
  556.     POP    HL
  557.     CALL    SPACE+OFFSET
  558.     CALL    PMSGFOLLOWING+OFFSET
  559.     DB    ', CONTENTS:',0A0H
  560.     LD    A,(IX+0)
  561.     CALL    P2HEX+OFFSET
  562.     LD    A,(IX+1)
  563.     CALL    P2HEX+OFFSET
  564.     LD    A,(IX+2)
  565.     CALL    P2HEX+OFFSET
  566.     LD    A,(IX+3)
  567.     CALL    P2HEX+OFFSET
  568.     LD    A,(IX+4)
  569.     CALL    P2HEX+OFFSET
  570.     LD    L,(IX+6) ;Print in reverse order
  571.     LD    H,(IX+5)
  572.     CALL    SPACE+OFFSET
  573.     CALL    PMSGFOLLOWING+OFFSET
  574.     DB    0DH,8AH
  575.     RET
  576. ADDERROR: LD    SP,0038H ;Not in ISIS area
  577.     CALL    PMSGFOLLOWING+OFFSET
  578.     DB    0DH,'ADDRESS',0A0H
  579.     CALL    PRINTIOPB+OFFSET
  580.     JP    A1+OFFSET
  581. CHERROR: LD    SP,0038H
  582.     CALL    PMSGFOLLOWING+OFFSET
  583.     DB    0DH,'CHANNEL',0A0H
  584.     CALL    PRINTIOPB+OFFSET
  585.     JP    A1+OFFSET
  586. PMSG:    PUSH    AF
  587. PS1:    LD    A,(HL)
  588.     INC    HL
  589.     CALL    PCHR+OFFSET
  590.     RLA
  591.     JR    NC,PS1
  592.     POP    AF
  593.     RET
  594. PMSGFOLLOWING:
  595.     EX    (SP),HL
  596.     CALL    PMSG+OFFSET
  597.     EX    (SP),HL
  598.     RET
  599. PCHR:    PUSH    AF
  600. ;SJ2:    IN    A,0F7H    ;CRT STATUS
  601. ;    AND     1
  602. ;    JR    Z,SJ2
  603. ;    POP    AF
  604. ;    PUSH    AF
  605. ;    OUT    0F6H,A    ;CRT DATA
  606. SJ1:    IN    A,0FBH    ;PRINTER STATUS
  607.     AND    1
  608.     JR    Z,SJ1
  609.     POP    AF
  610.     OUT    0FBH,A    ;PRINT DATA
  611.     RET
  612. SPACE:    LD    A,20H
  613.     CALL    PCHR+OFFSET
  614.     LD    A,H
  615.     CALL    P2HEX+OFFSET
  616.     LD    A,L
  617. P2HEX: PUSH    AF
  618.     LD    A,20H
  619.     CALL    PCHR+OFFSET
  620.     POP    AF
  621.      CALL    P1HEX+OFFSET
  622.     RRA
  623. P1HEX:    RRA
  624.     RRA
  625.     RRA
  626.     RRA
  627.     PUSH    AF
  628.     AND    0FH
  629.     CP    10
  630.     JR    C,PH1
  631.     ADD    7
  632. PH1:    ADD    30H
  633.     CALL    PCHR+OFFSET
  634.     POP    AF
  635.     RET
  636.     END    START
  637.