home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / sigm / vols000 / vol020 / vector.z80 < prev    next >
Encoding:
Text File  |  1984-04-29  |  2.8 KB  |  186 lines
  1.     TITLE VECTOR SUBSYSTEM OF SYSTEM MONITOR RELEASE A
  2. ;  ******Donated to the Pascal/Z Users Group,July 1980*****
  3. ;    INTEL I/O STANDARD VECTOR SUBSYSTEM
  4. ;    FOR THE SYSTEM MONITOR
  5. ;
  6. ;    MODIFIED FOR C-MACRO ASSEMBLER MAY 1979
  7. ;
  8. ;
  9. ;    EXTERNAL LINKAGES
  10. ;
  11. ;MBASE IS MONITOR BASE
  12. ;CBASE IS CONSOLE SUBSYSTEM BASE
  13. ;TBASE IS CASSETTE SUBSYSTEM BASE
  14. ;WBASE IS MONITOR WORK SPACE
  15. ;
  16. ;
  17. ;    LINKAGES TO CONSOLE SUBSYSTEM
  18. ;
  19. CSTATS    DEFL    CBASE+3
  20. CKEYIN    DEFL    CBASE+6
  21. CLISTR    DEFL    CBASE+0CH
  22. CVOUT    DEFL    CBASE+18H
  23. ;
  24. ;    LINKAGES TO CASSETTE SUBSYSTEM
  25. ;
  26. TSAVE    DEFL    TBASE+3
  27. TLOAD    DEFL    TBASE+6
  28. ;
  29. ;    LINKAGES TO MONITOR
  30.  
  31. MSTRT    DEFL    MBASE
  32. MRSTRT    DEFL    MBASE+3
  33. MMEMRY    DEFL    MBASE+6
  34.  
  35. ;START OF MONITOR CODE
  36. ;
  37. VBASE    EQU    $
  38. ;
  39. ;    EXTERNAL ENTRY VECTORS
  40. ;
  41. ;    INTEL STANDARD I/O
  42. ;
  43. VNTRY0    JP    MSTRT    ;COLD START OF MONITOR
  44. VNTRY1    JP    CINP    ;CONSOL INPUT
  45. VNTRY2    JP    RINP    ;READER INPUT
  46. VNTRY3    JP    COUT    ;CONSOL OUTPUT
  47. VNTRY4    JP    POUT    ;PUNCH OUTPUT
  48. VNTRY5    JP    LOUT    ;LINE PRINTER OUTPUT
  49. VNTRY6    JP    CSTA    ;CONSOL STATUS
  50. VNTRY7    JP    IOCH    ;I/O CHECK
  51. VNTRY8    JP    IOST    ;I/O SET
  52. VNTRY9    JP    MTST    ;MEMORY TEST
  53. VNTRYA    JP    MRSTRT    ;WARM START OF MONITOR
  54. ;
  55. ;    SUBSYSTEM BASE ADDRESSES
  56. VCADDR    DEFW    CBASE    ;CONSOLE SUBSYSTEM BASE ADDR
  57. VTADDR    DEFW    TBASE    ;CASSETTE SUBSYSTEM BASE ADDR
  58. VDADDR    DEFW    DBASE    ;DISK SUBSYSTEM BASE ADDR
  59. ;
  60. VWORK    DEFW    WBASE    ;MONITOR VARIABLE BASE ADDRESS
  61. ;
  62. ;
  63. ;    INTEL I/O ENTRY VECTORS
  64. ;
  65. ZCIV    DEFW    ZSKEY    ;TTY
  66.     DEFW    ZSKEY    ;CRT
  67.     DEFW    ZSKEY    ;BATCH
  68.     DEFW    ZSKEY    ;USER
  69. ZRIV    DEFW    ZCASI    ;TTY
  70.     DEFW    ZCASI    ;HI-SP TAPE
  71.     DEFW    ZCASI    ;CASSTTE
  72.     DEFW    ZCASI    ;USER
  73. ZCOV    DEFW    ZVIDEO    ;TTY
  74.     DEFW    ZVIDEO    ;CRT
  75.     DEFW    ZPRTR    ;BATCH
  76.     DEFW    ZVIDEO    ;USER
  77. ZPOV    DEFW    ZCASO    ;TTY
  78.     DEFW    ZCASO    ;HI-SP TAPE
  79.     DEFW    ZCASO    ;CASSETTE
  80.     DEFW    ZCASO    ;USER
  81. ZLOV    DEFW    ZPRTR    ;TTY
  82.     DEFW    ZVIDEO    ;CRT
  83.     DEFW    ZPRTR    ;PRINTER
  84.     DEFW    ZPRTR    ;USER
  85. ZSTV    DEFW    ZSTAT    ;TTY
  86.     DEFW    ZSTAT    ;CRT
  87.     DEFW    ZSTAT    ;BATCH
  88.     DEFW    ZSTAT    ;USER
  89. ;
  90. ;    INTEL ENTRY ROUTINES
  91. ;
  92. CINP    CALL    ZENTRY
  93.     AND    03H
  94.     LD    HL,ZCIV
  95.     JP    ZVECT
  96. ;
  97. RINP    CALL    ZENTRY
  98.     AND    0CH
  99.     RRCA
  100.     RRCA
  101.     LD    HL,ZRIV
  102.     JR    ZVECT
  103.  
  104. ;
  105. COUT    CALL    ZENTRY
  106.     AND    03H
  107.     LD    HL,ZCOV
  108.     JR    ZVECT
  109. ;
  110. POUT    CALL    ZENTRY
  111.     AND    30H
  112.     RRCA
  113.     RRCA
  114.     RRCA
  115.     RRCA
  116.     LD    HL,ZPOV
  117.     JR    ZVECT
  118. ;
  119. LOUT    CALL    ZENTRY
  120.     AND    0C0H
  121.     RLCA
  122.     RLCA
  123.     LD    HL,ZLOV
  124.     JR    ZVECT
  125. ;
  126. CSTA    CALL    ZENTRY
  127.     AND    03H
  128.     LD    HL,ZSTV
  129.     JR    ZVECT
  130. ;
  131. IOCH    CALL    ZENTRY
  132.     JR    ZEXIT
  133. ;
  134. IOST    CALL    ZENTRY
  135.     LD    A,C
  136.     LD    (IY-4DH),A
  137.     JR    ZEXIT
  138. ;
  139. MTST    CALL    ZENTRY
  140.     CALL    MMEMRY
  141.     LD    B,H
  142.     LD    A,L
  143.     JR    ZEXIT
  144. ;
  145. ZENTRY    EX    (SP),HL
  146.     PUSH    DE
  147.     PUSH    IY
  148.     LD    IY,(VWORK)
  149.     LD    A,(IY-4DH)
  150.     JP    (HL)
  151. ;
  152. ;    VECTOR ROUTINE
  153. ;
  154. ZVECT    ADD    A,A
  155.     ADD    A,L
  156.     LD    L,A
  157.     JR    NC,ZVT1
  158.     INC    H
  159. ZVT1    LD    E,(HL)
  160.     INC    HL
  161.     LD    D,(HL)
  162.     EX    DE,HL
  163.     POP    IY
  164.     POP    DE
  165.     EX    (SP),HL
  166.     RET
  167. ;
  168. ZEXIT    POP    IY
  169.     POP    DE
  170.     POP    HL
  171.     RET
  172. ;
  173. ZSKEY    CALL    CKEYIN
  174.     OR    A
  175.     RET
  176. ;
  177. ZSTAT    JP    CSTATS
  178. ;
  179. ZVIDEO    JP    CVOUT
  180. ;
  181. ZCASI    JP    TLOAD
  182. ;
  183. ZCASO    JP    TSAVE
  184. ;
  185. ZPRTR    JP    CLISTR
  186.