home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / sigm / vols000 / vol018 / stattime.asm < prev    next >
Encoding:
Assembly Source File  |  1984-04-29  |  5.9 KB  |  237 lines
  1.  
  2.     title    'STATTIME as of october 20, 1980'
  3.  
  4. ; 
  5. ; 
  6. ;  Here  is  an  interesting  "patch"  to  Digital  Research's 
  7. ; STAT.COM, that incorporates a "real time clock display. This 
  8. ; patch  works with STAT.COM for CP/M version 2.2 ONLY.  Merge 
  9. ; it into STAT.COM as follows:
  10. ; 
  11. ;      A>DDT STAT.COM<cr>
  12. ;      NEXT   PC
  13. ;      1580  0100
  14. ;      -ISTATTIME.HEX<cr>
  15. ;      -R<cr>
  16. ;      NEXT   PC
  17. ;      16CD  0000
  18. ;      -^C
  19. ;      A>SAVE 22 STATTIME.COM<cr>
  20. ; 
  21. ;  Now you have a new "STAT" command file called STATTIME.COM, 
  22. ; and it will display the "real time" on every execution...
  23. ; 
  24. ;                         Best regards,
  25. ;           
  26. ;                         Kelly Smith, MP/M-Net (tm) Sysop
  27. ;                         (805) 527-9321 (Modem, 300 Baud)
  28. ;
  29. ;
  30. ;
  31. ;    STATTIME.ASM (revised 10/16/80)
  32. ;
  33. ;    Revised from the May 1980, INTERFACE AGE MAGAZINE
  34. ;
  35. ;    For Compu-Time T-102 TIME/DATE board (With MM 5375 AC)
  36. ;
  37. ;       or,
  38. ;
  39. ;    QT Computer Systems Inc. "Clock/Calendar +" board
  40. ;
  41. ;
  42. bdos    equ    5
  43. pbuf    equ    9
  44.  
  45. stat    equ    433h    ; STAT.COM entry address
  46.  
  47. cr    equ    0dh    ; ASCII carriage return
  48. lf    equ    0ah    ; ASCII line feed
  49.  
  50. true    equ    -1    ; define true
  51. false    equ    not true; define false
  52. qt    equ    true    ; define QT Computer Systems Clock/Calendar + board
  53. ct    equ    false    ; Compu-Time Time/Date board
  54.  
  55.     if qt
  56.  
  57. clock    equ    080h    ; real time clock base port address
  58.  
  59.     endif
  60.  
  61.     if ct
  62.  
  63. clock    equ    024h    ; real time clock base port address
  64.  
  65.     endif
  66.  
  67.  
  68.     org     0100h
  69.  
  70.     jmp    date
  71.  
  72.     org    1501h    ; version 2.2 stat.com entry address
  73.  
  74. date:    push psw ! push b ! push d ! push h
  75.     lxi    h,month    ; point to month
  76.     mvi    d,8    ; select month tens digit
  77.     call    digit    ; read and store high digit
  78.     rlc ! rlc ! rlc ! rlc    ; shift to high order hex digit
  79.     mov    b,a    ; save in b reg.
  80.     call    digit    ; read and store month units digit
  81.     ora    b    ; or-in the units and tens digit
  82.     mov    b,a    ; save the month in b reg.
  83.     call    digit    ; read and store the day tens digit
  84.     rlc ! rlc ! rlc ! rlc    ; shift to high order hex digit
  85.     mov    c,a    ; save in c reg.
  86.     call    digit    ; read and store day units digit
  87.     ora    c    ; or-in the units and tens digit
  88.     mov    c,a    ; save the day in c reg.
  89.  
  90. ;
  91. ; test the date, and convert it to four year calendar format
  92. ;
  93.  
  94.     cpi    031h    ; 31st day?
  95.     mov    a,b    ; get the month, for next test
  96.     jnz    m2    ; if not the 31st, test for february
  97.     cpi    2    ; test for months < 31 days
  98.     jz    fix    ; ...and fix if needed
  99.     cpi    4
  100.     jz    fix
  101.     cpi    6
  102.     jz    fix
  103.     cpi    9
  104.     jz    fix
  105.     cpi    011h
  106.     jz    fix
  107. m2:    cpi    2    ; test for february
  108.     jnz    time    ; if not february, then read time
  109.     mov    a,c    ; get day for test
  110.     cpi    029h    ; is this the 29th day?
  111.  
  112. ;
  113. ; insert two NOP's over previous instruction, if this is a leap year
  114. ;
  115.     jz    fix    ; fix date...
  116.     cpi    030h    ; 30th day?
  117.     jnz    time    ; if not the 29th or 30th, go read time
  118. fix:    mvi    a,41    ; select month units and fast set
  119.     call    rdigit    ; read the month units digit
  120.     mov    b,a    ; save in b reg.
  121. floop:    in    clock    ; read the months unit digit
  122.     cmp    b    ; test for digit changed
  123.     jz    floop    ; wait until month is bumped (stable data)
  124. time:    lxi    h,hour    ; point to hour
  125.     mvi    d,0    ; select hour tens digit
  126.     call    ddigit    ; read hour tens and units
  127.     inx    h    ; step over ":"
  128.     call    ddigit    ; read minutes tens and units
  129.     inx    h    ; step over ":"
  130.     call    ddigit    ; read second tens and units
  131.     lxi    d,pdate    ; point to date and time message
  132.     mvi    c,pbuf    ; print buffer function
  133.     call    bdos    ; let CP/M do the work...
  134.     lda    month    ; get high byte of the month
  135.     cpi    ' '    ; in the range of january to september?
  136.     jz    jansept
  137.     lda    month+1    ; must be october to december...
  138.     cpi    '0'    ; october?
  139.     lxi    d,oct
  140.     jz    pmonth    ; print, if so
  141.     cpi    '1'    ; november?
  142.     lxi    d,nov
  143.     jz    pmonth    ; print, if so
  144.     lxi    d,dec    ; december.
  145.     jmp    pmonth    ; print it...
  146. jansept:lda    month+1    ; it's january to september
  147.     cpi    '1'    ; january?
  148.     lxi    d,jan
  149.     jz    pmonth    ; print, if so
  150.     cpi    '2'    ; february?
  151.     lxi    d,feb
  152.     jz    pmonth    ; print, if so
  153.     cpi    '3'    ; march?
  154.     lxi    d,mar
  155.     jz    pmonth    ; print, if so
  156.     cpi    '4'    ; april?
  157.     lxi    d,apr
  158.     jz    pmonth    ; print, if so
  159.     cpi    '5'    ; may?
  160.     lxi    d,may
  161.     jz    pmonth    ; print, if so
  162.     cpi    '6'    ; june?
  163.     lxi    d,jun
  164.     jz    pmonth    ; print month
  165.     cpi    '7'    ; july?
  166.     lxi    d,jul
  167.     jz    pmonth    ; print, if so
  168.     cpi    '8'    ; august?
  169.     lxi    d,aug
  170.     jz    pmonth    ; print, if so
  171.     lxi    d,sep    ; it's september
  172. pmonth:    mvi    c,pbuf    ; print buffer function
  173.     call    bdos    ; let CP/M do the work...
  174. done:    lxi    d,day    ; get the day
  175.     mvi    c,pbuf    ; print buffer function
  176.     call    bdos    ; let CP/M do the work...
  177.     pop h ! pop d ! pop b ! pop psw
  178.     jmp    stat    ; now jump into STAT...
  179.  
  180. ddigit:    call    digit    ; read and store two digits
  181. digit:    mov    a,d    ; move digit select code to a reg.
  182.     call    rdigit    ; read a clock digit
  183.     cpi    0ffh    ; test for board present
  184.     jz    nobrd    ; go print error message
  185.     ori    030h    ; convert digit to ASCII
  186.     cpi    03fh    ; test for blanked leading zero
  187.     jnz    store    ; go store digit, if not blanked
  188.     mvi    a,020h    ; convert to a blank
  189. store:    mov    m,a    ; store the digit in message buffer
  190.     inx    h    ; bump message pointer buffer location
  191.     inr    d    ; step to next digit
  192.     ani    00fh    ; mask off high ASCII nibble
  193.     ret        ; return with digit in a reg.
  194.  
  195. nobrd:    pop    h    ; adjust the stack
  196.     lxi    d,errmsg; point to the error message
  197.     jmp    done    ; print error message, and exit to CP/M
  198.  
  199. rdigit:    out    clock    ; select digit
  200.     mvi    a,0    ; ...some delay time for settling
  201. dloop:    dcr    a
  202.     jnz    dloop
  203.     in    clock    ; read a digit
  204.     ret        ; return with digit in a reg.
  205.  
  206. ;
  207. ; message buffers
  208. ;
  209.  
  210. pdate:    db    cr,lf,'Date: $'
  211. month:    ds    2    ; the month
  212. day:    db    'xx, '    ; the day...
  213.     db    '1980'    ; the year...
  214.     db    '  Time: '
  215. hour:    db    'xx:'    ; the hour...
  216.     db    'xx:'    ; the minute...
  217.     db    'xx'    ; the second...
  218.     db    cr,lf,'$'    ; string delimeter
  219.  
  220. errmsg:    db    cr,lf,'The Clock Board is NOT INSTALLED!',cr,lf,'$'
  221.  
  222. jan:    db    'January $'
  223. feb:    db    'February $'
  224. mar:    db    'March $'
  225. apr:    db    'April $'
  226. may:    db    'May $'
  227. jun:    db    'June $'
  228. jul:    db    'July $'
  229. Aug:    db    'August $'
  230. sep:    db    'September $'
  231. oct:    db    'October $'
  232. nov:    db    'November $'
  233. dec:    db    'December $'
  234.  
  235.     end
  236.  
  237.